#include  "msp430x44x.h"
;******************************************************************************
;   MSP-Test44x Demo - USART0 UART 2400 Ultra-low Power Echo ISR, 32kHz ACLK
;
;   Description; Echo a received character, RX ISR used. Normal mode is LPM3, 
;   USART0 RX interrupt triggers TX Echo. 
;   ACLK = UCLK0 = LFXT1 = 32768Hz, MCLK = SMCLK = DCOCLK
;   Baud rate divider with 32768hz XTAL @2400 = 32768Hz/2400 = 13.65 (000D 6Bh)
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;              
;                MSP430F449
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32768Hz  
;          --|RST          XOUT|-
;            |                 |
;            |             P2.4|-----------> 
;            |                 | 2400 - 8N1
;            |             P2.5|<-----------
;

;------------------------------------------------------------------------------ 
            .pseg code, abs=01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize '449 stackpointer
            call    #Init_Sys               ;
                                            ;   
Mainloop    bis.b   #LPM3,SR                ; Enter LPM3
            jmp     Mainloop                ; Do nothing
                                            ;
;------------------------------------------------------------------------------ 
Init_Sys;   Initalize MSP430 system
;------------------------------------------------------------------------------ 
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupFLL    bis.b   #XCAP14PF,&FLL_CTL0     ; Configure load caps
SetupUART0  mov.b   #SSEL0,&UTCTL0          ; UCLK = ACLK
            mov.b   #00Dh,&UBR00            ; 32k/2400 - 13.65
            mov.b   #000h,&UBR10            ; 32k 2400
            mov.b   #06Bh,&UMCTL0           ; 32k 2400 modulation 
            mov.b   #CHAR,&UCTL0            ; 8-bit characters *SWRST*
            bis.b   #UTXE0+URXE0,&ME1       ; Enable USART0 TXD/RXD
            bis.b   #URXIE0,&IE1            ; Enable USART0 RX interrupt
SetupP2     bis.b   #030h,&P2SEL            ; P2.4,5 = USART0 TXD/RXD
            bis.b   #010h,&P2DIR            ; P2.4 = output direction 
            eint                            ; General enable interrupts
            ret                             ; Return from subroutine
                                            ;             
;------------------------------------------------------------------------------ 
USART0RX_ISR;  Echo back RXed character, confirm TX buffer is ready first
;------------------------------------------------------------------------------ 
TX0         bit.b   #UTXIFG0,&IFG1          ; USART0 TX buffer ready?
            jz      TX0                     ; Jump if TX buffer not ready
            mov.b   &RXBUF0,&TXBUF0         ; TX -> RXed character
            reti                            ; 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x44x       
;------------------------------------------------------------------------------ 
            .pseg reset_vector, abs=0FFFEh                  ; 
            .data      RESET                   ; POR, ext. Reset, Watchdog
            .pseg rx_vector, abs=0FFF2h                  ; 
            .data      USART0RX_ISR            ; USART0 receive
            end