! 5.1  含橢圓孔的橢圓薄膜在外部張力作用下的靜力分析
! 本程序來源于邢靜忠編著的《ANSYS應用實例與分析》，科學出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）設置工程選項, 分析類型、單元類型和材料參數
/FILNAME, EX5.1(1)
/PREP7
SMRT, OFF
/TITLE, EX5.1(1), ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD(PLANE42).
/COM, USING 2-D STRUCTURAL SOLID, PLANE42
ANTYPE, STATIC
ET, 1, PLANE42, , , 3
MP, EX, 1, 210E9
MP, NUXY, 1, 0.3
R, 1, 0.1
! （2）在橢圓坐標系下, 定義關鍵點、線和面
! LOCAL, KCN, KCS, XC, YC, ZC, THXY, THYZ, THZX, PAR1, PAR2
LOCAL, 11, 1, , , , , , , 0.5
K, 1, 2, 90
K, 2, 2, 0
L, 1, 2
LOCAL, 12, 1, , , , , , , 0.8461585
K, 3, 3.25, 90
K, 4, 3.25, 0
L, 3, 4
CSYS, 0
L, 2, 4
L, 1, 3
AL, 2, 4, 1, 3
! (3)在相應的線上施加位移約束
DL, 4, 1, SYMM
DL, 3, 1, SYMM
SFL, 2, PRES, -10E6
MSHK, 2
MSHA, 0, 2D
SAVE
FINISH
! (4)執行自適應網格剖分和求解宏程序, 執行自定義的后處理宏程序
ADAPT, 3, 7, , , 1
/Post1
EPLOT
PLDISP, 1
PLNSOL, S, X
PLNSOL, S, Y
PLNSOL, S, 1
FINISH
! (5)定義完成后處理功能的宏程序MAC
*CREATE, MAC
/Graphics, Full
/POST1
PRERR
NSEL, S, LOC, Y, 0.0
NSEL, R, LOC, X, 2.0
*GET, MNODE, NODE, , NUM, MAX
*GET, SY_D, NODE, MNODE, S, Y
NSEL, ALL
ESEL, ALL
*STATUS, PARM
/Graphics, Power
*END
! (6)用前定義的宏程序完成后處理, 將計算結果保存到變量
*USE, MAC
SAVE, TABLE1
FINISH
! (7)改變單元為PLANE82, 重新計算
/CLEAR, NOSTART
/FILNAME, EX5.1(2)
/PREP7
SMRT, OFF
RESUME, EX5.1(1).db
/TITLE, EX5.1(2), ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD(PLANE82).
ET, 1, PLANE82, , , 3
FINISH
! （8）執行自適應網格宏程序, 執行自定義的后處理宏程序
ADAPT, 2, 5, , , 1
/Post1
/WINDOW, 5, OFF
/WINDOW, 1, FULL
PLNSOL, S, EQV
PLDISP, 1
PLNSOL, S, X
PLNSOL, S, Y
PLNSOL, S, 1
FINISH
! （9）用前定義的宏程序完成后處理, 將計算結果保存到變量
*USE, MAC
FINISH