RET 	
FD65	JC	FD68	；該點(diǎn)的內(nèi)容比待查找的內(nèi)容大否？
	MOV	A,R4	；偏大，取該點(diǎn)位置
	DEC	A	；減一
	MOV	R3,A	；作為新的區(qū)間高端
	SJMP	FD61	；繼續(xù)查找
FD68	MOV	A,R4	；偏小，取該點(diǎn)位置
	INC	A	；加一
	MOV	R2,A	；作為新的區(qū)間低端
	SJMP	FD61	；繼續(xù)查找
FD69	SETB	OV	；查找失敗
	RET
 	
    （２９）  標(biāo)號(hào)：ＦＤＤ２  功能：對(duì)分查找（ＲＯＭ）雙字節(jié)無符號(hào)增序數(shù)據(jù)表格

入口條件：查找內(nèi)容在R4、R5中，表格首址在DPTR中，數(shù)據(jù)個(gè)數(shù)在R7中。
出口信息：OV=0 時(shí)順序號(hào)在累加器A中，址在DPTR中；OV=1 時(shí)未找到。
影響資源：PSW、A、B、R1～R7、DPTR    堆棧需求：  ２字節(jié)

FDD2	MOV	R2,#0	；區(qū)間低端指針初始化（指向第一個(gè)數(shù)據(jù)）
	MOV	A,R7
	DEC	A
	MOV	R3,A	；區(qū)間高端指針初始化，指向最后一個(gè)數(shù)據(jù)
	MOV	R6,DPH	；保存表格首址
	MOV	R7,DPL
FD81	CLR	C	；判斷區(qū)間大小
	MOV	A,R3
	SUBB	A,R2
	JC	FD89	；區(qū)間消失，查找失敗
	RRC	A	；取區(qū)間大小的一半
	ADD	A,R2	；加上區(qū)間的低端
	MOV	R1,A	；得到區(qū)間的中心
	MOV	DPH,R6
	CLR	C	；計(jì)算區(qū)間中心的地址
	RLC	A
	JNC	FD82
	INC	DPH
FD82	ADD	A,R7
	MOV	DPL,A
	JNC	FD83
	INC	DPH
FD83	CLR	A	；讀取該點(diǎn)的內(nèi)容的高字節(jié)
	MOVC	A,@A+DPTR
	MOV	B,R4	；與待查找內(nèi)容的高字節(jié)比較
	CJNE	A,B,FD84；不相同
	MOV	A,#1	；讀取該點(diǎn)的內(nèi)容的低字節(jié)
	MOVC	A,@A+DPTR
	MOV	B,R5
	CJNE	A,B,FD84；與待查找內(nèi)容的低字節(jié)比較
	MOV	A,R1	；取順序號(hào)
	CLR	OV	；查找成功
	RET
FD84	JC	FD86	；該點(diǎn)的內(nèi)容比待查找的內(nèi)容大否？
	MOV	A,R1	；偏大，取該點(diǎn)位置
	DEC	A	；減一
	MOV	R3,A	；作為新的區(qū)間高端
	SJMP	FD81	；繼續(xù)查找
FD86	MOV	A,R1	；偏小，取該點(diǎn)位置
	INC	A	；加一
	MOV	R2,A	；作為新的區(qū)間低端
	SJMP	FD81	；繼續(xù)查找
FD89	MOV	DPH,R6	；相同，恢復(fù)首址
	MOV	DPL,R7
	SETB	OV	；查找失敗
	RET


    （３０）  標(biāo)號(hào)：  ＤＤＭ１    功能：求單字節(jié)十六進(jìn)制無符號(hào)數(shù)據(jù)塊的平均值

入口條件：數(shù)據(jù)塊的首址在DPTR中，數(shù)據(jù)個(gè)數(shù)在R7中。
出口信息：平均值在累加器A中。
影響資源：PSW、A、R2～R6  堆棧需求：  ４字節(jié)

