! 5.6  懸臂長板的大撓度彎曲
! 本程序來源于邢靜忠編著的《ANSYS應用實例與分析》，科學出版社，2006年
!
FINISH
/CLEAR, NOSTART
! (1)設置工程參數、分析類型、單元類型、實常數和材料參數
/FILNAM, EX5.6(1)
/PREP7
/TITLE, EX5.6(1), LARGE DEFLECTION OF A CANTILEVERED PLATE.
/NOPR
SMRT, OFF
ANTYPE, STATIC
NLGEOM, ON
ET, 1, SHELL43
R, 1, 1
MP, EX, 1, 1800
MP, NUXY, , 0
! (2)定義關鍵點、線和面, 并剖分為面單元
K, 1
K, 2, 12
K, 3, 12, 1
K, 4, , 1
L, 1, 2
L, 3, 4
LESIZE, ALL, , , 2
ESIZE, , 1
A, 1, 2, 3, 4
/VIEW, 1, 0.61, -0.64, 0.47
/VUP, 1, Z
AMESH, 1
! (3)施加位移約束和荷載力
NSEL, S, LOC, X
D, ALL, ALL
NSEL, S, LOC, X, 12
CP, 1, ROTY, ALL
TORQ=15.708
F, 2, MY, TORQ
NSEL, ALL
FINISH
! (4)進入求解選模塊, 設置求解選項后, 開始求解
/SOLU
AUTOTS, ON
NSUBST, 20
LNSRCH, ON
OUTPR, BASIC, LAST
OUTRES, ALL, ALL
SOLVE
FINISH
! (5)在后處理模塊, 顯示應力和位移計算結果
/POST1
RSYS, SOLU
SET, 1
SHELL, TOP
PRNSOL, S, COMP
PRNSOL, DOF
! (6)提取結果后存入變量
*GET, UX_N4, NODE, 4, U, X
*GET, UZ_N4, NODE, 4, U, Z
*GET, ROTY_N4, NODE, 4, ROT, Y
*GET, STRSS_N1, NODE, 1, S, X
! (7)保存計算結果
SAVE, TABLE_1
FINISH
! (8)重用改用有限應變層合殼單元SHELL181計算
/CLEAR, NOSTART
/FILNAM, EX5.6(2)
/PREP7
/TITLE, EX5.6(2), LARGE DEFLECTION OF A CANTILEVERED PLATE(SHELL181).
SMRT, OFF
/NOPR
ANTYPE, STATIC
NLGEOM, ON
ET, 1, SHELL181
R, 1, 1
RMORE, , , , , 10.0
MP, EX, 1, 1800
MP, NUXY, , 0
! (9)定義關鍵點、線和面, 并將面剖分為面單元
K, 1
K, 2, 12
K, 3, 12, 1
K, 4, , 1
L, 1, 2
L, 3, 4
LESIZE, ALL, , , 2
ESIZE, , 1
A, 1, 2, 3, 4
AMESH, 1
! (10) 施加位移約束和荷載力
NSEL, S, LOC, X
D, ALL, ALL
NSEL, S, LOC, X, 12
CP, 1, ROTY, ALL
TORQ=7.854
F, 2, MY, TORQ
NSEL, ALL
FINISH
! (11) 進入求解模塊, 設置求解選項后, 開始求解
/SOLU
AUTOTS, ON
NSUBST, 10
LNSRCH, ON
OUTPR, BASIC, LAST
OUTRES, ALL, ALL
SOLVE
FINISH
! (12)在求解模塊重啟動分析
/SOLU
ANTYPE, , REST
F, 2, MY, TORQ*2
SOLVE
FINISH
! (13)在后處理模塊, 顯示計算結果
/POST1
RSYS, SOLU
SET, 2
SHELL, TOP
PRNSOL, S, COMP
PRNSOL, DOF
*GET, UX_N4, NODE, 4, U, X
*GET, UZ_N4, NODE, 4, U, Z
*GET, ROTY_N4, NODE, 4, ROT, Y
*GET, STRSS_N1, NODE, 1, S, X
! (14) 顯示計算結果
*STATUS, PARM
Resume, TABLE_1
*STATUS, PARM
Finish