! 3.7  懸臂梁的雙向彎曲
! 本程序來源于邢靜忠編著的《ANSYS應用實例與分析》，科學出版社，2006年
!
Finish
/CLEAR, START
/FILNAME, EX3.7
/PREP7
/TITLE, EX3.7(1), STRAIGHT CANTILEVER BEAM BY SOLID5 ELEMENT.
! （1）利用六面體單元SOLID5計算懸臂梁的組合變形
ANTYPE, STATIC
ET, 1, SOLID5, 2
MP, EX, 1, 69E3
MP, NUXY, 1, 0.3
! （2）定義懸臂梁上的8個的關鍵點
K, 1
K, 2, 152.4
KGEN, 2, 1, 2, 1, , 5.08
KGEN, 2, 1, 4, 1, , , 2.54
! 上面兩行命令完成了節點3到4的定義和節點5到8的位置定義
! （3）定義一條邊線，指定這條線剖分單元的個數和一般單元的尺寸
L, 1, 2
SMRT, OFF
LESIZE, ALL, , , 10
ESIZE, 25.4
V, 1, 2, 4, 3, 5, 6, 8, 7
VMESH, 1
! （4）選擇左側截面處的所有節點，并固定這些節點。在右側的所有節點上施加集中力
NSEL, S, LOC, X, 0
D, ALL, ALL
NSEL, ALL
FK, 2, FX, 4.4483/4
*REPEAT, 4, 2
NOORDER
FINISH
! （5）求解在自由端拉力作用下懸臂梁的變形
/SOLU
SOLVE
! （6）改變荷載，計算在Y方向的集中力作用下的情形
FKDELE, ALL, FX
FK, 2, FY, 4.4483/4
*REPEAT, 4, 2
SOLVE
! （7）改變荷載，計算在Z方向的集中力作用下的情形
FKDELE, ALL, FY
FK, 2, FZ, 4.4483/4
*REPEAT, 4, 2
SOLVE
FINISH
! （8）進入一般后處理模塊
/POST1
CSYS, 0
! （9）定義宏程序，完成自由端位移結果的處理
*CREATE, MAC
SET, ARG1, 1
LCDEF, ARG1, ARG1
NSEL, S, LOC, X, 152.4
PRNSOL, U, COMP
LCFACT, ARG1, ARG2
LCASE, ARG1
PRNSOL, U, COMP
*END
! (10) 使用上面定義的宏程序處理第一個荷載工況
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX1, NODE, N1, U, X
! (11) 處理第2個荷載步的計算結果
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY1, NODE, N1, U, Y
! (12) 處理第3個荷載步的計算結果
*USE, MAC, 3, (1/10.9646)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ1, NODE, N1, U, Z
! (13) 將第一種情況的計算結果保存到數據庫
SAVE, TABLE_1
FINISH
! (14) 改變單元類型，重新分析矩形截面懸臂梁在端部集中力作用下的變形
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.7(2), STRAIGHT CANTILEVER BEAM by SOLID92 ELEMENT.
SMRT, OFF
MOPT, VMESH, MAIN
MOPT, AMESH, ALTE
! (15) 使用10節點四面體單元SOLID92
ANTYPE, STATIC
ET, 1, SOLID92
MP, EX, 1, 69E3
MP, PRXY, 1, 0.3
K, 1
K, 2, , 5.08
KGEN, 2, 1, 2, 1, , , 2.54
KGEN, 2, 1, 4, 1, 152.4/9
ESIZE, 25.4
V, 1, 2, 4, 3, 5, 6, 8, 7
VMESH, 1
! (16) 利用第1塊體的單元模式，生成其余的8部分單元，定義固定端部的約束
VGEN, 9, 1, 1, 1, 152.4/9, , , 4
NSEL, S, LOC, X, 0
D, ALL, ALL
SAVE
! (17) 獲取相應節點的編號，并在這些節點上施加荷載
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 1.27
*GET, MIDD, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 5.08
NSEL, R, LOC, Z, 1.27
*GET, TOPP, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 0.0
NSEL, R, LOC, Z, 1.27
*GET, BOTT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 2.54
*GET, LFT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, .00
*GET, RGHT, NDMX
NSEL, ALL
! (18) 給上面選擇出的這些節點施加沿著X方向的軸向荷載
F, RGHT, FX, 4.4483/6
F, LFT, FX, 4.4483/6
F, TOPP, FX, 4.4483/6
F, BOTT, FX, 4.4483/6
F, MIDD, FX, 4.4483/3
FINISH
! (19) 進入求解模塊開始計算
/SOLU
SOLVE
! (20) 改變荷載，給上面選擇出的這些節點施加沿著Y方向的軸向荷載，重新計算
FDELE, ALL
F, RGHT, FY, 4.4483/6
F, LFT, FY, 4.4483/6
F, TOPP, FY, 4.4483/6
F, BOTT, FY, 4.4483/6
F, MIDD, FY, 4.4483/3
SOLVE
! (21) 改變荷載，給上面選擇出的這些節點施加沿著Z方向的軸向荷載，重新計算
FDELE, ALL
F, RGHT, FZ, 4.4483/6
F, LFT, FZ, 4.4483/6
F, TOPP, FZ, 4.4483/6
F, BOTT, FZ, 4.4483/6
F, MIDD, FZ, 4.4483/3
SOLVE
FINISH
! (22) 利用前面定義的宏，處理前面計算的3種荷載工況的位移
/POST1
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX2, NODE, N1, U, X
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY2, NODE, N1, U, Y
*USE, MAC, 3, (1/.432)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ2, NODE, N1, U, Z
! (23) 將第二種情況的計算結果保存到數據庫
SAVE, TABLE_2
FINISH
! (24) 改變為10節點四面體耦合場單元SOLID98，重新計算懸臂梁在端部集中力作用下的雙向彎曲
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.7(3), STRAIGHT CANTILEVER BEAM by SOLID98 ELEMENT.
SMRT, OFF
MOPT, VMESH, MAIN
MOPT, AMESH, ALTE
RESUME
ET, 1, SOLID98, 2
! (25) 選擇自由端有荷載的節點
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 1.27
*GET, MIDD, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 5.08
NSEL, R, LOC, Z, 1.27
*GET, TOPP, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 0.0
NSEL, R, LOC, Z, 1.27
*GET, BOTT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 2.54
*GET, LFT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, .00
*GET, RGHT, NDMX
NSEL, ALL
! (26) 給上面選擇出的這些節點施加沿著X方向的軸向荷載，開始計算
F, RGHT, FX, 4.4483/6
F, LFT, FX, 4.4483/6
F, TOPP, FX, 4.4483/6
F, BOTT, FX, 4.4483/6
F, MIDD, FX, 4.4483/3
FINISH
/SOLU
SOLVE
! (27) 改變荷載，給上面選擇出的這些節點施加沿著Y方向的軸向荷載，重新計算
FDELE, ALL
F, RGHT, FY, 4.4483/6
F, LFT, FY, 4.4483/6
F, TOPP, FY, 4.4483/6
F, BOTT, FY, 4.4483/6
F, MIDD, FY, 4.4483/3
SOLVE
! (28) 改變荷載，給上面選擇出的這些節點施加沿著Z方向的軸向荷載，重新計算
FDELE, ALL
F, RGHT, FZ, 4.4483/6
F, LFT, FZ, 4.4483/6
F, TOPP, FZ, 4.4483/6
F, BOTT, FZ, 4.4483/6
F, MIDD, FZ, 4.4483/3
SOLVE
FINISH
! (29) 在后處理模塊中，利用前面定義的宏，處理前面計算的3種荷載工況的位移
/POST1
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX3, NODE, N1, U, X
!
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY3, NODE, N1, U, Y
!
*USE, MAC, 3, (1/.432)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ3, NODE, N1, U, Z
! (30) 將第三種情況的計算結果保存到數據庫
SAVE, TABLE_3
FINISH
!
! (31) 改變為20節點四面體3D單元SOLID147，重新計算懸臂梁在端部集中力作用下的雙向彎曲
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.7(4), STRAIGHT CANTILEVER BEAM by SOLID147 ELEMENT.
SMRT, OFF
MOPT, VMESH, ALTE
MOPT, AMESH, ALTE
ANTYPE, STATIC
ET, 1, SOLID147
MP, EX, 1, 69E3
MP, NUXY, 1, 0.3
! (32) 定義梁上的8個關鍵點
K, 1
K, 2, 152.4
KGEN, 2, 1, 2, 1, , 5.08
KGEN, 2, 1, 4, 1, , , 2.54
! (33) 定義一條邊線，指定這條線剖分單元的個數和一般單元的尺寸
L, 1, 2
LESIZE, ALL, , , 10
ESIZE, 25.4
V, 1, 2, 4, 3, 5, 6, 8, 7
VMESH, 1
! (34) 選擇并固定左側截面處的所有節點，在右側的所有節點上施加集中力
NSEL, S, LOC, X, 0
D, ALL, ALL
NSEL, ALL
FK, 2, FX, 4.4483/4
*REPEAT, 4, 2
NOORDER
FINISH
! (35) 分別求解在自由端拉力和橫向力作用下懸臂梁的軸向變形和橫向撓度。
/SOLU
SOLVE
!
FKDELE, ALL, FX
FK, 2, FY, 1.1121
*REPEAT, 4, 2
SOLVE
!
FKDELE, ALL, FY
FK, 2, FZ, 1.1121
*REPEAT, 4, 2
SOLVE
FINISH
! (36) 進入后處理模塊，準備提取有限元結果
/POST1
CSYS, 0
! (37) 定義宏程序，完成自由端位移計算結果的處理
*CREATE, MAC
SET, ARG1, 1
LCDEF, ARG1, ARG1
NSEL, S, LOC, X, 152.4
PRNSOL, U, COMP
LCFACT, ARG1, ARG2
LCASE, ARG1
PRNSOL, U, COMP
*END
! (38) 使用上面定義的宏程序處理第1個工況
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX4, NODE, N1, U, X
! (39) 提取第二步結果
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY4, NODE, N1, U, Y
! (40) 提取第3步結果
*USE, MAC, 3, (1/10.9646)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ4, NODE, N1, U, Z
! (41) 將第四種情況的計算結果保存到數據庫
SAVE, TABLE_4
! (42) 從第1個表中恢復數據，繪制單元應力云圖
RESUME, TABLE_1
NSEL, ALL
/VIEW, 1, 2, 1, 1
EPLOT
/TYPE, 1, CAP
/DIST, 1, 5.08
/FOCUS, 1, .3, .15, .09
/Auto
PLNSOL, S, X
*STATUS, PARM
! (43) 從結果文件中讀入計算結果，并顯示
RESUME, TABLE_2
*STATUS, PARM
RESUME, TABLE_3
*STATUS, PARM
RESUME, TABLE_4
*STATUS, PARM
! (44) 刪除宏文件，臨時文件TABLE_*
/DELETE, MAC
/DELETE, TABLE_1
/DELETE, TABLE_2
/DELETE, TABLE_3
/DELETE, TABLE_4
FINISH