! 3.9  懸臂等強度梁的彎曲
! 本程序來源于邢靜忠編著的《ANSYS應用實例與分析》，科學出版社，2006年
!
FINISH
/CLEAR, NOSTART
/FILNAME, EX3.9
! （1）定義工程選項，分析類型為靜力（STATIC）分析，單元類型和實常數，材料參數等
/PREP7
/TITLE, EX3.9(1), BENDING OF A TAPERED PLATE (BEAM) WITH SHELL63 ELEMENT.
ANTYPE, STATIC
ET, 1, SHELL63, 2
R, 1, 12.7
MP, EX, 1, 207E3
MP, NUXY, 1, 0
! （2）通過節點和單元建模
N, 1
N, 8, 508, -38.1
FILL
N, 11
N, 18, 508, 38.1
FILL
E, 1, 2, 12
E, 2, 3, 12
E, 13, 12, 3
E, 3, 4, 14
E, 14, 13, 3
EGEN, 3, 2, 2, 5
! （3）定義耦合自由度，以保證變形對稱
CP, 1, UZ, 2, 12
CP, 2, ROTY, 2, 12
CPSGEN, 6, 1, 1, 2
OUTPR, ALL, ALL
D, 8, ALL, , , 18, 10
D, ALL, ROTX, 0
F, 1, FZ, -44.483
FINISH
! （4）進入求解模塊，開始求解
/SOLU
SOLVE
FINISH
! （5）進入一般后處理模塊，繪制變形圖定義單元表，提取應力結果和節點位移
/POST1
/VIEW, 1, 1, 1, 1
PLDISP, 2
ETABLE, STRS, S, 1
ESORT, STRS
*GET, SMAX1, SORT, , MAX
PRNSOL, DOF
LFT_NODE = NODE(0, 0, 0)
*GET, DEFL1, NODE, LFT_NODE, U, Z
*STATUS, PARM
! （6）將計算結果保存到數據庫
SAVE, TABLE_1
FINISH
! （7）改為三維梁單元BEAM44，重新計算
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.9(2), BENDING OF A TAPERED PLATE WITH TAPERED BEAM ELEMENT BEAM44.
! （8）定義分析類型，單元類型和實常數
ANTYPE, STATIC
ET, 1, BEAM44
*DO, I, 1, 10
  R, I, 1, 1, (I-1)*76.2*12.7*12.7*12.7/120, 6.35, 1
  RMORE, 1, 1, I*76.2*12.7*12.7*12.7/120, 6.35, 1
*ENDDO
RMOD, 1, 3, 76.2*12.7*12.7*12.7/120/2
RLIST
MP, EX, 1, 207E3
MP, GXY, 1, 207E3/2.6
! （9）定義節點位置
N, 1
N, 11, 508
FILL
N, 12, , , 10
NGEN, 10, 1, 12
! (10) 定義梁單元
E, 1, 2, 12
EGEN, 10, 1, 1, , , , , 1
! (11) 施加位移約束條件
D, 11, ALL
D, 1, UY, , , 10, , ROTX, ROTZ
F, 1, FZ, -44.483
OUTPR, ALL, ALL
FINISH
! (12) 在求解模塊中求解
/SOLU
SOLVE
FINISH
! (13) 在后處理模塊中，繪制變形圖，定義單元表，提取應力計算結果
/POST1
/VIEW, 1, 1, 1, 1
PLDISP, 2
ETABLE, STRS, NMISC, 1
ESORT, STRS
*GET, SMAX2, SORT, , MAX
PRNSOL, DOF
LFT_NODE = NODE (0, 0, 0)
*GET, DEFL2, NODE, LFT_NODE, U, Z
SAVE, TABLE_2
! (14) 從數據庫中恢復數據，并顯示前后兩次的計算結果
RESUME, TABLE_1
*STATUS, PARM
RESUME, TABLE_2
*STATUS, PARM
FINISH