.global JumpToKernel0x 
// r0 = jump address 
// r1 = arguments to use (these get shifted) 


由于arm-GCC的c參數(shù)調(diào)用的順序是從左到右R0開始，所以R0是KERNKEL的地址， 
r1是參數(shù)字符串的地址： 



到此為止，為linux引導(dǎo)做的準(zhǔn)備工作就結(jié)束了，下一回我們就正式進(jìn)入linux的代碼。 



好，從本節(jié)開始，我們走過了bootloader的漫長征途，開始進(jìn)入linux的內(nèi)核： 
說實(shí)話，linux寶典的確高深莫測，洋人花了十幾年修煉，各種內(nèi)功心法層處不窮。有些地方反復(fù)推敲也領(lǐng)悟不了其中奧妙，煉不到第九重啊。。 


linux的入口是一段匯編代碼，用于基本的硬件設(shè)置和建立臨時(shí)頁表，對于 
ARM LINUX是 linux/arch/arm/kernle/head-armv.S, 走！ 


#if defined(CONFIG_MX1) 
mov r1, #MACH_TYPE_MX1 
#endif 


這第一句話好像就讓人看不懂，好像葵花寶典開頭的八個字：欲練神功。。。。 


那來的MACH_TYPE_MX1？其實(shí)，在head-armv.S 
中的一項(xiàng)重要工作就是設(shè)置內(nèi)核的臨時(shí)頁表，不然mmu開起來也玩不轉(zhuǎn)，但是內(nèi)核怎么知道如何映射內(nèi)存呢？linux的內(nèi)核將映射到虛地址0xCxxx xxxx處，但他怎么知道把哪一片ram映射過去呢？ 


因?yàn)椴煌ǖ南到y(tǒng)有不通的內(nèi)存影像，所以，LINUX約定，內(nèi)核代碼開始的時(shí)候， 
R1放的是系統(tǒng)目標(biāo)平臺的代號，對于一些常見的，標(biāo)準(zhǔn)的平臺，內(nèi)核已經(jīng)提供了支持，只要在編譯的時(shí)候選中就行了，例如對X86平臺，內(nèi)核是從物理地址1M開始映射的。如果老兄是自己攢的平臺，只好麻煩你自己寫了。 


小弟拿人錢財(cái)，與人消災(zāi)，用的是摩托的MX1,只好自己寫了，定義了#MACH_TYPE_MX1，當(dāng)然，還要寫一個描述平臺的數(shù)據(jù)結(jié)構(gòu)： 


MACHINE_START(MX1ADS, "Motorola MX1ADS") 
MAINTAINER("SPS Motorola") 


BOOT_MEM(0x08000000, 0x00200000, 0xf0200000) 


FIXUP(mx1ads_fixup) 
MAPIO(mx1ads_map_io) 
INITIRQ(mx1ads_init_irq) 
MACHINE_END 


看起來怪怪的，但現(xiàn)在大家只要知道他定義了基本的內(nèi)存映象：RAM從0x08000000開始，i/o空間從0x00200000開始，i/o空間映射到虛擬地址空間 
0xf0200000開始處。摩托的芯片i/o和內(nèi)存是統(tǒng)一編址的。 
其他的項(xiàng)，在下面的初始化過程中會逐個介紹到。 


好了好了，再看下面的指令： 



mov r0, #F_BIT | I_BIT | MODE_SVC @ make sure svc mode //設(shè)置為SVC模式，允許中斷和快速中斷 
//此處設(shè)定系統(tǒng)的工作狀態(tài)，arm有7種狀態(tài) 
//每種狀態(tài)有自己的堆棧 


msr cpsr_c, r0 @ and all irqs diabled 
bl __lookup_processor_type 


//定義處理器相關(guān)信息，如value, mask, mmuflags， 
//放在proc.info段中 
//__lookup_processor_type 取得這些信息，在下面 
//__lookup_architecture_type 中用 


