/*--備份指定表到另一數據庫

	備份指定數據庫中的指定表列表到一個新的數據庫

--鄒建 2003.12--*/

/*--調用示例
	--備份數據當前數據庫的所有內容
	exec p_backupdatabase
	
	--備份當前數據庫的指定表
	exec p_backupdatabase @tblist='tb,tb1,tb2'
--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_BackupDataBase]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_BackupDataBase]
GO

CREATE PROCEDURE p_BackupDataBase
@s_dbname sysname='',			--要備份的數據庫名,如果不指定,則備份當前數據庫
@d_dbname sysname='',			--備份生成的數據庫名,如果不指定,則為:@s_dbname+'_bak'
@tblist varchar(8000)=''		--要備份的表名列表,如果不指定,則表示所有用戶表
AS
declare @sql varchar(8000),@err_msg varchar(1000)

--參數檢測
if isnull(@s_dbname,'')='' set @s_dbname=db_name()
if isnull(@d_dbname,'')='' set @d_dbname=@s_dbname+'_bak'
if exists(select 1 from master..sysdatabases where name=@d_dbname)
begin
	set @err_msg='備份的數據庫 ['+@d_dbname+'] 已經存在!'
	goto lb_exit
end
if not exists(select 1 from master..sysdatabases where name=@s_dbname)
begin
	set @err_msg='要備份的數據庫 ['+@d_dbname+'] 不存在!'
	goto lb_exit
end

--創建備份的數據庫
set @sql='create database ['+@d_dbname+']'
exec(@sql)

--備份表
declare @tbname sysname
set @sql='declare tb cursor for
select name from ['+@s_dbname+']..sysobjects 
where status>0 and xtype=''U'''
+case isnull(@tblist,'') when '' then '' 
	else ' and name in('''+replace(@tblist,',',''',''')+''')' end
exec(@sql)
open tb
fetch next from tb into @tbname
while @@fetch_status=0
begin
	set @sql='select * into ['+@d_dbname+']..['+@tbname
		+'] from ['+@s_dbname+']..['+@tbname+']'
	exec(@sql)
	fetch next from tb into @tbname
end
close tb
deallocate tb

lb_exit:
	if @err_msg<>'' raiserror(@err_msg,1,16)
go