;********************************************************
;使用LCD的溫度控制器____2004.12.XUJING.
;-------------------------------------------
;00H:18B20存在標志位,0表示存在,1表示不存在              *
;01H:溫度設置標記位,1表示設定高溫限值,0表示設定低溫限值.*
;02H:暫未用,03H:控制器開關標記,0:表示溫度低,1表示溫度高
;注:;每次讀寫應先reset,然后跳過rom檢測,再之后才能向18b20發命令.
;注;;MOV A,#4EH;應該是先送此條命令然后馬上傳兩個字節的溫度數據,中間不能用reset!.不然就出問題
;*注:程序編制中遇到2個主要錯誤:子程序中少寫了ret而出現未知錯誤,
;標記位地址與字節地址重疊.
;對于不同的18b20這個程序可能有些問題,我遇到是的將暫存器的數據拷回18b20中數據無法保存.
;換過18b20就正常了.
;估計不同的18b20之間時序可能有微小的差別,或者是18b20損壞所致.
;*
;********************************************************
ORG 00H
JMP INPORT
ORG 0BH
;JMP TM0
ORG 30H
INPORT:
TMP_H EQU 29H ;溫度高字節
TMP_L EQU 28H
RS EQU P3.7;確定具體硬件的連接方式
RW EQU P3.6 ;確定具體硬件的連接方式
E  EQU P3.5 ;確定具體硬件的連接方式
KEY_SET EQU P3.0
KEY_UP  EQU P3.1
KEY_DOWN EQU P3.2
DS18B20_FLAG EQU 70h
SET_FLAG EQU 01H
FLASH_FLAG EQU 02H
K_ON EQU 03H
MOV 25H,#0FFH ;位00h-07h全部置1
MOV R4,#14
MOV TMOD,#01H
MOV TL0,#0B0H
MOV TH0,#3CH
MOV IE,#10000010B ;(8:總控,2:定時0溢出中斷控制位)


LCD_INIT:
;15MS
MOV R6,#30  ； 00110000
CALL DELAY_BY_R6 ;15ms
MOV P1,#38H ;寫38h
ACALL WRITE_NOT_CHECK_BUSY
MOV R6,#10；   00010000
CALL DELAY_BY_R6 ;5ms
MOV P1,#38H
ACALL WRITE_NOT_CHECK_BUSY
MOV R6,#10
CALL DELAY_BY_R6 ;5ms
;-----設轉初始值
SETB E
MOV P1,#00000001B ;清屏并光標復位
ACALL ENABLE;調用寫入命令子程序
MOV P1,#00111000B ;8位2行5x7點陣
ACALL ENABLE ;調用寫入命令子程序
MOV P1,#00001110B ;顯示器開、光標開、光標允許閃爍
ACALL ENABLE ;調用寫入命令子程序
MOV P1,#00000110B;文字不動，光標自動右移
ACALL ENABLE ;調用寫入命令子程序


STORE_DEFINE_DATA: ;把自定義字符存入CGRAM
MOV P1,#40H ;CGRAM起始地址
ACALL ENABLE
MOV R2,#8
MOV DPTR,#DEFINE_DATA
MOV R3,#0
NEXTP:
MOV A,R3
MOVC A,@A+DPTR
MOV P1,A
CALL WRITE_DATA_TO_LCD
INC R3
DJNZ R2,NEXTP

;****************主程序*******************
START:
CALL RESET
JNB  70h,MAIN1
MOV P1,#0C0H ;寫入顯示起始地址（第二行第一個位置）
ACALL ENABLE ;調用寫入命令子程序

DS18B20_NOT_READY:
CALL DISPLAY_18B20_ERROR

LOOP1:
CALL RESET
JNB 70h,MAIN1
JMP LOOP1 ;如果栓測不到18b20程序下面不執行

MAIN1:
MOV P1,#00000001B ;清屏并光標復位
ACALL ENABLE;調用寫入命令子程序
CALL DISPLAY_WATING ;等待第一次結果.
CALL SKIP_ROM
CALL TEMP_CONV
CALL DELAY_600MS
MOV P1,#00000001B ;清屏并光標復位
ACALL ENABLE;調用寫入命令子程序




