unit NewDBGrid;
interface
uses
  Windows, Messages, SysUtils, Classes,
  Graphics, Controls,  Forms, Dialogs,
  DB, Grids, DBGrids;
type
  TDrawFieldCellEvent = procedure(Sender: TObject; Field: TField;
           var Color: TCOlor;Var Font: TFont;Row:Longint) of object;
  //新的數(shù)據(jù)控件由 TDBGrid 繼承而來
  TNewDBGrid = class(TDBGrid)
    private
        //私有變量
        FWZebra: Boolean;          //是否顯示斑馬顏色
        FWFirstColor : TColor;     //單數(shù)行顏色
        FWSecondColor : TCOlor;    //雙數(shù)行顏色
        FDrawFieldCellEvent : TDrawFieldCellEvent;
        procedure AutoInitialize;   //自動(dòng)初使化過程
        procedure AutoDestroy;
        function  GetWFirstColor : TColor;     
		//FirstColor 的讀寫函數(shù)及過程
        procedure SetWFirstColor(Value : TColor);
        function  GetWSecondColor : TCOlor;
        procedure SetWSecondColor(Value : TColor);
        function  GetWZebra : Boolean;
        procedure SetWZebra(Value : Boolean);
    protected
        procedure Scroll(Distance: Integer); override;
        //本控件的重點(diǎn)過程
        procedure DrawCell(Acol,ARow: Longint;ARect:
                   TRect;AState: TGridDrawState); override;
    public
        constructor Create(AOwner: TComponent); override;
        destructor Destroy; override;
    published
property WZebra: Boolean read GetWZebra write SetWZebra;
        property OnDblClick;
        property OnDragDrop;
        property OnKeyUp;
        property OnKeyDown;
        property OnKeyPress;
        property OnEnter;
        property OnExit;
        property OnDrawDataCell;
        property WFirstColor : TColor
             read GetWFirstColor write SetWFirstColor ;
        property WSecondColor : TColor
             read GetWSecondColor write SetWSecondColor ;
  end;
procedure Register;
implementation
procedure Register;
begin
     RegisterComponents('Data Controls', [TNewDBGrid]);
end;
procedure TNewDBGrid.AutoInitialize;
begin
  FWFirstColor := RGB(239,254,247);
  FWSecondColor := RGB(249,244,245);
  {可以在次添加需要的其它控件及初使化參數(shù)}
end;
procedure TNewDBGrid.AutoDestroy;
begin
  {在這里釋放自己添加參數(shù)等占用的系統(tǒng)資源}
end;

procedure TNewDBGrid.SetWZebra(Value : Boolean);
begin
     FWZebra := Value;
     Refresh;
end;

function TNewDBGrid.GetWZebra: Boolean;
begin
     Result :=FWZebra;
end;


function TNewDBGrid.GetWFirstColor : TColor;
begin
     Result := FWFirstColor;
end;
procedure TNewDBGrid.SetWFirstColor(Value : TColor);
begin
     FWFirstColor := Value;
     Refresh;
end;

function TNewDBGrid.GetWSecondColor : TColor;
begin
     Result := FWSecondColor;
end;
procedure TNewDBGrid.SetWSecondColor(Value : TColor);
begin
     FWSecondColor := Value;
     Refresh;
end;


constructor TNewDBGrid.Create(AOwner: TComponent);
begin
     inherited Create(AOwner);
     AutoInitialize;
end;

destructor TNewDBGrid.Destroy;
begin
     AutoDestroy;
     inherited Destroy;
end;

//實(shí)現(xiàn)斑馬效果
procedure TNewDBGrid.DrawCell(ACol,ARow:
Longint;ARect: TRect;AState: TGridDrawState);
var
  OldActive: Integer;
  Highlight: Boolean;
  Value: string;
  DrawColumn: Tcolumn;
  cl: TColor;
  fn: TFont;