DDM1	MOV	A,R7	；保存數(shù)據(jù)個(gè)數(shù)
	MOV	R2,A
	PUSH	DPH
	PUSH	DPL
	CLR	A	；初始化累加和
	MOV	R4,A
	MOV	R5,A
DM11	MOVX	A,@DPTR	；讀取一個(gè)數(shù)據(jù)
	ADD	A,R5	；累加到累加和中
	MOV	R5,A
	JNC	DM12
	INC	R4
DM12	INC	DPTR	；調(diào)整指針
	DJNZ	R2,DM11	；累加完全部數(shù)據(jù)
	LCALL	D457	；求平均值（R4R5／R7－→R3）
	MOV	A,R3	；取平均值
	POP	DPL
	POP	DPH
	RET

    （３１）  標(biāo)號(hào)：  ＤＤＭ２    功能：求雙字節(jié)十六進(jìn)制無符號(hào)數(shù)據(jù)塊的平均值

入口條件：數(shù)據(jù)塊的首址在DPTR中，雙字節(jié)數(shù)據(jù)總個(gè)數(shù)在R7中。
出口信息：平均值在R4、R5中。
影響資源：PSW、A、R2～R6      堆棧需求：  ４字節(jié)

DDM2	MOV	A,R7	；保存數(shù)據(jù)個(gè)數(shù)
	MOV	R2,A	；初始化數(shù)據(jù)指針
	PUSH	DPL	；保持首址
	PUSH	DPH
	CLR	A	；初始化累加和
	MOV	R3,A
	MOV	R4,A
	MOV	R5,A
DM20	MOVX	A,@DPTR	；讀取一個(gè)數(shù)據(jù)的高字節(jié)
	MOV	B,A
	INC	DPTR
	MOVX	A,@DPTR	；讀取一個(gè)數(shù)據(jù)的低字節(jié)
	INC	DPTR
	ADD	A,R5	；累加到累加和中
	MOV	R5,A
	MOV	A,B
	ADDC	A,R4
	MOV	R4,A
	JNC	DM21
	INC	R3
DM21	DJNZ	R2,DM20	；累加完全部數(shù)據(jù)
	POP	DPH	；恢復(fù)首址
	POP	DPL
	LJMP	DV31	；求R3R4R5／R7－→R4R5，得到平均值

    （３２）  標(biāo)號(hào)：  ＸＲ１    功能：求單字節(jié)數(shù)據(jù)塊的（異或）校驗(yàn)和

入口條件：數(shù)據(jù)塊的首址在DPTR中，數(shù)據(jù)的個(gè)數(shù)在R6、R7中。
出口信息：校驗(yàn)和在累加器A中。
影響資源：PSW、A、B、R4～R7  堆棧需求：  ２字節(jié)

XR1	MOV	R4,DPH	；保存數(shù)據(jù)塊的首址
	MOV	R5,DPL
	MOV	A,R7	；雙字節(jié)計(jì)數(shù)器調(diào)整
	JZ	XR10
	INC	R6
XR10	MOV	B,#0	；校驗(yàn)和初始化
XR11	MOVX	A,@DPTR	；讀取一個(gè)數(shù)據(jù)
	XRL	B,A	；異或運(yùn)算
	INC	DPTR	；指向下一個(gè)數(shù)據(jù)
	DJNZ	R7,XR11	；雙字節(jié)計(jì)數(shù)器減一
	DJNZ	R6,XR11
	MOV	DPH,R4	；恢復(fù)數(shù)據(jù)首址
	MOV	DPL,R5
	MOV	A,B	；取校驗(yàn)和
	RET

    （３３）  標(biāo)號(hào)：  ＸＲ２    功能：求雙字節(jié)數(shù)據(jù)塊的（異或）校驗(yàn)和

入口條件：數(shù)據(jù)塊的首址在DPTR中，雙字節(jié)數(shù)據(jù)總個(gè)數(shù)在R6、R7中。
出口信息：校驗(yàn)和在R2、R3中。
影響資源：PSW、A、R2～R7      堆棧需求：  ２字節(jié)

