! 3.14  自行車車架變形和內力分析
! 本程序來源于邢靜忠編著的《ANSYS應用實例與分析》，科學出版社，2006年
!
FINISH
/Clear
/FILNAME, EX3.14
/TITLE, EX3.14, 3D Bicycle Space Frame.
! （1）進入前處理模塊, 定義基本參數
/PREP7
x1 = 500  $  x2 = 825
y1 = 325  $  y2 = 400  $  z1 = 50
/Pnum, KP, 1
/Pnum, Line, 1
/VIEW, 1, 1, 2, 3
! （2）定義關鍵點
K, 1, 0, y1, 0
K, 2, 0, y2, 0  $  K, 3, x1, y2, 0  $  K, 4, x1, 0, 0
K, 5, x2, 0, z1    $  K, 6, x2, 0, -z1
! （3）過關鍵點定義線
L, 1, 2
L, 2, 3
L, 3, 4
L, 4, 1
L, 4, 6  $  L, 4, 5
L, 3, 5  $  L, 3, 6
! （4）定義單元類型和實常數
ET, 1, PIPE16
KEYOPT, 1, 6, 1
! 定義實常數
R, 1, 25, 2
R, 2, 12, 1
! （5） 定義材料參數
MP, EX, 1, 70000
MP, PRXY, 1, 0.33
! （6）定義單元尺寸后剖分單元
LESIZE, ALL, 50
! 開始剖分線單元
REAL, 1
LMESH, 1, 6, 1
REAL, 2
LMESH, 7, 8
/EShape, 1
Eplot
FINISH
! （7）進入求解模塊后指定位移約束和荷載，并開始求解
/SOLU
ANTYPE, 0
! 在關鍵點上施加位移約束(用dk命令)
DK, 1, UX, 0, , , UY, UZ
DK, 5, UY, 0, , , UZ
DK, 6, UY, 0, , , UZ
! 在關鍵點上定義荷載 (用fk命令)
FK, 3, FY, -600
FK, 4, FY, -200
SOLVE
FINISH
! （8）定義單元表提取計算結果
/post1
! 命令格式：ETable, 單元表名稱，數據項名稱，數據編號
ETable, vonmi0, nmisc, 5
ETable, vonmj0, nmisc, 45
! 0度位置的軸向力
ETable, axii0, ls, 1
ETable, axij0, ls, 33
! 軸力引起的軸向應力(不含彎曲引起的應力)
ETable, diri, smisc, 13
ETable, dirj, smisc, 15
! （9）在多個窗口中同時顯示多種結果
/WIND, ALL, OFF
/WIND, 1, LTOP
/WIND, 2, RTOP
/WIND, 3, LBOT
/WIND, 4, RBOT
GPLOT
/GCMD, 1, PLDISP, 2
/GCMD, 2, PLNSOL, U, SUM, 0, 1
! 用圖形顯示單元內力分布：PLLS, i端內力名稱, j端內力名稱
/GCMD, 3, PLLS, vonmi0, vonmj0
/GCMD, 4, PLLS, axii0, axij0
GPLOT
/CONT, 2, 9, 0, , 0.27
/CONT, 3, 9, 0, , 18
/CONT, 4, 9, -18, , 18
/FOCUS, ALL, -0.34, , , 1
/Replot
PRNSOL, DOF
FINISH