@ECHO OFF

SET EXDIR=Ex1
SET UCOSTOP=\Micrium\Software
SET TMDIR=%UCOSTOP%\TEMP
SET BLDIR=%TMDIR%\%EXDIR%
SET FEXDIR=%UCOSTOP%\uCOS-II\Ports\80x86\DOS\L\PACC751\AMR\%EXDIR%

REM FreeDOS always returns true if we just test for %UCOSTOP%\NUL
REM regardless of whether %UCOSTOP% exists or not, so test for a
REM file that should always be there.
IF EXIST %UCOSTOP%\UCOS-II\SOURCE\OS_CORE.C GOTO OKAY
ECHO.
ECHO Error: Can not find the toplevel MicroC/OS directory (%UCOSTOP%)!
ECHO.
ECHO If the software is installed in a different directory, edit this batch file
ECHO and change the UCOSTOP setting.
GOTO EXIT

:OKAY

IF NOT %RTDEVOS%XXX == XXX GOTO RTENVOK
IF NOT %RTDEVOS%XXX == XXX GOTO RTENVOK
ECHO Error: RTDEVOS environment variable has not been set.
ECHO It should be set to either WIN95 or WINNT
GOTO EXIT

:RTENVOK

IF NOT EXIST %TMDIR%\DUMMY            MD    %TMDIR%
ECHO DUMMY > %TMDIR%\DUMMY
IF NOT EXIST %BLDIR%\DUMMY            MD    %BLDIR%
ECHO DUMMY > %BLDIR%\DUMMY
IF NOT EXIST %BLDIR%\WORK\MAKEFILE    MD    %BLDIR%\WORK
COPY  MAKEFILE  %BLDIR%\WORK\MAKEFILE > NUL
IF NOT EXIST %BLDIR%\OBJ\DUMMY        MD    %BLDIR%\OBJ
ECHO DUMMY > %BLDIR%\OBJ\DUMMY

CD    %BLDIR%\WORK

IF %RTDEVOS%XXX == WIN95XXX GOTO WIN95MK
IF %RTDEVOS%XXX == WINNTXXX GOTO WINNTMK
ECHO Error: RTDEVOS environment variable should be WIN95 or WINNT
CD %FEXDIR%
GOTO EXIT

:WIN95MK
DMAKE  TOP=%UCOSTOP% BLDIR=%BLDIR% EXDIR=%EXDIR% COMPRO=COMMAND
CD %FEXDIR%
GOTO EXIT

:WINNTMK
DMAKE  TOP=%UCOSTOP% BLDIR=%BLDIR% EXDIR=%EXDIR% COMPRO=CMD
CD %FEXDIR%

:EXIT