MAIN :
CALL RESET
CALL SKIP_ROM
CALL RECALL_EPROM ;調入溫度限值.
MAIN_MAIN:
CALL READ_TEMP ;讀18b20的內部溫度
JB 70h,DS18B20_NOT_READY ;中途失敗!
CALL DATA_CONV ; 數據轉換
CALL DISPLAY_18B20_TEMP
CALL DISPLAY_18B20_TEMP_XZ;顯示限值.
CALL CONTROL
JNB KEY_SET,S1
JMP MAIN_MAIN


CONTROL:
JNB 03H,CONTROL1
LCALL DISPLAY_OFF
AJMP CONTROL_END
CONTROL1:
LCALL DISPLAY_ON
CONTROL_END:
RET

S1:
LCALL DELAY_2MS ;延時消抖
JB KEY_SET,MAIN
JNB KEY_SET,$
LCALL KEY ;有鍵輸入
AJMP MAIN


;***************鍵處理程序******************
KEY: SETB 01H
KEY_IN:;有鍵輸入的程序
MOV P1,#00000001B ;清屏并光標復位
ACALL ENABLE;調用寫入命令子程序
JNB 01H,DSP_SET_L ;01如果是0,則顯示L:
DSP_SET_H: ;顯示高溫的限值
MOV P1,#10000000B
ACALL DISPLAY_SETING_TEMP_H ;顯示SETING_TEMP:H ..
MOV DPTR,#LED_DATA
MOV R1,42H ;碼表初值
MOV R0,#1;字數
CALL DISPLAY
;---------------顯示溫度限值低位
MOV DPTR,#LED_DATA
MOV R1,41H ;碼表初值
MOV R0,#1;字數
CALL DISPLAY
;---------------顯示溫度限值低位
MOV DPTR,#LED_DATA
MOV R1,40H ;碼表初值
MOV R0,#1;字數
CALL DISPLAY
AJMP KEY_SELECT

DSP_SET_L:;顯示低溫的限值
MOV P1,#10000000B
ACALL DISPLAY_SETING_TEMP_L ;顯示SETING_TEMP:L ..
MOV DPTR,#LED_DATA
MOV R1,45H ;碼表初值
MOV R0,#1;字數
CALL DISPLAY
;---------------顯示溫度限值低位
MOV DPTR,#LED_DATA
MOV R1,44H ;碼表初值
MOV R0,#1;字數
CALL DISPLAY
;---------------顯示溫度限值低位
MOV DPTR,#LED_DATA
MOV R1,43H ;碼表初值
MOV R0,#1;字數
CALL DISPLAY
AJMP KEY_SELECT


KEY_SELECT:
JNB KEY_SET,K_SET
JNB KEY_UP,K_UP
JNB KEY_DOWN,K_DOWN
AJMP KEY_SELECT


K_SET:
LCALL DELAY_2MS
lcall delay_2ms
lcall delay_2ms
JB KEY_SET,KEY_SELECT


MOV R5,#250
KSET_LOOP:
JB KEY_SET,KEY_CPL
LCALL DELAY_2MS
LCALL DELAY_2MS
DJNZ R5,KSET_LOOP
AJMP EXT_KEY


K_UP:
LCALL DELAY_2MS
lcall delay_2ms
JB KEY_UP,KEY_SELECT
JNB  01H,K_UP_LOW

K_UP_HIGH:
JNB KEY_UP,$
MOV A,2AH
INC A
MOV 2AH,A
JMP K_UP_DOWN_END

K_UP_LOW:
JNB KEY_UP,$
MOV A,2BH
INC A
MOV 2BH,A
JMP K_UP_DOWN_END

;*********************

K_DOWN:
LCALL DELAY_2MS
JB KEY_DOWN,KEY_SELECT
JNB  01H,K_DOWN_LOW

K_DOWN_HIGH:
JNB KEY_DOWN,$
MOV A,2AH
DEC A
MOV 2AH,A
JMP K_UP_DOWN_END

K_DOWN_LOW:
JNB KEY_DOWN,$
MOV A,2BH
DEC A
MOV 2BH,A

K_UP_DOWN_END:

MOV A,2AH
MOV B,#10
DIV AB
MOV 40H,B ;高溫限值個位
MOV B,#10
DIV AB
MOV 41H,B;十位
MOV 42H,A;百位
;----------------------------
MOV A,2BH
MOV B,#10
DIV AB
MOV 43H,B ;低溫限值位個位
MOV B,#10
DIV AB
MOV 44H,B ;十位
MOV 45H,A ;百位

AJMP KEY_IN


KEY_CPL:
CPL 01H
AJMP KEY_IN




