;T16550-3.asm
;16550雙機通信發送機程序

;***************根據CHECK配置信息修改下列符號值*******************
IOY0         EQU   9C00H          ;片選IOY0對應的端口始地址
;*****************************************************************
MY16550_0    EQU   IOY0+00H*4     ;16550數據緩沖寄存器端口地址
MY16550_1    EQU   IOY0+01H*4     ;16550中斷允許寄存器端口地址
MY16550_3    EQU   IOY0+03H*4     ;16550線路控制寄存器端口地址
MY16550_4    EQU   IOY0+04H*4     ;16550 MODEM控制寄存器端口地址
MY16550_5    EQU   IOY0+05H*4     ;16550線路狀態寄存器端口地址

STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA  SEGMENT
AA    DB  2FH
DATA  ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX

       MOV DX,MY16550_3           ;設置16550線路控制寄存器
       MOV AL,80H                 ;準備設置波特率除數寄存器
       OUT DX,AL
       CALL DALLY

       MOV DX,MY16550_0           ;設置除數寄存器低字節0CH  
       MOV AL,0CH                 ;000C對應9600 bit/s
       OUT DX,AL            
       CALL DALLY
                            
       MOV DX,MY16550_1           ;設置除數寄存器高字節00H
       MOV AL,00H
       OUT DX,AL
       CALL DALLY
       
       MOV DX,MY16550_3           ;設置線路控制寄存器，初始化數據格式
       MOV AL,1BH                 ;偶校驗，1位停止位，字符寬度為8
       OUT DX,AL
       CALL DALLY

       MOV DX,MY16550_4           ;設置MODEM控制寄存器 
       MOV AL,03H
       OUT DX,AL
       CALL DALLY
        
       MOV DX,MY16550_1           ;設置中斷允許寄存器
       MOV AL,00H                 ;中斷不打開
       OUT DX,AL
       CALL DALLY

A1:    INC AA
       MOV DX,MY16550_0
       MOV AL,AA
       OUT DX,AL              
       CALL DALLY
       CMP AL,39H
       JNZ A1

QUIT:  MOV AX,4C00H               ;返回到DOS
       INT 21H

DALLY PROC NEAR                   ;軟件延時子程序
       PUSH CX
       PUSH AX
       MOV CX,0300H
D1:    MOV AX,3000H
D2:    DEC AX
       JNZ D2
       LOOP D1
       POP AX
       POP CX
       RET
DALLY ENDP

CODE ENDS
     END START