ORG 0000H
       AJMP MAIN
       ORG 0030H
  MAIN:
       ADDR8279_1 EQU    0BFFFH
       ADDR8279_2 EQU    0BFFEH
  
       MOV      DPTR,#ADDR8279_1
       MOV      A,#0D1H
       MOVX     @DPTR,A
  WAIT:MOVX     A,@DPTR
       JB       ACC.7,WAIT
       MOV      A,#00H
       MOVX     @DPTR,A
       MOV      A,#2CH
       MOVX     @DPTR,A
       
       CLR 00H 
       CLR 01H
CHAXUN:LCALL SEACH 
       JBC 00H,MAIN1 
       SJMP CHAXUN 
 MAIN1:SETB IT1
       SETB EA
       SETB EX1
ADC0809:MOV DPTR,#8100H     ;；ADC0809首址
       MOVX @DPTR,A        ;；啟動AD轉換
  HERE:SETB P1.0
       JNB  P1.0,SEVER1  
       SJMP HERE
SEVER1:MOVX A,@DPTR
       MOV R3,A
       MOV DPTR ,#8000H    ;D/A口地址 
       MOVX @DPTR,A  
       MOV R2,#00H
       MOV R7,#60H
       MOV R6,#09H
       LCALL MULD
       MOV  R7,#0FFH
       LCALL  DV31
       MOV A,R4 
       MOV R6,A 
       MOV A,R5 
       MOV R7,A 
       LCALL HB2
       MOV 35H,R5 
       MOV 34H,R4 
       ACALL TRANS
       LCALL LED
       LCALL SEACH 
       JBC 01H ,NEXT  
       AJMP  ADC0809 
 NEXT:MOV DPTR,#8000H
      MOV A,#00H
      MOVX @DPTR,A
      AJMP MAIN   
   
TRANS: MOV R0,#35H
       MOV R1,#30H
       MOV R6,#02H
  LAST:MOV      A,@R0
       ANL      A,#0FH
       MOV      @R1,A
       MOV      A,@R0
       ANL      A,#0F0H
       SWAP     A
       INC  R1
       MOV      @R1,A
       INC  R1
       DEC R0
       DJNZ R6,LAST
       RET   
   
   KEY:MOV  DPTR ,#ADDR8279_1
       MOV  A,#40H
	   MOVX @DPTR,A
	   MOV DPTR,#ADDR8279_2
	   MOVX A,@DPTR
	   ANL A,#3FH

       CJNE A,#0AH,KEY1             
       SETB 00H
       AJMP RETUN    
      
  KEY1:CJNE A,#0BH,RETUN 
       SETB 01H  
 RETUN:RET   
   
 
  
  
  
   ;;; （５）  標號： ＭＵＬＤ    功能：雙字節二進制無符號數乘法

;;入口條件：被乘數在R2、R3中，乘數在R6、R7中。
;;出口信息：乘積在R2、R3、R4、R5中。
;;;影響資源：PSW、A、B、R2～R7    堆棧需求：  ２字節

MULD:	MOV	A,R3	;;；計算R3乘R7
	MOV	B,R7
	MUL	AB
	MOV	R4,B         ;;	；暫存部分積
	MOV	R5,A
	MOV	A,R3	  ;; ；計算R3乘R6
	MOV	B,R6
	MUL	AB
	ADD	A,R4	   ;;;；累加部分積
	MOV	R4,A
	CLR	A
	ADDC	A,B
	MOV	R3,A
	MOV	A,R2	;;;；計算R2乘R7
	MOV	B,R7
	MUL	AB
	ADD	A,R4	;;;；累加部分積
	MOV	R4,A
	MOV	A,R3
	ADDC	A,B 
	MOV	R3,A
	CLR	A
	RLC	A
	XCH	A,R2	;;;；計算R2乘R6
	MOV	B,R6
	MUL	AB
	ADD	A,R3	;;;；累加部分積
	MOV	R3,A
	MOV	A,R2
	ADDC	A,B
	MOV	R2,A
	RET
   ;; （９）  標號：  ＤＶ３１    功能：三字節二進制無符號數除以單字節二進制數

;;;入口條件：被除數在R3、R4、R5中，除數在R7中。
;;出口信息：OV=0 時，雙字節商在R4、R5中，OV=1 時溢出。
;;影響資源：PSW、A、B、R2～R7    堆棧需求：  ２字節

DV31:	CLR	C
	MOV	A,R3
	SUBB	A,R7
	JC	DV30
	SETB	OV	;;；商溢出
	RET
DV30:	MOV	R2,#10H	      ;;；求R3R4R5／R7－→R4R5
DM23:	CLR	C
	MOV	A,R5
	RLC	A
	MOV	R5,A
	MOV	A,R4
	RLC	A
	MOV	R4,A
	MOV	A,R3
	RLC	A
	MOV	R3,A
	MOV	F0,C
	CLR	C
	SUBB	A,R7
	ANL	C,/F0
	JC	DM24
	MOV	R3,A
	INC	R5
DM24:	DJNZ	R2,DM23
	MOV	A,R3	            ;；四舍五入
	ADD	A,R3
	JC	DM25
	SUBB	A,R7
	JC	DM26
DM25:	INC	R5
	MOV	A,R5
	JNZ	DM26
	INC	R4
DM26:	CLR	OV
	RET            ;;; ；商在R4R5中 
  
 
 ;    （１７）  標號： ＨＢ２   功能：雙字節十六進制整數轉換成雙字節ＢＣＤ碼整數

;入口條件：待轉換的雙字節十六進制整數在R6、R7中。
;出口信息：轉換后的三字節ＢＣＤ碼整數在R3、R4、R5中。
;;影響資源：PSW、A、R2～R7    堆棧需求：  ２字節

HB2:	CLR	A	    ;；ＢＣＤ碼初始化
	MOV	R3,A
	MOV	R4,A
	MOV	R5,A
	MOV	R2,#10H	       ;；轉換雙字節十六進制整數
HB3:	MOV	A,R7                   ;	；從高端移出待轉換數的一位到CY中
	RLC	A
	MOV	R7,A
	MOV	A,R6
	RLC	A
	MOV	R6,A
	MOV	A,R5	               ;；ＢＣＤ碼帶進位自身相加，相當于乘２
	ADDC	A,R5
	DA	A	                  ;;;;;；十進制調整
	MOV	R5,A
	MOV	A,R4
	ADDC	A,R4
	DA	A
	MOV	R4,A
	MOV	A,R3
	ADDC	A,R3
	MOV	R3,A	                    ;；雙字節十六進制數的萬位數不超過６，不用調整
	DJNZ	R2,HB3                      ;	；處理完１６ｂｉｔ
	RET 	
   
 
   LED:MOV      DPTR,#ADDR8279_1
       MOV      A,#90H
       MOVX      @DPTR,A
       MOV      R1,#30H
       MOV      R7,#04H
       MOV      DPTR,#ADDR8279_2
  LOOP:MOV      A,@R1
       ADD      A,#05H
       MOVC     A,@A+PC
       MOVX     @DPTR,A
       INC      R1
       DJNZ     R7,LOOP
       RET
       DB       3FH,06H,5BH,4FH,66H,6DH
       DB       7DH,07H,7FH,6FH  
SEACH:MOV      DPTR,#ADDR8279_1   
       MOVX     A,@DPTR
       ANL A,#07H
       JZ  RETUN4
       LJMP KEY
RETUN4:RET
END