XR2	MOV	R4,DPH	；保存數(shù)據(jù)塊的首址
	MOV	R5,DPL
	MOV	A,R7	；雙字節(jié)計(jì)數(shù)器調(diào)整
	JZ	XR20
	INC	R6
XR20	CLR	A	；校驗(yàn)和初始化
	MOV	R2,A
	MOV	R3,A
XR21	MOVX	A,@DPTR	；讀取一個(gè)數(shù)據(jù)的高字節(jié)
	XRL	A,R2	；異或運(yùn)算
	MOV	R2,A
	INC	DPTR
	MOVX	A,@DPTR	；讀取一個(gè)數(shù)據(jù)的低字節(jié)
	XRL	A,R3	；異或運(yùn)算
	MOV	R3,A
	INC	DPTR	；指向下一個(gè)數(shù)據(jù)
	DJNZ	R7,XR21	；雙字節(jié)計(jì)數(shù)器減一
	DJNZ	R6,XR21
	MOV	DPH,R4	；恢復(fù)數(shù)據(jù)首址
	MOV	DPL,R5
	RET

    （３４）  標(biāo)號(hào)：  ＳＯＲＴ    功能：?jiǎn)巫止?jié)無符號(hào)數(shù)據(jù)塊排序（增序）

入口條件：數(shù)據(jù)塊的首址在R0中，字節(jié)數(shù)在R7中。
出口信息：完成排序（增序）
影響資源：PSW、A、R2～R6      堆棧需求：  ２字節(jié)

SORT	MOV	A,R7
	MOV	R5,A	；比較次數(shù)初始化
SRT1	CLR	F0	；交換標(biāo)志初始化
	MOV	A,R5	；取上遍比較次數(shù)
	DEC	A	；本遍比上遍減少一次
	MOV	R5,A	；保存本遍次數(shù)
	MOV	R2,A	；復(fù)制到計(jì)數(shù)器中
	JZ	SRT5	；若為零，排序結(jié)束
	MOV	A,R0	；保存數(shù)據(jù)指針
	MOV	R6,A
SRT2	MOV	A,@R0	；讀取一個(gè)數(shù)據(jù)
	MOV	R3,A
	INC	R0	；指向下一個(gè)數(shù)據(jù)
	MOV	A,@R0	；再讀取一個(gè)數(shù)據(jù)
	MOV	R4,A
	CLR	C
	SUBB	A,R3	；比較兩個(gè)數(shù)據(jù)的大小
	JNC	SRT4	；順序正確（增序或相同），不必交換
	SETB	F0	；設(shè)立交換標(biāo)志
	MOV	A,R3	；將兩個(gè)數(shù)據(jù)交換位置
	MOV	@R0,A
	DEC	R0
	MOV	A,R4
	MOV	@R0,A
	INC	R0	；指向下一個(gè)數(shù)據(jù)
SRT4	DJNZ	R2,SRT2	；完成本遍的比較次數(shù)
	MOV	A,R6	；恢復(fù)數(shù)據(jù)首址
	MOV	R0,A
	JB	F0,SRT1	；本遍若進(jìn)行過交換，則需繼續(xù)排序
SRT5	RET		；排序結(jié)束
	END



          （二）      ＭＣＳ－５１  浮點(diǎn)運(yùn)算子程序庫(kù)及其使用說明


    本浮點(diǎn)子程序庫(kù)有三個(gè)不同層次的版本，以便適應(yīng)不同的應(yīng)用場(chǎng)合：
    １．小型庫(kù)（FQ51A.ASM）：只包含浮點(diǎn)加、減、乘、除子程序。
    ２．中型庫(kù)（FQ51B.ASM）：在小型庫(kù)的基礎(chǔ)上再增加絕對(duì)值、倒數(shù)、比較、平方、
開平方、數(shù)制轉(zhuǎn)換等子程序。
    ３．大型庫(kù)（FQ51.ASM）：包含本說明書中的全部子程序。
    為便于讀者使用本程序庫(kù)，先將有關(guān)約定說明如下：
    １．雙字節(jié)定點(diǎn)操作數(shù)：用[R0]或[R1]來表示存放在由R0或R1指示的連續(xù)單元中的數(shù)
據(jù)，地址小的單元存放高字節(jié)。如果[R0]=1234H，若(R0)=30H，則(30H)=12H，(31H)=34H。
    ２．二進(jìn)制浮點(diǎn)操作數(shù)：用三個(gè)字節(jié)表示，第一個(gè)字節(jié)的最高位為數(shù)符，其余七位為
階碼（補(bǔ)碼形式），第二字節(jié)為尾數(shù)的高字節(jié)，第三字節(jié)為尾數(shù)的低字節(jié)，尾數(shù)用雙字節(jié)
純小數(shù)（原碼）來表示。當(dāng)尾數(shù)的最高位為１時(shí)，便稱為規(guī)格化浮點(diǎn)數(shù)，簡(jiǎn)稱操作數(shù)。在
程序說明中，也用[R0]或[R1]來表示R0或R1指示的浮點(diǎn)操作數(shù)，例如：當(dāng)[R0]=-6.000時(shí)，
則二進(jìn)制浮點(diǎn)數(shù)表示為83C000H。若(R0)=30H，則(30H)=83H,(31H)=0C0H,(32H)=00H。
    ３．十進(jìn)制浮點(diǎn)操作數(shù)：用三個(gè)字節(jié)表示，第一個(gè)字節(jié)的最高位為數(shù)符，其余七位為
階碼（二進(jìn)制補(bǔ)碼形式），第二字節(jié)為尾數(shù)的高字節(jié)，第三字節(jié)為尾數(shù)的低字節(jié)，尾數(shù)用
雙字節(jié)ＢＣＤ碼純小數(shù)（原碼）來表示。當(dāng)十進(jìn)制數(shù)的絕對(duì)值大于１時(shí)，階碼就等于整數(shù)
部分的位數(shù)，如 876.5 的階碼是03H，-876.5 的階碼是 83H；當(dāng)十進(jìn)制數(shù)的絕對(duì)值小于1
時(shí)，階碼就等于 80H 減去小數(shù)點(diǎn)后面零的個(gè)數(shù)，例如 0.00382 的階碼是 7EH，-0.00382
的階碼是 0FEH。在程序說明中，用[R0]或[R1]來表示R0或R1指示的十進(jìn)制浮點(diǎn)操作數(shù)。例
如有一個(gè)十進(jìn)制浮點(diǎn)操作數(shù)存放在30H、31H、32H中，數(shù)值是 -0.07315，即-0.7315乘以10
的-1次方，則(30H)=0FFH，31H=73H，(32H)=15H。若用[R0]來指向它，則應(yīng)使(R0)=30H。
    ４．運(yùn)算精度：?jiǎn)未味c(diǎn)運(yùn)算精度為結(jié)果最低位的當(dāng)量值；單次二進(jìn)制浮點(diǎn)算術(shù)運(yùn)算
的精度優(yōu)于十萬分之三；單次二進(jìn)制浮點(diǎn)超越函數(shù)運(yùn)算的精度優(yōu)于萬分之一；ＢＣＤ碼浮
點(diǎn)數(shù)本身的精度比較低（萬分之一到千分之一），不宜作為運(yùn)算的操作數(shù)，僅用于輸入或
輸出時(shí)的數(shù)制轉(zhuǎn)換。不管那種數(shù)據(jù)格式，隨著連續(xù)運(yùn)算的次數(shù)增加，精度都會(huì)下降。
    ５．工作區(qū)：數(shù)據(jù)工作區(qū)固定在A、B、R2～R7，數(shù)符或標(biāo)志工作區(qū)固定在PSW和23H單
元(位1CH～1FH)。在浮點(diǎn)系統(tǒng)中，R2、R3、R4和位1FH為第一工作區(qū)，R5、R6、R7和位1EH
為第二工作區(qū)。用戶只要不在工作區(qū)中存放無關(guān)的或非消耗性的信息，程序就具有較好的
透明性。
    ６．子程序調(diào)用范例：由于本程序庫(kù)特別注意了各子程序接口的相容性，很容易采用
