--創建一個測試的數據庫
CREATE DATABASE db
GO

--創建兩個登錄
EXEC sp_addlogin 'aa'
EXEC sp_addlogin 'bb'

--設置登錄的默認數據庫為測試數據庫 db
EXEC sp_defaultdb 'aa','db'
EXEC sp_defaultdb 'bb','db'
GO

--授予登錄訪問數據庫的權限(將登錄設置為數據庫的用戶)
USE db
EXEC sp_grantdbaccess 'aa'
EXEC sp_grantdbaccess 'bb'

--創建一個屬于用戶bb的表
CREATE TABLE bb.tb(id int)
GO

--至此,測試環境已經創建好了,使用用戶aa或者bb從查詢分析器登錄,驗證用戶的可用性

--用戶驗證完成后,備份并刪除測試數據庫,演示孤立用戶的產生過程
USE master
BACKUP DATABASE db TO DISK='c:\db.bak' WITH FORMAT
DROP DATABASE db
GO

--刪除登錄,用以模擬目標服務器沒有事先創建登錄時的情況
EXEC sp_droplogin 'aa'
EXEC sp_droplogin 'bb'
GO

--還原測試數據庫
RESTORE DATABASE db FROM DISK='c:\DB.bak'
GO

--查看還原后的測試數據庫的用戶
USE db
EXEC sp_helpuser
/*--結果
UserName GroupName   LoginName DefDBName UserID SID
-------- --------- -------- -------- ----- --------------------------------------------
aa   public    NULL   NULL   5  0x71BA40BA3C89FA43A5DFD74620E81FDA
bb   public    NULL   NULL   6  0xDE41BBF527C4F545AFFA0EBAE864DE40
dbo  db_owner  NULL   NULL   1  0x010500000000000515000000BE604AE3EA4BA8F3E9CE046BF4010000
--*/

--可以看到用戶aa,bb在還原后的數據庫中確實存在,但使用aa或者bb登錄時,會提示"用戶'aa'登錄失敗"
GO

--下面重新建立登錄aa,bb
EXEC sp_addlogin 'aa'
EXEC sp_addlogin 'bb'

--這次可以使用aa,bb登錄,但登錄后無法訪問測試數據庫db
GO

--將登錄設置為測試數據庫的用戶
USE db
EXEC sp_grantdbaccess 'aa'
EXEC sp_grantdbaccess 'bb'
/*--將收到錯誤信息
服務器: 消息 15023，級別 16，狀態 1，過程 sp_grantdbaccess，行 147
當前數據庫中已存在用戶或角色 'aa'。
服務器: 消息 15023，級別 16，狀態 1，過程 sp_grantdbaccess，行 147
當前數據庫中已存在用戶或角色 'bb'。
--*/
GO

--嘗試刪除測試數據庫中的用戶
EXEC sp_revokedbaccess 'aa'
/* 用戶aa可以正常刪除,因為用戶aa在測試數據庫中沒有對象 */
EXEC sp_revokedbaccess 'bb'
/*--將收到錯誤信息
服務器: 消息 15183，級別 16，狀態 1，過程 sp_MScheck_uid_owns_anything，行 17
該用戶擁有數據庫中的對象，無法除去該用戶。
name        type
----------- -------
tb          U 
--*/

--再次授予登錄aa訪問測試數據庫的權限
EXEC sp_grantdbaccess 'aa'

--這次可以順利授權,并且用aa登錄也可以正常訪問測試數據庫.


/*=================================================================*/
--解決孤立用戶bb

--1. 報告孤立用戶
USE db
EXEC sp_change_users_login 'Report'
GO


--2. 處理孤立用戶
USE db
EXEC sp_change_users_login 'Auto_Fix','bb',null,'bb'