?? me300b-密碼鎖－專用工具.asm
字號:
;=============== 24C01 端口位定義 ====================
SDA EQU P3.4 ;24C01的串行數據線
SCLK24 EQU P3.3 ;24C01的串行時鐘線
PASS_NEW EQU 30H
PASS_OLD EQU 38H
COUN1 EQU 3FH
RS EQU P2.0
RW EQU P2.1
EN EQU P2.2
X EQU 26H ;LCD 地址變量
BEEP EQU P3.7
;------------------------------------------------------
ORG 0000H
JMP MAIN
;------------------------------------------------------
MAIN:
MOV SP,#60H
MOV A,#00H
MOV R0,#PASS_NEW
CLR_1: MOV @R0,A
INC R0
CJNE R0,#3EH,CLR_1
ACALL SET_LCD
MAIN1:
MOV P1,#0F0H
MOV A,P1
CJNE A,#0F0H,MAIN2
JMP MAIN1
MAIN2:
CALL KEY_IN
CALL BEEP_BL
CJNE A,#0CH,MAIN3
CALL WRIRE_WORD
MAIN3: CJNE A,#0DH,MAIN4
CALL READ_WORD
MAIN4: CJNE A,#0FH,MAIN5
AJMP MAIN
MAIN5:
AJMP MAIN1
;-------------------------------------------------
;
;-------------------------------------------------
WRIRE_WORD:
MOV DPTR,#INF03 ;指針指到顯示信息3
MOV A,#1 ;顯示在第一行
CALL LCD_SHOW
MOV DPTR,#INF04 ;指針指到顯示信息4
MOV A,#2 ;顯示在第二行
CALL LCD_SHOW
CALL PASS_IN
CALL EEPW ;密碼寫入24C01
RET
READ_WORD:
MOV DPTR,#INF05 ;指針指到顯示信息5
MOV A,#1 ;顯示在第一行
CALL LCD_SHOW
MOV DPTR,#INF06 ;指針指到顯示信息6
MOV A,#2 ;顯示在第二行
CALL LCD_SHOW
CALL EEPR ;讀出密碼
MOV R0,#PASS_OLD
MOV R2,#09H
MOV R4,#06H
READ1: MOV A,@R0 ;保存密碼值
MOV B,R2
CALL LCDP2
INC R2
INC R0
DJNZ R4,READ1
RET
;---------------------------------------------------
INF03:
DB " WRITE PASSWORD ",0
INF04:
DB "PASSWORD ------ ",0
INF05:
DB " READ PASSWORD ",0
INF06:
DB "PASSWORD ",0
;----------------------------------------------------
;輸入密碼值子程序
;----------------------------------------------------
PASS_IN:
P_IN1:
MOV R0,#PASS_NEW
MOV R3,#00H ;存放鍵值
MOV R2,#09H ;設置LCD地址
MOV COUN1,#06H ;6位密碼
P_IN2:
MOV P1,#0F0H
MOV A,P1
CJNE A,#0F0H,P_IN3
jmp P_IN2
P_IN3:
CALL KEY_IN
CALL SETDATA0
CALL BEEP_BL
DJNZ COUN1,P_IN2
RET
;------------------------------------------
SETDATA0:
MOV A,R3
ANL A,#0FH ;取出低四位二進制數
PUSH ACC
CLR C
SUBB A,#0AH ;減10
POP ACC
JC ASCII4 ;該數小于10，轉ASCII4
INC COUN1 ;字母鍵無效，
RET
ASCII4: ADD A,#30H ;小于10的數加上30H
MOV @R0,A ;保存密碼值
MOV B,R2
CALL LCDP2
INC R2
INC R0
RET
;-----------------------------------------------------
; LCD 初始化設置
;-----------------------------------------------------
SET_LCD:
CLR EN
CALL INIT_LCD ;初始化 LCD
CALL DELAY1
MOV DPTR,#INF01 ;指針指到顯示信息1
MOV A,#1 ;顯示在第一行
CALL LCD_SHOW
MOV DPTR,#INF02 ;指針指到顯示信息2
MOV A,#2 ;顯示在第二行
CALL LCD_SHOW
RET
;-----------------------------------------------------
INF01: DB " WRITE & READ ",0 ;LCD 第一行顯示信息
INF02: DB "--- PASSWORD ---",0 ;LCD 第二行顯示信息
;-----------------------------------------------------
INIT_LCD: ;8位I/O控制 LCD 接口初始化
MOV A,#38H ;雙列顯示，字形5*7點陣
CALL WCOM
CALL DELAY1
MOV A,#38H ;雙列顯示，字形5*7點陣
CALL WCOM
CALL DELAY1
MOV A,#38H ;雙列顯示，字形5*7點陣
CALL WCOM
CALL DELAY1
MOV A,#0CH ;開顯示，關光標，
CALL WCOM
CALL DELAY1
MOV A,#01H ;清除 LCD 顯示屏
CALL WCOM
CALL DELAY1
RET
;----------------------------------------------------
LCD_SHOW: ;在LCD的第一行或第二行顯示信息字符
CJNE A,#1,LINE2 ;判斷是否為第一行
LINE1: MOV A,#80H ;設置 LCD 的第一行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數據
MOV A,#80H ;設置 LCD 的第一行地址
CALL WCOM ;寫入命令
JMP FILL
LINE2: MOV A,#0C0H ;設置 LCD 的第二行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數據
MOV A,#0C0H ;設置 LCD 的第二行地址
CALL WCOM
FILL: CLR A ;填入字符
MOVC A,@A+DPTR ;由消息區取出字符
CJNE A,#0,LC1 ;判斷是否為結束碼
RET
LC1: CALL WDATA ;寫入數據
INC DPTR ;指針加1
JMP FILL ;繼續填入字符
RET
;---------------------------------------------------
CLR_LINE: ;清除該行 LCD 的字符
MOV R0,#24
CL1: MOV A,#' '
CALL WDATA
DJNZ R0,CL1
RET
;-----------------------------------------------------
; 寫指令、數據使能子程序
;-----------------------------------------------------
ENABLE: ;寫指令使能
CLR RS ;RS=L,RW=L,D0-D7=指令碼，E=高脈沖
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
ENABLE1: ;寫數據使能
SETB RS ;RS=H,RW=L,D0-D7=數據，E=高脈沖
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
DELAY0: MOV R7,#250 ;延時500微秒
DJNZ R7,$
RET
;----------------------------------------------------
;寫入命令子程序
;----------------------------------------------------
WCOM: ;以8位控制方式將命令寫至LCD
MOV P0,A ;寫入命令
CALL ENABLE
RET
;----------------------------------------------------
;寫入數據子程序
;----------------------------------------------------
WDATA: ;以8位控制方式將數據寫至LCD
MOV P0,A ;寫入數據
CALL ENABLE1
RET
;---------------------------------------------------
;在 LCD 第二行顯示字符
;A=ASC DATA, B=LINE X POS
;---------------------------------------------------
LCDP2: ;在LCD的第二行顯示字符
PUSH ACC ;
MOV A,B ;設置顯示地址
ADD A,#0C0H ;設置LCD的第二行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數據
RET
;-------------------------------------------------------
;ASCII 轉換并顯示子程序
;-------------------------------------------------------
CONV:
MOV X,#9 ;設置顯示起始位置
MOV A,R3
ANL A,#0F0H ;取出高四位二進制數
SWAP A ;高四位與低四位互換
PUSH ACC ;壓入堆棧
CLR C ;C=0
SUBB A,#0AH ;減10
POP ACC ;彈出堆棧
JC ASCII0 ;該數小于10，轉ASCII0
ADD A,#07H ;大于10的數加上37H
ASCII0: ADD A,#30H ;小于10的數加上30H
MOV B,X
CALL LCDP2
MOV A,R3
ANL A,#0FH ;取出低四位二進制數
PUSH ACC
CLR C
SUBB A,#0AH ;減10
POP ACC
JC ASCII1 ;該數小于10，轉ASCII1
ADD A,#07H ;大于10的數加上37H
ASCII1: ADD A,#30H ;小于10的數加上30H
INC X
MOV B,X
CALL LCDP2
RET
;-----------------------------------------------------
DELAY2: MOV R5,#15H
DELAY: ;延時R5×10MS
MOV R6,#50
D1: MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;-----------------------------------------------------
DELAY1: ;延時5MS
MOV R6,#25
D2: MOV R7,#100
DJNZ R7,$
DJNZ R6,D2
RET
;------------------------------------------------------
;鍵掃描子程序
;------------------------------------------------------
SCAN_KEY:
SCAN_K: MOV P1,#0F0H
MOV A,P1
CJNE A,#0F0H,KEY_NUM0 ;有鍵按下轉
JMP KEY_END
KEY_NUM0: CALL KEY_IN
CALL BEEP_BL
MOV R5,#04H
CALL DELAY
KEY_END: RET
;-----------------------------------------------------
;反轉法詢鍵值子程序 （A）＝鍵值
;-----------------------------------------------------
KEY_IN: MOV P1,#0F0H ;置列線為0，行線為1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列線為1，行線為0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位與低四位重新組合
CJNE A,#0FFH,KEY_IN1 ;0FFH為末按鍵
RET
KEY_IN1: MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH
KEY_IN2: INC R3
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到，取順序碼
RET
KEY_IN3: CJNE A,#0FFH,KEY_IN2 ;末完，繼續查
RET ;0FFH為結束碼
;-----------------------------------------------------
KEYTABLE:
DB 0EEH,0EDH,0EBH,0E7H,0DEH ;0,1,2,3,4, 順序碼
DB 0DDH,0DBH,0D7H,0BEH,0BDH ;5,6,7,8,9,
DB 0BBH,0B7H,07EH,07DH,07BH ;A,B,C,D,E,
DB 077H,0FFH ;F 0FF為結束碼
;-------------------------------------------------------
;=================================================
;寫串行E2PROM子程序
;(R1)=欲寫數據存放地址指針
;(R7)=連續讀字節數
;24CO1一次可連續寫8個字節，12個字節分兩次寫。
;=================================================
EEPW: PUSH ACC
PUSH PSW
CLR PSW.3
SETB PSW.4
MOV R1,#PASS_NEW
MOV R7,#06H ;連續寫8個字節
LCALL START
MOV A,#0A0H ;送器件地址
ACALL SUBS
MOV A,#00H ;送片內字節地址
ACALL SUBS
AGAIN1:
MOV A,@R1
ACALL SUBS ;調發送單字節子程序
INC R1
DJNZ R7,AGAIN1 ;連續寫8個字節
LCALL STOP ;發停止信號
POP PSW
POP ACC
RET
SUBS:
MOV R0,#08H ;發送單字節子程序
LOOP: CLR SCLK24
RLC A
MOV SDA,C
NOP
SETB SCLK24
ACALL DELAY24
DJNZ R0,LOOP ;循環8次送8個bit
CLR SCLK24
ACALL DELAY24
SETB SCLK24
REP: MOV C,SDA
JC REP ;判應答到否，未到則等待
CLR SCLK24
RET
DELAY24:
NOP
NOP
RET
;=========================================================
;讀串行E2PROM子程序EEPR
;(R1)=欲讀數據存放地址指針
;(R7)=連續讀字節數
;=========================================================
EEPR: PUSH ACC
PUSH PSW
CLR PSW.3
SETB PSW.4
MOV R7,#06H
MOV R1,#PASS_OLD
LCALL START ;發開始信號
MOV A,#0A0H ;送器件地址
ACALL SUBS ;調發送單字節子程序
MOV A,#00H ;送片內字節地址
ACALL SUBS
LCALL START ;再發開始信號
MOV A,#0A1H
ACALL SUBS
MORE: ACALL SUBR
MOV @R1,A
MOV A,#00H
INC R1
DJNZ R7,MORE
LCALL STOP ;送停止信號
POP PSW
POP ACC
RET
SUBR: MOV R0,#08H ;接受單字節子程序
LOOP2: SETB SCLK24
ACALL DELAY24
MOV C,SDA
RLC A
CLR SCLK24
ACALL DELAY24
DJNZ R0,LOOP2
CJNE R7,#01H,ALOW
SETB SDA ;若是最后一個字節置SDA=1
AJMP SETOK
ALOW:
CLR SDA ;否則置SDA=0
SETOK: ACALL DELAY24
SETB SCLK24
ACALL DELAY24
CLR SCLK24
ACALL DELAY24
SETB SDA ;應答畢,SDA置1
RET
START:
CLR SDA
ACALL DELAY24
SETB SDA
SETB SCLK24
ACALL DELAY24
CLR SDA
SETB SCLK24
RET
STOP:
CLR SDA
SETB SCLK24
ACALL DELAY24
SETB SDA
ACALL DELAY24
RET
;===============================================
;蜂鳴器響一聲子程序
;===============================================
BEEP_BL:
MOV R6,#100
BL2: CALL DEX1
CPL BEEP
DJNZ R6,BL2
MOV R5,#15
CALL DELAY_BL
RET
DEX1: MOV R7,#180
DE2: NOP
DJNZ R7,DE2
RET
;-------------------------------------------
DELAY_BL: ;(R5)*延時10MS
MOV R6,#50
DL1: MOV R7,#100
DJNZ R7,$
DJNZ R6,DL1
DJNZ R5,DELAY_BL
RET
;-------------------------------------------
END
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -