?? init1335.asm
字號:
;********************INIT1335********************
;本程序實現液晶顯示控制器SED1335的初始化。
;入口參數:圖形顯示區的行數在SOU中(前0~240行)。
;出口參數:無。
;占用資源:W,STATUS,RB0~RB2,RC,023H,024H,028H,029H,二重堆棧。
;說 明:1.顯示屏為320*240點陣。
; 2.顯示屏前128行為圖形方式,后112行為文本方式
; 3.SAD1=0000H,SAD2=5000H,SAD3=3000H所有的區都開顯示且不閃爍。
; 4.AP=48,顯示緩沖區將被清0
WWR EQU 0
A0 EQU 2
RRD EQU 1
IFNDEF INIT13351
#DEFINE INIT13351
;*****************指令碼寫入子程序************
CMDIN MOVWF PORTC
BSF PORTB,A0
NOP
NOP
BCF PORTB,WWR
NOP
NOP
BSF PORTB,WWR
RETURN
;*****************數據及參數寫入子程序****************
DATAIN MOVWF PORTC
BCF PORTB,A0
NOP
NOP
BCF PORTB,WWR
NOP
NOP
BSF PORTB,WWR
RETURN
;*****************數據讀出子程序****************
DATAOUT BSF STATUS,RP0
MOVLW 0FFH
MOVWF TRISC
BCF STATUS,RP0
BSF PORTB,A0
NOP
NOP
BCF PORTB,RRD
NOP
NOP
MOVF PORTC,W
BSF PORTB,RRD
BSF STATUS,RP0
CLRF TRISC
BCF STATUS,RP0
RETURN
;*****************初始化程序************************
INIT1335 BSF STATUS,RP0
CLRF TRISC
CLRF TRISB
BCF STATUS,RP0
CLRF PCLATH
MOVLW 30H
MOVWF CNT
MOVLW 40H
CALL CMDIN ;寫SYSTEM SET指令
MOVLW 30H ;P1(單屏結構,內部CGROM+CGRAM1)
CALL DATAIN
MOVLW 87H ;P2
CALL DATAIN
MOVLW 07H ;P3
CALL DATAIN
MOVLW 28H ;P4(320個點,40字節)
CALL DATAIN
MOVLW 42H ;P5
CALL DATAIN
MOVLW 0F0H ;P6(L/F=240行)
CALL DATAIN
MOVLW 30H ;P7(AP=48)
CALL DATAIN
MOVLW 0 ;P8
CALL DATAIN
MOVLW 44H ;寫SCROLL指令
CALL CMDIN
MOVLW 00H ;P1
CALL DATAIN
MOVLW 00H ;P2(SAD1從0000H開始)
CALL DATAIN
MOVF SOU,W ;P3(SAD1占SOU行)
CALL DATAIN
MOVLW 00H ;P4
CALL DATAIN
MOVLW 50H ;P5(SAD2從5000H開始)
CALL DATAIN
MOVLW 0F0H ;P6(SAD2占240行)
CALL DATAIN
MOVLW 00H ;P7
CALL DATAIN
MOVLW 30H ;P8(SAD3從3000H開始)
CALL DATAIN
MOVLW 00H ;P9
CALL DATAIN
MOVLW 00H ;P10
CALL DATAIN
MOVLW 5BH ;OYLAY
CALL CMDIN
MOVLW 04H ;P(一區為圖形屬性,三區為文本屬性)
CALL DATAIN
MOVLW 5AH
CALL CMDIN ;HDOT SCR
MOVLW 00H
CALL DATAIN ;點位移0
MOVLW 01001100B ;CSRDIR
CALL CMDIN
MOVLW 46H ;CSRW
CALL CMDIN
MOVLW 00H
CALL DATAIN ;P1
CALL DATAIN ;P2(光標指針設在0000h)
MOVLW 59H ;DISP ON/OFF(開顯示)
CALL CMDIN
MOVLW 54H ;P(所有區顯示但不閃爍)
CALL DATAIN
;**********RAM清0***************
CLR1335 CLRW
MOVWF TEMP1
MOVWF CNT
MOVLW 42H
CALL CMDIN
MOVLW 00H
LOOP96 CALL DATAIN ;RAM清0
DECFSZ CNT,F
GOTO LOOP96
DECFSZ TEMP1,F
GOTO LOOP96
RETURN
ENDIF
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -