;************************************************************
;name: RT12232液晶顯示程序
;day : 2005.08.12
;功能: 用RT12232液晶模塊顯示Nyist  I Love you
;      顯示用的是P0口
;************************************************************
        rs        bit        p3.5
        rw        bit        p3.6
        e        bit        p3.7
        
        org        0000h
        ajmp        main
main:
        nop
        mov        sp,#55h
        acall        delay
        acall        init_lcd                        ;LCD初始化子程序
        mov        a,#82h                ;設置顯示的位置為第1行第2列
        acall        write_com        
        mov        r2,#5                ;要顯示5個數，Nyist
        mov        dptr,#tab1
display:
        clr        a
        movc        a,@a+dptr
        acall        write_dat
        inc        dptr
        djnz        r2,display
        
        mov        a,#91h
        acall        write_com
        mov        r2,#11
        mov        dptr,#tab2
display2:
        clr        a
        movc        a,@a+dptr
        acall        write_dat
        inc        dptr
        djnz        r2,display2
        sjmp        $                ;顯示完成，動態停機
;-------------------------------------------------------
;LCD初始化子程序
;--------------------------------------
init_lcd:
        mov        a,#38h                ;設置成8位總線,二行顯示
        acall        write_com
        mov        a,#01h                ;清屏命令字
        acall        write_com
        mov        a,#06h                ;清標移動，顯示區不移動，讀寫操作后，AC自動加1
        acall        write_com
        mov        a,#0ch                ;開顯示，關光標，不閃爍
        acall        write_com
        ret
;------------------------------------------------------
;寫指令子程序
;--------------------------------------------
write_com:
        push        dph
        push        dpl
        clr        rs                ;選定指令寄存器
        clr        rw                ;寫指令
        mov        p0,a
        setb        e
        nop
        nop
        clr        e
        acall        delay
        pop        dpl
        pop        dph
        ret
;-----------------------------
;寫數據子程序
;-----------------------------
write_dat:
        push        dph
        push        dpl
        setb        rs
        clr        rw
        mov        p0,a
        setb        e
        nop
        nop
        clr        e
        acall        delay
        pop        dpl
        pop        dph
        ret
;-----------------------------
;延時子程序
;-----------------------------
delay:
        mov        r6,#100
delay1:        mov        r7,#100
        djnz        r7,$
        djnz        r6,delay1
        ret
;-----------------------------
tab1:
        db 4eh,79h,69h,73h,74h
          ; N   y   i   s   t
tab2:
        db 49h,20h,4ch,6fh,76h,65h,20h,79h,6fh,75h,21h
          ; I       L   o   v   e       y   o   u   !
        end