;-----------------------------------------------------------
;重慶大學DSP實驗室
;函數名：void cursample(cursample_struct *p)
;函數功能：采樣電機相電流ia,ib，并轉換為Q12格式
;(以額定電流為基準)
;數字濾波方式：平均值濾波
;轉換公式：
;	ix=Kcurrent*((result>>6)-512)	(Q12)
;			;result 為電流平均值
;			;x=a, b
;	Kcurrent=(4096*imax)/(512*ib)	(Q0)
;			;選擇imax=(1.5V*33.33)/(27*50e-3)
;			;ib為額定電流峰值
;入口條件：
;	result8--result11
;			;電流ia的AD轉換結果寄存器
;	result12--result15
;			;電流ib的AD轉換結果寄存器
;出口條件：
;	typedef struct
;	{	int zeropoint_ib;B相電流采樣提升零點
;		int ib;		;B相電流值，Q12
;		int zeropoint_ia;A相電流采樣提升零點	Q0
;		int ia;		;A相電流值，Q12
;	}cursample_struct;
;請用戶在主程序中聲明以下函數和全局變量：
;	typedef struct
;	{	int zeropoint_ib;B相電流采樣提升零點
;		int ib;		;B相電流值，Q12
;		int zeropoint_ia;A相電流采樣提升零點	Q0
;		int ia;		;A相電流值，Q12
;	}cursample_struct;
;	extern void cursample(cursample_struct *p);

;2002.4.16.
;-----------------------------------------------------------
		.def _cursample 
Kcurrent .set 1h				;Q0
cursample_frame .set 02h
		.text
_cursample:
		POPD	*+
		SAR		AR0,*+
		SAR		AR1,*
		LAR		AR0,#cursample_frame
		LAR		AR0,*0+,AR0		
		LAR		AR2,*,AR2
		SBRK	#3h
		LAR		AR3,*,AR2		;AR3:zeropoint_ib
		LAR		AR2,#70B0h 	  	;STACK:*p/address/AR0/AR1
								;ARP:AR2, AR0:AR1, AR2:RESULT8
		CLRC	SXM
		LACC	#0
		RPT		#3
		ADD		*+,8			;CALCULATE AVERAGE OF AD RESULT
		MAR		*,AR0           ;ARP:AR0
		SACH    *+,AR2          ;STACK:*p/ADDRESS/AR0/ia/y
								;ARP:AR2, AR0:y, AR2:RESULT12
		LACC	#0 				             
		RPT		#3
		ADD		*+,8	        ;CALCULATE AVERAGE OF AD RESULT
		MAR		*,AR3
		SETC	SXM
		SUB		*+,16,AR0		;STACK:*p/ADDRESS/AR0/ia/ib
								;ARP:AR0, AR0:ib,
		SACH	*

		LT		*-,AR3			;STACK:*p/ADDRESS/AR0/ia/ib
								;ARP:AR0, AR0:ia, AR2:RESULT17
		MPY		#Kcurrent		;Kcurrent*ib
		SPL		*+,AR0           ;ib=Kcurrent*ib
		LACC	*,AR3			
		SUB		*+,AR0
		SACL	*               ;GETTING POSITIVE OR NEGATIVE VALUES OF ia
		LT		*,AR3           ;ARP:AR3
		MPY		#Kcurrent       ;Kcurrent*ia
		SPL		*,AR1           ;ia=Kcurrent*ia
		SBRK	#(cursample_frame+1)
		LAR		AR0,*-
		PSHD	*
		RET
		.end