?? page.asp
字號:
<%
'=====================================================================
'XDOWNPAGE ASP版本
'版本 1.00
'Code by zykj2000
'Email: zykj_2000@163.net
'BBS: http://bbs.513soft.net
'本程序可以免費使用、修改，希望我的程序能為您的工作帶來方便
'但請保留以上請息
'
'程序特點
'本程序主要是對數據分頁的部分進行了封裝，而數據顯示部份完全由用戶自定義，
'支持URL多個參數
'
'使用說明
'程序參數說明
'PapgeSize 定義分頁每一頁的記錄數
'GetRS 返回經過分頁的Recordset此屬性只讀
'GetConn 得到數據庫連接
'GetSQL 得到查詢語句
'程序方法說明
'ShowPage 顯示分頁導航條,唯一的公用方法
'
'例:
' <!--#include file="conn.asp"-->
' <!--#include file="xdownpage.inc"--> '包含文件
'
' Set mypage=new xdownpage '創建對象
' mypage.getconn=conn '得到數據庫連接
' mypage.getsql="select * from productinfo order by id asc"
' mypage.pagesize=5 '設置每一頁的記錄條數據為5條
' set rs=mypage.getrs() '返回Recordset
' mypage.showpage() '顯示分頁信息，這個方法可以，在set rs=mypage.getrs()以后
' 任意位置調用，可以調用多次
' for i=1 to mypage.pagesize '接下來的操作就和操作一個普通Recordset對象一樣操作
' if not rs.eof then '這個標記是為了防止最后一頁的溢出
' response.write rs(0) & "<br>" '這里就可以自定義顯示方式了
' rs.movenext
' else
' exit for
' end if
' next
'
'=====================================================================
'Const Btn_First="<font face=webdings>9</font>" '定義第一頁按鈕顯示樣式
'Const Btn_Prev="<font face=webdings>3</font>" '定義前一頁按鈕顯示樣式
'Const Btn_Next="<font face=webdings>4</font>" '定義下一頁按鈕顯示樣式
'Const Btn_Last="<font face=webdings>:</font>" '定義最后一頁按鈕顯示樣式
Const Btn_First="首頁" '定義第一頁按鈕顯示樣式
Const Btn_Prev="上頁" '定義前一頁按鈕顯示樣式
Const Btn_Next="下頁" '定義下一頁按鈕顯示樣式
Const Btn_Last="末頁" '定義最后一頁按鈕顯示樣式
Const XD_Align="center" '定義分頁信息對齊方式
Const XD_Width="100%" '定義分頁信息框大小
Const XD_Height=""
Class Xdownpage
Private XD_PageCount,XD_Conn,XD_Rs,XD_SQL,XD_PageSize,Str_errors,int_curpage,str_URL,int_totalPage,int_totalRecord
'=================================================================
'PageSize 屬性
'設置每一頁的分頁大小
'=================================================================
Public Property Let PageSize(int_PageSize)
If IsNumeric(Int_Pagesize) Then
XD_PageSize=CLng(int_PageSize)
Else
str_error=str_error & "PageSize的參數不正確"
ShowError()
End If
End Property
Public Property Get PageSize
If XD_PageSize="" or (not(IsNumeric(XD_PageSize))) Then
PageSize=10
Else
PageSize=XD_PageSize
End If
End Property
'=================================================================
'GetRS 屬性
'返回分頁后的記錄集
'=================================================================
Public Property Get GetRs()
Set XD_Rs=Server.createobject("adodb.recordset")
XD_Rs.PageSize=PageSize
XD_Rs.Open XD_SQL,XD_Conn,1,1
If not(XD_Rs.eof and XD_RS.BOF) Then
If int_curpage>XD_RS.PageCount Then
int_curpage=XD_RS.PageCount
End If
XD_Rs.AbsolutePage=int_curpage
End If
Set GetRs=XD_RS
End Property
'================================================================
'GetConn 得到數據庫連接
'
'================================================================
Public Property Let GetConn(obj_Conn)
Set XD_Conn=obj_Conn
End Property
'================================================================
'GetSQL 得到查詢語句
'
'================================================================
Public Property Let GetSQL(str_sql)
XD_SQL=str_sql
End Property
'==================================================================
'Class_Initialize 類的初始化
'初始化當前頁的值
'
'==================================================================
Private Sub Class_Initialize
'========================
'設定一些參數的黙認值
'========================
XD_PageSize=10 '設定分頁的默認值為10
'========================
'獲取當前面的值
'========================
If request("page")="" Then
int_curpage=1
ElseIf not(IsNumeric(request("page"))) Then
int_curpage=1
ElseIf CInt(Trim(request("page")))<1 Then
int_curpage=1
Else
Int_curpage=CInt(Trim(request("page")))
End If
End Sub
'====================================================================
'ShowPage 創建分頁導航條
'有首頁、前一頁、下一頁、末頁、還有數字導航
'
'====================================================================
Public Sub ShowPage()
Dim str_tmp
int_totalRecord=XD_RS.RecordCount
If int_totalRecord<=0 Then
str_error=str_error & "總記錄數為零，請輸入數據"
Call ShowError()
End If
If int_totalRecord<pagesize Then
int_TotalPage=1
Else
If int_totalRecord mod PageSize =0 Then
int_TotalPage = Int(int_TotalRecord / XD_PageSize * -1)*-1
Else
int_TotalPage = Int((int_TotalRecord / XD_PageSize * -1)*-1)+1
End If
End If
If Int_curpage>int_Totalpage Then
int_curpage=int_TotalPage
End If
'===============================================================================
'顯示分頁信息，各個模塊根據自己要求更改顯求位置
'===============================================================================
response.write "<table border=0 cellpadding=0 cellspacing=0 width="&XD_Width&"><tr><form name='TurnPage'><td align="&XD_Align&" height="&XD_Height&">"
str_tmp=ShowFirstPrv
'response.write str_tmp
'str_tmp=showNumBtn
response.write str_tmp
str_tmp=ShowNextLast
response.write str_tmp
str_tmp=ShowPageInfo
response.write str_tmp
'Response.write "</td><td>"
Response.Write ShowGoto()
response.write "</td></FORM></tr></table>"
End Sub
'====================================================================
Public Function PageInfo()
Dim str_tmp,strHtml
int_totalRecord=XD_RS.RecordCount
If int_totalRecord<=0 Then
str_error=str_error & "總記錄數為零，請輸入數據"
Call ShowError()
End If
If int_totalRecord<pagesize Then
int_TotalPage=1
Else
If int_totalRecord mod PageSize =0 Then
int_TotalPage = Int(int_TotalRecord / XD_PageSize * -1)*-1
Else
int_TotalPage = Int((int_TotalRecord / XD_PageSize * -1)*-1)+1
End If
End If
If Int_curpage>int_Totalpage Then
int_curpage=int_TotalPage
End If
'===============================================================================
'顯示分頁信息，各個模塊根據自己要求更改顯求位置
'===============================================================================
strHtml = "<table border='0' cellpadding='0' cellspacing='0' width='"&XD_Width&"'><tr><form name='TurnPage'><td align='"&XD_Align&"'>"
str_tmp=ShowFirstPrv
'response.write str_tmp
'str_tmp=showNumBtn
strHtml = strHtml & str_tmp
str_tmp=ShowNextLast
strHtml = strHtml & str_tmp
str_tmp=ShowPageInfo
strHtml = strHtml & str_tmp
'Response.write "</td><td>"
strHtml = strHtml & ShowGoto()
strHtml = strHtml & "</td></FORM></tr></table>"
PageInfo = strHtml
End Function
'====================================================================
'ShowFirstPrv 顯示首頁、前一頁
'
'
'====================================================================
Private Function ShowFirstPrv()
Dim Str_tmp,int_prvpage
If int_curpage=1 Then
str_tmp="<span disabled>["&Btn_First&"]["&Btn_Prev&"]</span>"
Else
int_prvpage=int_curpage-1
str_tmp="[<a title='首頁' href='"&geturl&"1'>"&Btn_First&"</a>][<a title='上一頁' href='"&geturl & int_prvpage &"'>"& Btn_Prev&"</a>]"
End If
ShowFirstPrv=str_tmp
End Function
'====================================================================
'ShowNextLast 下一頁、末頁
'
'
'====================================================================
Private Function ShowNextLast()
Dim str_tmp,int_Nextpage
If Int_curpage>=int_totalpage Then
str_tmp= "<span disabled>["&Btn_Next & "][" & Btn_Last &"]</span>"
Else
Int_NextPage=int_curpage+1
str_tmp="[<a title='下一頁' href='"& geturl & int_NextPage &"'>"&Btn_Next&"</a>][<a title='最末頁' href='"&geturl & int_totalpage &"'>"& Btn_Last&"</a>]"
End If
ShowNextLast=str_tmp
End Function
'====================================================================
'ShowNumBtn 數字導航
'
'
'====================================================================
'Private Function showNumBtn()
' Dim i,str_tmp
' For i=1 to int_totalpage
' str_tmp=str_tmp & "<a href="& geturl & i &">["&i&"]</a> "
' Next
' showNumBtn=str_tmp
'
'End Function
'====================================================================
'ShowNumBtn 修改后的數字導航
'
'====================================================================
Function showNumBtn()
Dim i,str_tmp,end_page,start_page
if int_curpage>4 then
if int_curpage+2<int_totalpage then
start_page=int_curpage-2
end_page=int_curpage+2
else
start_page=int_totalpage-4
end_page=int_totalpage
end if
else
start_page=1
if int_totalpage>5 then
end_page=5
else
end_page=int_totalpage
end if
end if
For i=start_page to end_page
str_tmp=str_tmp & " [<a title='轉到第["&i&"]頁' href='"& geturl & i &"'>"&i&"</a>] "
Next
showNumBtn=str_tmp
End Function
'====================================================================
'ShowGoto 頁面跳轉
'
'
'====================================================================
Private Function ShowGoto()
Dim M_item,strTmp
strTmp = ""
'========================================================
'將返回的Url參數逐個的寫入隱藏域中，以便與參數繼續傳遞
'========================================================
For Each M_item In Request.QueryString
If InStr("page",M_Item)=0 Then '從參數中除去 "page" 的值
strTmp = strTmp & "<input type=hidden name = '"&M_Item&"' value = '"&Request.QueryString(""&M_Item&"")&"'>"
End If
Next
'========================================================
strTmp = strTmp & " 轉到第：<input style='height:18px' type='text' name='page' size='3' maxlength='10' value='"&int_curpage&"' onchange=""document.TurnPage.GoPage.disabled=false"">"
strTmp = strTmp & " 頁 <input style='height:18px' type='submit' id='GoPage' disabled value='Go'>"
ShowGoto = strTmp
End Function
'====================================================================
'ShowPageInfo 分頁信息
'更據要求自行修改
'
'====================================================================
Private Function ShowPageInfo()
Dim str_tmp
str_tmp=" [頁次:"&int_curpage&"/"&int_totalpage&"頁] [共"&int_totalrecord&"條] ["&XD_PageSize&"條/頁]"
ShowPageInfo=str_tmp
End Function
'====================================================================
'修改后的獲取當前Url參數的函數
'Codeing by Redsun
'====================================================================
Private Function GetUrl()
Dim ScriptAddress, M_ItemUrl, M_item
ScriptAddress = CStr(Request.ServerVariables("SCRIPT_NAME"))&"?"'取得當前地址
If (Request.QueryString <> "") Then
M_ItemUrl = ""
For Each M_item In Request.QueryString
If InStr("page",M_Item)=0 Then
M_ItemUrl = M_ItemUrl & M_Item &"="& Server.URLEncode(Request.QueryString(""&M_Item&"")) & "&"
End If
Next
ScriptAddress = ScriptAddress & M_ItemUrl'取得帶參數地址
End If
GetUrl = ScriptAddress & "page="
End Function
'====================================================================
' 設置 Terminate 事件。
'====================================================================
Private Sub Class_Terminate
If Not IsObject(XD_RS) Then Exit Sub
'XD_RS.close()
Set XD_RS = Nothing
End Sub
'====================================================================
'ShowError 錯誤提示
'====================================================================
Private Sub ShowError()
If str_Error <> "" Then
Response.Write("<font color=""#FF0000""><br><b>" & SW_Error & "</font>")
Response.End
End If
End Sub
End class
%>?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -