;Led-HZ.asm
;32位LED點陣漢字顯示實驗

INCLUDE LED-HZ.inc
.386P

;****************根據查看端口資源修改下列符號值*******************
IOY0         EQU   9C00H          ;片選IOY0對應的端口始地址
;*****************************************************************

STACK1 SEGMENT STACK 
        DW 256 DUP(?)
STACK1 ENDS

DATA   SEGMENT  USE16 	
ADDR    DW   ?
DATA   ENDS

CODE SEGMENT  USE16
        ASSUME CS:CODE,DS:DATA

START: MOV  AX,DATA
       MOV  DS,AX
	   	  
A2:    MOV  ADDR,OFFSET HZDOT    ;取漢字數組始地址     
       MOV  SI,ADDR         
A1:    MOV  CX,20H               ;控制1屏顯示時間

LOOP2: CALL DISPHZ
       SUB  SI,32
       LOOP LOOP2       
               
KEY:   MOV  AH,1                 ;判斷是否有按鍵按下？
       INT  16H
       JNZ  QUIT
       
       ADD  SI,2  
       MOV  AX,SI       
       SUB  AX,ADDR
       CMP  AX,352               ;比較文字是否顯示完畢
       JNB  A2                   
       JMP  A1
       
QUIT:  MOV  EAX,0                ;滅燈
       MOV  DX,IOY0
       OUT  DX,EAX
       
       MOV  AX,4C00H             ;結束程序退出
       INT  21H

DISPHZ PROC NEAR                 ;顯示1屏漢字子程序
       PUSH CX
       MOV  CX,16
       MOV  BX,0FFFEH
LOOP1: MOV  AL,BYTE PTR[SI]
       MOV  AH,BYTE PTR[SI+1]
       ROL  EAX,16 
       MOV  AX,BX             
       ADD  SI,2
       ROL  BX,1 
       NOT  EAX
       MOV  DX,IOY0
       OUT  DX,EAX
       CALL DALLY
       LOOP LOOP1
       POP  CX
       RET
DISPHZ ENDP

DALLY  PROC NEAR                  ;軟件延時子程序
       MOV  AX,0FFFFH
D1:    DEC  AX
       JNZ  D1
       RET
DALLY  ENDP

CODE ENDS
     END START