;********************MUBCDSHL********************
;本程序實現多字節非壓縮BCD碼非循環左移1位(即乘10)。
;入口參數: 原數據地址在SADR中,字節數在CNT中。
;出口參數: 結果首地址在SADR中,字節數在CNT中,移出位在SOU中。
;占用資源: W,STATUS,FSR,020H,023H,024H,028H,一重堆棧。
;說    明: 原數據將被沖掉.     

           IFNDEF       MUBCDSHL1
            #DEFINE     MUBCDSHL1

MUBCDSHL    DECF        CNT,W
            ADDWF       SADR,F
            MOVF        SADR,W
            MOVWF       FSR         ;得到末地址
            MOVF        SOU,W
            MOVWF       TEMP1       ;保存移入位
            MOVF        INDF,W
            MOVWF       SOU         ;移出位
            DECF        CNT,F
            DECF        FSR,F
LOOP13      MOVF        INDF,W
            INCF        FSR,F
            MOVWF       INDF
            DECF        FSR,F
            DECF        FSR,F
            DECFSZ      CNT,F
            GOTO        LOOP13
            INCF        FSR,F
            MOVF        TEMP1,W
            MOVWF       INDF        ;移入位
            DECF        FSR,W
            SUBWF       SADR,W
            MOVWF       CNT         ;恢復字節數
            MOVF        FSR,W
            MOVWF       SADR
            RETLW       0
           ENDIF