積木方式（或流水線方式）完成一個(gè)公式的計(jì)算。以浮點(diǎn)運(yùn)算為例：
    計(jì)算   ｙ = Ｌｎ √ ｜ Ｓｉｎ （ａｂ／ｃ＋ｄ） ｜
    已知：a=-123.4；b=0.7577；c=56.34；d=1.276； 它們分別存放在30H、33H、36H、
39H開始的連續(xù)三個(gè)單元中。用ＢＣＤ碼浮點(diǎn)數(shù)表示時(shí)，分別為a=831234H；b=007577H；
c=025634H；d=011276H。
    求解過程：通過調(diào)用ＢＴＯＦ子程序，將各變量轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)，再進(jìn)行各
種運(yùn)算，最后調(diào)用ＦＴＯＢ子程序，還原成十進(jìn)制形式，供輸出使用。程序如下：
TEST	MOV  	R0,#39H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ｄ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R0,#36H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ｃ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R0,#33H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ｂ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R0,#30H   ；指向ＢＣＤ碼浮點(diǎn)操作數(shù)ａ
	LCALL	BTOF      ；將其轉(zhuǎn)換成二進(jìn)制浮點(diǎn)操作數(shù)
	MOV  	R1,#33H   ；指向二進(jìn)制浮點(diǎn)操作數(shù)ｂ
	LCALL	FMUL      ；進(jìn)行浮點(diǎn)乘法運(yùn)算
	MOV  	R1,#36H   ；指向二進(jìn)制浮點(diǎn)操作數(shù)ｃ
	LCALL	FDIV      ；進(jìn)行浮點(diǎn)除法運(yùn)算
	MOV  	R1,#39H   ；指向二進(jìn)制浮點(diǎn)操作數(shù)ｄ
	LCALL	FADD      ；進(jìn)行浮點(diǎn)加法運(yùn)算
	LCALL	FSIN      ；進(jìn)行浮點(diǎn)正弦運(yùn)算
	LCALL	FABS      ；進(jìn)行浮點(diǎn)絕對(duì)值運(yùn)算
	LCALL	FSQR      ；進(jìn)行浮點(diǎn)開平方運(yùn)算
	LCALL	FLN       ；進(jìn)行浮點(diǎn)對(duì)數(shù)運(yùn)算
	LCALL	FTOB      ；將結(jié)果轉(zhuǎn)換成ＢＣＤ碼浮點(diǎn)數(shù)
STOP	LJMP	STOP
	END
    運(yùn)行結(jié)果，[R0]=804915H，即ｙ=-0.4915，比較精確的結(jié)果應(yīng)該是-0.491437。

    （１）  標(biāo)號(hào)：  ＦＳＤＴ    功能：浮點(diǎn)數(shù)格式化

入口條件：待格式化浮點(diǎn)操作數(shù)在[R0]中。
出口信息：已格式化浮點(diǎn)操作數(shù)仍在[R0]中。
影響資源：PSW、A、R2、R3、R4、位1FH    堆棧需求：  ６字節(jié)

FSDT	LCALL	MVR0	；將待格式化操作數(shù)傳送到第一工作區(qū)中
	LCALL	RLN	；通過左規(guī)完成格式化
	LJMP	MOV0	；將已格式化浮點(diǎn)操作數(shù)傳回到[R0]中

    （２）  標(biāo)號(hào)：  ＦＡＤＤ    功能：浮點(diǎn)數(shù)加法

入口條件：被加數(shù)在[R0]中，加數(shù)在[R1]中。
出口信息：OV=0時(shí)，和仍在[R0]中，OV=1時(shí)，溢出。
影響資源：PSW、A、B、R2～R7、位1EH、1FH  堆棧需求：  ６字節(jié)

FADD	CLR	F0	；設(shè)立加法標(biāo)志
	SJMP	AS	；計(jì)算代數(shù)和

    （３）  標(biāo)號(hào)：  ＦＳＵＢ    功能：浮點(diǎn)數(shù)減法