這一段是查詢處理器的種類，大家知道arm有arm7, arm9等類型，如何區(qū)分呢？ 
在arm協(xié)處理器中有一個只讀寄存器，存放處理器相關(guān)信息。__lookup_processor_type將返回如下的結(jié)構(gòu)： 


__arm920_proc_inf 
.long 0x41009200 //CPU id 
.long 0xff00fff0 //cpu mask 
.long 0x00000c1e @ mmuflags 
b __arm920_setup 
.long cpu_arch_name 
.long cpu_elf_name 
.long HWCAP_SWP | HWCAP_HALF | HWCAP_26BIT 
.long cpu_arm920_info 
.long arm920_processor_functions 



第一項(xiàng)是CPU id，將與協(xié)處理器中讀出的id作比較，其余的都是與處理器相關(guān)的 
信息，到下面初始化的過程中自然會用到。。 


查詢到了處理器類型和系統(tǒng)的內(nèi)存映像后就要進(jìn)入初始化過程中比較關(guān)鍵的一步了，開始設(shè)置mmu，但首先要設(shè)置一個臨時(shí)的內(nèi)核頁表，映射4m的內(nèi)存，這在初始化過程中是足夠了： 


//r5=0800 0000 ram起始地址 r6=0020 0000 io地址，r7=f020 0000 虛io 
teq r7, #0 @ invalid architecture? 
moveq r0, #'a' @ yes, error 'a' 
beq __error 
bl __create_page_tables 


其中__create_page_tables為： 
__create_page_tables: 
pgtbl r4 
//r4=0800 4000 臨時(shí)頁表的起始地址 
//r5=0800 0000, ram的起始地址 
//r6=0020 0000, i/o寄存器空間的起始地址 
//r7=0000 3c08 
//r8=0000 0c1e 


//the page table in 0800 4000 is just temp base page, when init_task's sweaper_page_dir ready, 
// the temp page will be useless 
// the high 12 bit of virtual address is base table index, so we need 4kx4 = 16k temp base page, 


mov r0, r4 
mov r3, #0 
add r2, r0, #0x4000 @ 16k of page table 
1: str r3, [r0], #4 @ Clear page table 
str r3, [r0], #4 
str r3, [r0], #4 
str r3, [r0], #4 
teq r0, r2 
bne 1b 
/* 
* Create identity mapping for first MB of kernel. 
* This is marked cacheable and bufferable. 
* 
* The identity mapping will be removed by 
*/ 


// 由于linux編譯的地址是0xC0008000,load的地址是0x08008000,我們需要將虛地址0xC0008000映射到0800800一段 
//同時(shí)，由于部分代碼也要直接訪問0x08008000，所以0x08008000對應(yīng)的表項(xiàng)也要填充 
// 頁表中的表象為section,AP=11表示任何模式下可訪問，domain為0。 
add r3, r8, r5 @ mmuflags + start of RAM 
//r3=0800 0c1e 
add r0, r4, r5, lsr #18 
//r0=0800 4200 
str r3, [r0] @ identity mapping 
//*0800 4200 = 0800 0c1e 0x200表象 對應(yīng)的是0800 0000 的1m 
/* 
* Now setup the pagetables for our kernel direct 
* mapped region. We round TEXTADDR down to the 
* nearest megabyte boundary. 
*/ 
//下面是映射4M 


add r0, r4, #(TEXTADDR & 0xfff00000) >> 18 @ start of kernel 
//r0 = r4+ 0x3000 = 0800 4000 + 3000 = 0800 7000 
str r3, [r0], #4 @ PAGE_OFFSET + 0MB 
//*0800 7004 = 0800 0c1e 
add r3, r3, #1 << 20 
//r3=0810 0c1e 
str r3, [r0], #4 @ PAGE_OFFSET + 1MB 
//*0800 7008 = 0810 0c1e 
add r3, r3, #1 << 20 
str r3, [r0], #4 
//*0800 700c = 0820 0c1e @ PAGE_OFFSET + 2MB 
add r3, r3, #1 << 20 
str r3, [r0], #4 @ PAGE_OFFSET + 3MB 
//*0800 7010 = 0830 0c1e 