EXT_KEY:
MOV P1,#00000001B ;清屏并光標復位
CALL ENABLE;調用寫入命令子程序
CALL DISPLAY_SAVE

CALL RESET
CALL SKIP_ROM
MOV A,#4EH
CALL WRITE
MOV A,2AH ;2A數據送高溫限值寄存器.
CALL WRITE
MOV A,2BH ;2B數據送低溫限什寄存器.
CALL WRITE

CALL RESET
CALL SKIP_ROM
MOV A,#48H ;將高低溫限值寄存器數據送18B20-EPROM保存.
CALL WRITE
A_END:

RET







;***************18b20指令子程序**********************
READ_TEMP:  ;讀1820內部溫度子程序.
     CALL RESET
     JB 70h,EXT1
     CALL SKIP_ROM
     CALL TEMP_CONV ;溫度AD變換
     CALL DELAY_600MS  ;時........
     CALL RESET
     CALL SKIP_ROM
     CALL TEMP_GET ;發取溫度的命令
     CALL READ ;接收...
	  EXT1:
     RET

SKIP_ROM:;跳過ROM檢測
    MOV A,#0CCH ;#0CCH為跳過rom命令
    CALL WRITE
    RET

RECALL_EPROM:;重調Eprom
    MOV A,#0B8H
    CALL WRITE
    RET


TEMP_CONV:
    MOV A,#44H ;AD變換
	 CALL WRITE
	 RET

TEMP_GET:
    MOV A ,#0BEH;讀18b20命令
    CALL WRITE
    RET


;****************************18B20基本時序子程序*********************************
RESET:  ;初始化子程序
   SETB P2.0
   NOP
   CLR P2.0    ;拉低
   MOV R3,#150 ; *4=600US
   CALL DELAY_BY_R3
   SETB P2.0    ;拉高
   MOV R3,#15  ; 60US
   CALL DELAY_BY_R3
   MOV R3,#60 ;4個周期*60=240US內檢測
A1: JNB P2.0,A2 ;檢測到低平信號
    DJNZ R3,A1 ;如果沒有應答的低電平信號,返回A1重新檢測,超時后下一行,
    SETB 70h ;DS1820不存在.
    JMP A3
A2: CLR 70h
    MOV R3,120;240US;等恢復時間2*120=240us
    DJNZ R3, $
A3:
   RET
;------------------------

WRITE:
    MOV R2,#8;一個字節為8位
    CLR C ;C位清0 C位用來放A的一位數據,用移位的方法放入C
B1: SETB P2.0
	 NOP
    CLR P2.0
	 MOV R3,#4 ;16US
	 CALL DELAY_BY_R3
	 RRC A        ;把A中的數送入C
	 MOV P2.0,C   ;把C送入總線
    MOV R3,#12    ;48US(一位數據的發送:60us<tx<120us)
	 CALL DELAY_BY_R3
	 SETB P2.0  ;拉高1us結束一位
	 NOP
	 DJNZ R2,B1
         RET

READ:
MOV R1,#4 ;接收4個字節數據依次是1.低位 2.高位. 3.高限 4.低限
MOV R0,#28H;低位放28H;高位放29h (1. 28H,2. 29H 3. 2AH 4. 2BH )
C0: MOV R2,#8;一字節數據8位
C1: CLR C ;清除C
SETB P2.0
NOP
NOP
CLR P2.0 ;拉低.
NOP ;1us秒后拉高?
SETB P2.0
MOV R3,#4  ;16us后采數據
CALL DELAY_BY_R3
MOV C,P2.0 ;讀出18b20的數據
RRC  A ;移入A
MOV R3,#12;48US恢復時間
CALL DELAY_BY_R3
DJNZ R2,C1 ;一個字節收完
MOV @R0,A  ;移入存儲位
INC  R0     ;下一位;29h
DJNZ R1,C0 ;全部取完嗎?沒有重復
RET
;*********************************************************************************



;*****************LCD_控制命令***************
DISPLAY: MOV A,R1
MOVC A,@A+DPTR
MOV P1,A
CALL WRITE_DATA_TO_LCD
INC R1
DJNZ R0,DISPLAY
RET


WRITE_NOT_CHECK_BUSY:
SETB E
NOP
NOP
CLR RS ;寫入控制命令的子程序
CLR RW
CLR E
RET


ENABLE:
SETB E
NOP
NOP