NAME Modules


;定義供外部使用的功能模塊
PUBLIC    _CheckRAM

; 定義 ASM 格式 源程序
      bytes SEGMENT DATA
      PROC  SEGMENT CODE

; Description:  把片外 RAM 空間清零 且 自檢
; INPUT: 無參數傳遞
; OUT :  C =0 OK,  C =1 ERROR
; Author: 吳允平
; Date: 2003.9.12
          PUBLIC ?_CheckRAM?byte		; 參數傳遞段首地址
          RSEG    bytes
          ?_CheckRAM?byte:
          DS      0			; 參數傳遞的字節數( 無)
          RSEG    PROC
_CheckRAM:MOV     DPTR,#0ffffh
CKRam0:   INC     DPTR
          MOV     A,#0AAH
          MOVX    @DPTR,A
          NOP
          NOP
          MOVX    A,@DPTR
          MOV     B,A
          MOV     A,#55H
          MOVX    @DPTR,A
          NOP
          NOP
          MOVX    A,@DPTR
          ORL     A,B
          CPL     A                        ; 取反 A=0 才是正確的 RAM
          SETB    C                        ; 默認 錯誤 退出
          JNZ     CKRam1                   ; 不為零 說明 RAM 有錯 無需在檢 置錯誤標志位退出
Clr256:   MOVX    @DPTR,A                  ; 運行到此 A=0
          MOV     A,DPH
          CJNE    A,#07FH,CKRam0
          MOV     A,DPL
          CJNE    A,#0FFH,CKRam0           ; 32K RAM地址空間清零
          CLR     C                        ; 初始化 完成, 設置 退出
CKRam1:   RET

END