入口條件：被減數(shù)在[R0]中，減數(shù)在[R1]中。
出口信息：OV=0時(shí)，差仍在[R0]中，OV=1時(shí)，溢出。
影響資源：PSW、A、B、R2～R7、位1EH、1FH    堆棧需求：６字節(jié)

FSUB	SETB	F0	；設(shè)立減法標(biāo)志
AS	LCALL	MVR1	；計(jì)算代數(shù)和。先將[R1]傳送到第二工作區(qū)
	MOV	C,F0	；用加減標(biāo)志來校正第二操作數(shù)的有效符號(hào)
	RRC	A
	XRL	A,@R1
	MOV	C,ACC.7
ASN	MOV	1EH,C	；將第二操作數(shù)的有效符號(hào)存入位1EH中
	XRL	A,@R0	；與第一操作數(shù)的符號(hào)比較
	RLC	A
	MOV	F0,C	；保存比較結(jié)果
	LCALL	MVR0	；將[R0]傳送到第一工作區(qū)中
	LCALL	AS1	；在工作寄存器中完成代數(shù)運(yùn)算
MOV0	INC	R0	；將結(jié)果傳回到[R0]中的子程序入口
	INC	R0
	MOV	A,R4	；傳回尾數(shù)的低字節(jié)
	MOV	@R0,A
	DEC	R0
	MOV	A,R3	；傳回尾數(shù)的高字節(jié)
	MOV	@R0,A
	DEC	R0
	MOV	A,R2	；取結(jié)果的階碼
	MOV	C,1FH	；取結(jié)果的數(shù)符
	MOV	ACC.7,C	；拼入階碼中
	MOV	@R0,A
	CLR	ACC.7	；不考慮數(shù)符
	CLR	OV	；清除溢出標(biāo)志
	CJNE	A,#3FH,MV01；階碼是否上溢？
	SETB	OV	；設(shè)立溢出標(biāo)志
MV01	MOV	A,@R0	；取出帶數(shù)符的階碼
	RET
MVR0	MOV	A,@R0	；將[R0]傳送到第一工作區(qū)中的子程序
	MOV	C,ACC.7	；將數(shù)符保存在位1FH中
	MOV	1FH,C
	MOV	C,ACC.6	；將階碼擴(kuò)充為８ｂｉｔ補(bǔ)碼
	MOV	ACC.7,C
	MOV	R2,A	；存放在R2中
	INC	R0
	MOV	A,@R0	；將尾數(shù)高字節(jié)存放在R3中
	MOV	R3,A
	INC	R0
	MOV	A,@R0	；將尾數(shù)低字節(jié)存放在R4中
	MOV	R4,A
	DEC	R0	；恢復(fù)數(shù)據(jù)指針
	DEC	R0
	RET
MVR1	MOV	A,@R1	；將[R1]傳送到第二工作區(qū)中的子程序
	MOV	C,ACC.7	；將數(shù)符保存在位1EH中
	MOV	1EH,C
	MOV	C,ACC.6	；將階碼擴(kuò)充為８ｂｉｔ補(bǔ)碼
	MOV	ACC.7,C
	MOV	R5,A	；存放在R5中
	INC	R1
	MOV	A,@R1	；將尾數(shù)高字節(jié)存放在R6中
	MOV	R6,A
	INC	R1
	MOV	A,@R1	；將尾數(shù)低字節(jié)存放在R7中
	MOV	R7,A
	DEC	R1	；恢復(fù)數(shù)據(jù)指針
	DEC	R1
	RET
AS1	MOV	A,R6	；讀取第二操作數(shù)尾數(shù)高字節(jié)
	ORL	A,R7
	JZ	AS2	；第二操作數(shù)為零，不必運(yùn)算
	MOV	A,R3	；讀取第一操作數(shù)尾數(shù)高字節(jié)
	ORL	A,R4
	JNZ	EQ1
	MOV	A,R6	；第一操作數(shù)為零，結(jié)果以第二操作數(shù)為準(zhǔn)
	MOV	R3,A
	MOV	A,R7
	MOV	R4,A
	MOV	A,R5
	MOV	R2,A
	MOV	C,1EH
	MOV	1FH,C