begin
  {如果處于控件裝載狀態(tài),則直接填充顏色后退出}
  if csLoading in ComponentState then
     begin
       Canvas.Brush.Color := Color;
       Canvas.FillRect(ARect);
       Exit;
     end;
  if (gdFixed in AState) and (ACol - IndicatorOffset < 0 ) then
     begin
       inherited DrawCell(ACol,ARow,ARect,AState);
       Exit;
     end;
  {對(duì)于列標(biāo)題,不用任何修飾}
  if (dgTitles in Options) and (ARow = 0) then
     begin
       inherited DrawCell(ACol,ARow,ARect,AState);
       Exit;
     end;
  if (dgTitles in Options) then Dec(ARow);
  Dec(ACol,IndicatorOffset);
  if (gdFixed in AState) and ([dgRowLines,dgColLines] * Options =
        [dgRowLines,dgColLines]) then
     begin
       {縮減ARect,以便填寫數(shù)據(jù)}
       InflateRect(ARect,-1,-1);
     end
  else
     with Canvas do
       begin
         DrawColumn := Columns[ACol];
         Font := DrawColumn.Font;
         Brush.Color := DrawColumn.Color;
         Font.Color := DrawColumn.Font.Color;
         if FWZebra then   //如果屬性WZebra為True則顯示斑馬紋
         if Odd(ARow) then
            Brush.Color := FWSecondColor
         else
            Brush.Color := FWFirstColor;
         if (DataLink = nil) or not DataLink.Active then
            FillRect(ARect)
         else
            begin
             Value := '';
             OldActive := DataLink.ActiveRecord;
             try
               DataLink.ActiveRecord := ARow;
               if Assigned(DrawColumn.Field) then
                  begin
                    Value := DrawColumn.Field.DisplayText;
                    if Assigned(FDrawFieldCellEvent) then
                       begin
                         cl := Brush.Color;
                         fn := Font;
                FDrawFieldCellEvent(self,DrawColumn.Field,cl,fn,ARow);
                Brush.Color := cl;
                 Font := fn;
                       end;
                  end;
               Highlight := HighlightCell(ACol,ARow,Value,AState);
               if Highlight and (not FWZebra) then
                  begin
                    Brush.Color := clHighlight;
                    Font.Color := clHighlightText;
                  end;
               if DefaultDrawing then
            DefaultDrawColumnCell(ARect,ACol,DrawColumn,AState);
           if Columns.State = csDefault then
                  DrawDataCell(ARect,DrawColumn.Field,AState);
                  DrawColumnCell(ARect,ACol,DrawColumn,AState);
              finally
                DataLink.Activerecord := OldActive;
            end;
            if DefaultDrawing and (gdSelected in AState) and
               ((dgAlwaysShowSelection in Options) or Focused)
               and not (csDesigning in Componentstate)
               and not (dgRowSelect in Options)
               and (ValidParentForm(self).ActiveControl = self) then
               begin
                 //顯示當(dāng)前光標(biāo)處為藍(lán)底黃字,同時(shí)加粗顯示
                 Windows.DrawFocusRect(Handle,ARect);
                 Canvas.Brush.COlor := clBlue;
                 Canvas.FillRect(ARect);
                 Canvas.Font.Color := clYellow;
                 Canvas.Font.Style := [fsBold];
                 DefaultDrawColumnCell(ARect,ACol,DrawColumn,AState);
               end;
           end;
       end;
     if (gdFixed in AState) and ([dgRowLines,dgColLines] * Options =
        [dgRowLines,dgColLines]) then
        begin
          InflateRect(ARect,-2,-2);
 DrawEdge(Canvas.Handle,ARect,BDR_RAISEDINNER,BF_BOTTOMRIGHT);
DrawEdge(Canvas.Handle,ARect,BDR_SUNKENINNER,BF_TOPLEFT);
        end;
end;
//如果移動(dòng)光標(biāo)等,則需要刷新顯示DBGrid
procedure TNewDBGrid.Scroll(Distance: Integer);
begin
  inherited Scroll(Distance);
  refresh;
end;
end.