;define the stack size
;定義堆棧的大小
SVC_STACK_LEGTH         EQU         0
FIQ_STACK_LEGTH         EQU         0
IRQ_STACK_LEGTH         EQU         256
ABT_STACK_LEGTH         EQU         0
UND_STACK_LEGTH         EQU         0

NoInt       EQU 0x80

USR32Mode   EQU 0x10
SVC32Mode   EQU 0x13
SYS32Mode   EQU 0x1f
IRQ32Mode   EQU 0x12
FIQ32Mode   EQU 0x11

    IMPORT __use_no_semihosting_swi

;The imported labels
;引入的外部標號在這聲明
    IMPORT  FIQ_Exception                   ;Fast interrupt exceptions handler 快速中斷異常處理程序
    IMPORT  __main                          ;The entry point to the main function C語言主程序入口 
    IMPORT  TargetResetInit                 ;initialize the target board 目標板基本初始化

;The emported labels
;給外部使用的標號在這聲明
    EXPORT  bottom_of_heap
    EXPORT  StackUsr
    
    EXPORT  Reset
    EXPORT __user_initial_stackheap

    CODE32

    RSEG   vectors:CODE:NOROOT(2)
 ;   ENTRY

;interrupt vectors
;中斷向量表
Reset
        LDR     PC, ResetAddr
        LDR     PC, UndefinedAddr
        LDR     PC, SWI_Addr
        LDR     PC, PrefetchAddr
        LDR     PC, DataAbortAddr
        DCD     0xb9205f80
        LDR     PC, [PC, #-0xff0]
        LDR     PC, FIQ_Addr

ResetAddr           DCD     ResetInit
UndefinedAddr       DCD     Undefined
SWI_Addr            DCD     SoftwareInterrupt
PrefetchAddr        DCD     PrefetchAbort
DataAbortAddr       DCD     DataAbort
Nouse               DCD     0
IRQ_Addr            DCD     0
FIQ_Addr            DCD     FIQ_Handler


;未定義指令
Undefined
        B       Undefined

;軟中斷
SoftwareInterrupt			
        B       SoftwareInterrupt	

;取指令中止
PrefetchAbort
        B       PrefetchAbort

;取數據中止
DataAbort
        B       DataAbort

;快速中斷
FIQ_Handler
        STMFD   SP!, {R0-R3, LR}
        BL      FIQ_Exception
        LDMFD   SP!, {R0-R3, LR}
        SUBS    PC,  LR,  #4
        
;/*********************************************************************************************************

InitStack    
        MOV     R0, LR
;Build the SVC stack
;設置管理模式堆棧
        MSR     CPSR_c, #0xd3		
        LDR     SP, StackSvc	
;Build the IRQ stack	
;設置中斷模式堆棧
        MSR     CPSR_c, #0xd2
        LDR     SP, StackIrq
;Build the FIQ stack
;設置快速中斷模式堆棧
        MSR     CPSR_c, #0xd1
        LDR     SP, StackFiq
;Build the DATAABORT stack
;設置中止模式堆棧
        MSR     CPSR_c, #0xd7
        LDR     SP, StackAbt
;Build the UDF stack
;設置未定義模式堆棧
        MSR     CPSR_c, #0xdb
        LDR     SP, StackUnd
;Build the SYS stack
;設置系統模式堆棧
        MSR     CPSR_c, #0x5f
        LDR     SP, =StackUsr

        MOV     PC, R0

;/*********************************************************************************************************

;********************************************************************************************************/
ResetInit
        
        BL      InitStack               ;初始化堆棧 Initialize the stack
        BL      TargetResetInit         ;目標板基本初始化 Initialize the target board
                                        ;跳轉到c語言入口 Jump to the entry point of C program
        B       __main


;********************************************************************************************************/
__user_initial_stackheap    
    LDR   r0,=bottom_of_heap
;    LDR   r1,=StackUsr
    MOV   pc,lr


StackSvc           DCD     SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4
StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4
StackFiq           DCD     FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4
StackAbt           DCD     AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4
StackUnd           DCD     UndtStackSpace + (UND_STACK_LEGTH - 1)* 4


    
;/* 分配堆棧空間 */
        RSEG   MyStacks: DATA:NOROOT(2)
SvcStackSpace      DC16   SVC_STACK_LEGTH * 4  ;Stack spaces for Administration Mode 管理模式堆棧空間
IrqStackSpace      DC16   IRQ_STACK_LEGTH * 4  ;Stack spaces for Interrupt ReQuest Mode 中斷模式堆棧空間
FiqStackSpace      DC16   FIQ_STACK_LEGTH * 4  ;Stack spaces for Fast Interrupt reQuest Mode 快速中斷模式堆棧空間
AbtStackSpace      DC16   ABT_STACK_LEGTH * 4  ;Stack spaces for Suspend Mode 中止義模式堆棧空間
UndtStackSpace     DC16   UND_STACK_LEGTH * 4  ;Stack spaces for Undefined Mode 未定義模式堆棧


       RSEG   Heap: DATA:NOROOT(2)
bottom_of_heap    DC16  1

       RSEG   Stacks: DATA: NOROOT(2)
StackUsr

    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/