AS2	RET
EQ1	MOV	A,R2	；對(duì)階，比較兩個(gè)操作數(shù)的階碼
	XRL	A,R5
	JZ	AS4	；階碼相同，對(duì)階結(jié)束
	JB	ACC.7,EQ3；階符互異
	MOV	A,R2	；階符相同，比較大小
	CLR	C
	SUBB	A,R5
	JC	EQ4
EQ2	CLR	C	；第二操作數(shù)右規(guī)一次
	MOV	A,R6	；尾數(shù)縮小一半
	RRC	A
	MOV	R6,A
	MOV	A,R7
	RRC	A
	MOV	R7,A
	INC	R5	；階碼加一
	ORL	A,R6	；尾數(shù)為零否？
	JNZ	EQ1	；尾數(shù)不為零，繼續(xù)對(duì)階
	MOV	A,R2	；尾數(shù)為零，提前結(jié)束對(duì)階
	MOV	R5,A
	SJMP	AS4
EQ3	MOV	A,R2	；判斷第一操作數(shù)階符
	JNB	ACC.7,EQ2；如為正，右規(guī)第二操作數(shù)
EQ4	CLR	C
	LCALL	RR1	；第一操作數(shù)右規(guī)一次
	ORL	A,R3	；尾數(shù)為零否？
	JNZ	EQ1	；不為零，繼續(xù)對(duì)階
	MOV	A,R5	；尾數(shù)為零，提前結(jié)束對(duì)階
	MOV	R2,A
AS4	JB	F0,AS5	；尾數(shù)加減判斷
	MOV	A,R4	；尾數(shù)相加
	ADD	A,R7
	MOV	R4,A
	MOV	A,R3	
	ADDC	A,R6
	MOV	R3,A
	JNC	AS2
	LJMP	RR1	；有進(jìn)位，右規(guī)一次
AS5	CLR	C	；比較絕對(duì)值大小
	MOV	A,R4
	SUBB	A,R7
	MOV	B,A
	MOV	A,R3
	SUBB	A,R6
	JC	AS6
	MOV	R4,B	；第一尾數(shù)減第二尾數(shù)
	MOV	R3,A
	LJMP	RLN	；結(jié)果規(guī)格化
AS6	CPL	1FH	；結(jié)果的符號(hào)與第一操作數(shù)相反
	CLR	C	；結(jié)果的絕對(duì)值為第二尾數(shù)減第一尾數(shù)
	MOV	A,R7
	SUBB	A,R4
	MOV	R4,A
	MOV	A,R6
	SUBB	A,R3
	MOV	R3,A
RLN	MOV	A,R3	；浮點(diǎn)數(shù)規(guī)格化
	ORL	A,R4	；尾數(shù)為零否？
	JNZ	RLN1
	MOV	R2,#0C1H；階碼取最小值
	RET     	
RLN1	MOV	A,R3
	JB	ACC.7,RLN2；尾數(shù)最高位為一否？
	CLR	C	；不為一，左規(guī)一次
	LCALL	RL1
	SJMP	RLN	；繼續(xù)判斷
RLN2	CLR	OV	；規(guī)格化結(jié)束
	RET
RL1	MOV	A,R4	；第一操作數(shù)左規(guī)一次
	RLC	A	；尾數(shù)擴(kuò)大一倍
	MOV	R4,A
	MOV	A,R3
	RLC	A
	MOV	R3,A
	DEC	R2	；階碼減一
	CJNE	R2,#0C0H,RL1E；階碼下溢否？
	CLR	A
	MOV	R3,A	；階碼下溢，操作數(shù)以零計(jì)
	MOV	R4,A
	MOV	R2,#0C1H
RL1E	CLR	OV
	RET
RR1	MOV	A,R3	；第一操作數(shù)右規(guī)一次
	RRC	A	；尾數(shù)縮小一半