;****************************************************************************** 
; 文件名：EINT0_VECT.S
; 功能：使用外部中斷0進(jìn)行LED1的控制，每當(dāng)有一次中斷時(shí)，即取反LED1控制口，以便指示中斷輸入。
;      使用向量中斷方式。
; 說(shuō)明：將跳線器JP4_LED1短接，然后按下/放開(kāi)KEY1，使EINT0為低/高電平。
;****************************************************************************** 
			INCLUDE		LPC2294.INC
			EXPORT  	MAIN
			
VIC_BASE	EQU		0xFFFFF000
				
LED1CON  	EQU		(1<<22)					; P0.22引腳控制LED1，低電平點(diǎn)亮

			AREA   	EINT0_VECTC,CODE,READONLY 	
			ENTRY							
		
MAIN 		MSR     CPSR_c, #0x5F			; 切換處理器工作模式，并允許IRQ中斷
            LDR		R0,=PINSEL0				
			MOV		R1,#0x00000000			
			STR		R1,[R0]					
			MOV		R1,#0x00000001			
			STR		R1,[R0,#0x04]			; 設(shè)置管腳連接，P0.16設(shè)置為EINT0
			
			LDR		R0,=IO0DIR				
			LDR		R1,=LED1CON
			STR		R1,[R0]					; 設(shè)置LED1控制口為輸出
			
			LDR		R0,=MEMMAP
    		MOV		R1,#0x02
			STR		R1,[R0]					; REMAP操作(若寫到片內(nèi)FLASH，則不需要REMAP)
			
EINT1_INI	LDR		R0,=EXTMODE
			MOV		R1,#0x0F
			STR		R1,[R0]					; 設(shè)置EINT0中斷為邊沿觸發(fā)模式
			LDR		R0,=EXTPOLAR
			MOV		R1,#0x00				
			STR		R1,[R0]					; 設(shè)置EINT0中斷為下降沿觸發(fā)
			LDR		R0,=EXTINT
			MOV		R1,#0x0F
			STR		R1,[R0]					; EXTINT=0x0F 

			LDR		R0,=VIC_BASE
			MOV		R1,#0x00000000
			STR		R1,[R0,#0x0C]			; VICIntSelect=0x00000000
			MOV		R1,#0x2E
			STR		R1,[R0,#0x200]			; VICVectCntl0=0x2E
			LDR		R1,=IRQ_EINT0
			STR		R1,[R0,#0x100]			; VICVectAddr0=(int)IRQ_EINT0
			MOV		R1,#0x00004000
			STR		R1,[R0,#0x10]			; VICIntEnable=0x00004000			
		
WAIT_IRQ	B		WAIT_IRQ	


;******************************************************************************
; 名稱：IRQ_EINT0
; 功能：EINT0中斷服務(wù)程序
; 入口參數(shù)：無(wú)
; 出口參數(shù)：無(wú)
; 占用資源：R0、R1
;******************************************************************************
IRQ_EINT0	
			LDR		R0,=IO0SET
			LDR		R1,[R0]					; 讀取IO0SET的值
			ANDS	R1,R1,#LED1CON
			LDREQ	R0,=IO0SET				; 設(shè)置R0=IO0SET
			LDRNE	R0,=IO0CLR				; 或設(shè)置R0=IO0CLR
			MOV		R1,#LED1CON
			STR		R1,[R0]
			
			LDR		R0,=EXTINT
			MOV		R1,#0x01
			STR		R1,[R0]					; EXTINT=0x01，清除EINT0中斷標(biāo)志
			
			LDR		R0,=VICVectAddr
			MOV		R1,#0
			STR		R1,[R0]					; VICVectAddr=0						
   			SUBS	PC,LR,#4				; IRQ中斷返回
			
			END