bic r8, r8, #0x0c @ turn off cacheable 
//r8=0000 0c12 @ and bufferable bits 
mov pc, lr //子程序返回。 
下一回就要開始打開mmu的操作了 


上回書講到已經(jīng)設(shè)置好了內(nèi)核的頁表，然后要跳轉(zhuǎn)到__arm920_setup， 
這個函數(shù)在arch/arm/mm/proc-arm929.s 


__arm920_setup: 
mov r0, #0 
mcr p15, 0, r0, c7, c7 @ invalidate I,D caches on v4 
mcr p15, 0, r0, c7, c10, 4@ drain write buffer on v4 
mcr p15, 0, r0, c8, c7 @ invalidate I,D TLBs on v4 
mcr p15, 0, r4, c2, c0 @ load page table pointer 
mov r0, #0x1f @ Domains 0, 1 = client 
mcr p15, 0, r0, c3, c0 @ load domain access register 
mrc p15, 0, r0, c1, c0 @ get control register v4 
/* 
* Clear out 'unwanted' bits (then put them in if we need them) 
*/ 
@ VI ZFRS BLDP WCAM 
bic r0, r0, #0x0e00 
bic r0, r0, #0x0002 
bic r0, r0, #0x000c 
bic r0, r0, #0x1000 @ ...0 000. .... 000. 
/* 
* Turn on what we want 
*/ 
orr r0, r0, #0x0031 
orr r0, r0, #0x2100 @ ..1. ...1 ..11 ...1 


#ifdef CONFIG_CPU_ARM920_D_CACHE_ON 
orr r0, r0, #0x0004 @ .... .... .... .1.. 
#endif 
#ifdef CONFIG_CPU_ARM920_I_CACHE_ON 
orr r0, r0, #0x1000 @ ...1 .... .... .... 
#endif 
mov pc, lr 


這一段首先關(guān)閉i,d cache,清除write buffer ，然后設(shè)置頁目錄地址，設(shè)置 
domain的保護(hù)，在上節(jié)中，注意到頁目錄項(xiàng)的domain都是0，domain寄存器中 
的domain 0 對應(yīng)的是0b11，表示訪問模式為manager,不受限制。 


接下來設(shè)置控制寄存器，打開d,i cache和mmu 
注意arm的d cache必須和mmu一起打開，而i cache可以單獨(dú)打開 


其實(shí)，cache和mmu的關(guān)系實(shí)在是緊密，每一個頁表項(xiàng)都有標(biāo)志標(biāo)示是否是 
cacheable的，可以說本來就是設(shè)計(jì)一起使用的 


最后，自函數(shù)返回后，有一句 
mcr p15, 0, r0, c1, c0 
使設(shè)置生效。 



上回我們講到arm靠初始化完成了，打開了cache, 
到此為止，匯編部分的初始化代碼就差不多了，最后還有幾件事情做： 


1。初始化BSS段，全部清零，BSS是全局變量區(qū)域。 
2。保存與系統(tǒng)相關(guān)的信息：如 
.long SYMBOL_NAME(compat) 
.long SYMBOL_NAME(__bss_start) 
.long SYMBOL_NAME(_end) 
.long SYMBOL_NAME(processor_id) 
.long SYMBOL_NAME(__machine_arch_type) 
.long SYMBOL_NAME(cr_alignment) 
.long SYMBOL_NAME(init_task_union)+8192 
不用講，大家一看就明白意思 


3。重新設(shè)置堆棧指針，指向init_task的堆棧。init_task是系統(tǒng)的第一個任務(wù)，init_task的堆棧在task structure的后8K,我們后面會看到。 


4。最后就要跳到C代碼的start_kernel。 
b SYMBOL_NAME(start_kernel) 


現(xiàn)在讓我們來回憶一下目前的系統(tǒng)狀態(tài)： 
臨時(shí)頁表已經(jīng)建立，在0X08004000處，映射了4M，虛地址0XC000000被映射到0X08000000. 
CACHE,MMU都已經(jīng)打開。 
堆棧用的是任務(wù)init_task的堆棧。