@echo off

rem B.BAT -- V1.3  May 3, 2005

rem This batch file does a "fast incremental rebuild" of the application (or component).

rem You should ONLY use this batch file after you have used the "build"
rem command to successfully build your application (or by directly calling
rem the "build_exe.pl" perl script in the NDK, or by calling the "build_exeWin.exe"
rem pre-compiled perl script in the NDK).

rem This batch file invokes the makefile in the local directory for the application.
rem It assumes the full build has already been done, and the resulting
rem NDK/MPTK  components have already been built.  If you change anything
rem that affects  anything outside this application directory tree, you
rem will have to do a full build before using this b.bat command again.

rem Note that this b.bat command also produces a local build.log file
rem which records the build commands that are executed.

rem To use this b.bat file with your own application, simply copy it into the same
rem directory where the application's "makefile" is located.  You may have to edit the
rem "pushd ..\..\" statement below, if your application is located at a different relative
rem directory level from the directory where the setup.bat file is located at the top
rem of your company directory tree.

rem ---------------------------------------------------------------------
rem Call the setup batch file that sets environment variables:

rem First, save the current disk drive and path to the current directory
rem (must switch to the other dir, run mdssetup.bat, then switch back, or
rem some sde and other paths won't be set up correctly):

rem Save current directory path (containing the app we want to build),
rem and switch to the directory containing mdssetup.bat:

pushd ..\..\

call setup.bat called_from_some_other_batch_file

rem Return to the saved directory we were in when we invoked the pushd, above:

popd

echo:
echo: ===================================
echo      Doing fast incremental build
echo: ===================================
echo:
%_XA_CMD_SHELL% -c "%MAKE% %2 %3 2>&1 | tee build.log"

rem ------------------------------------------------------------
rem Open a new command window, unless there's a command-line parameter that says not to:

if "%1"=="called_from_some_other_setup_file" goto skip_opening_new_cmd_window
if "%1"=="called_from_some_other_batch_file" goto skip_opening_new_cmd_window
if "%_B_BAT_ALREADY_OPENED_NEW_CMD_WINDOW%"=="yes" goto skip_opening_new_cmd_window

rem This opens a new command window with the same environment variables as
rem the current command window.  This is used to leave a command window open
rem if you invoke this batch file by double-clicking it in Windows Explorer
rem (or by invoking it from the command line, although in this case, your don't
rem really need to open another command window).
rem This must be skipped if called from some other batch file, or we won't return
rem to the calling batch file till the new command window is closed.  In that case,
rem the calling batch file is expected to specify the "skip_opening_new_cmd_window"
rem command line parameter when calling this batch file:

set _B_BAT_ALREADY_OPENED_NEW_CMD_WINDOW=yes
@call cmd.exe /K "title %~n0 - (%_CMD_WINDOW_TITLE%)"

:skip_opening_new_cmd_window

:end