;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
;                   單片機與單片機通信實例（從機1）
;功能：通過串口接收主機的詢問信號，然后通過串口返回脈沖數
;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
ORG 0000H
JMP START                 ; 程序開始
ORG 0023H                 
JMP Serial_RX_ISR           ; 串口中斷向量

START:    
      MOV SP,#60H         ; 將堆棧位置設為60H
      CALL Init             ; 進行串口及相關寄存器的初始化       

MainLoop:
;－－－－－－－－－－－－－－－－－－－－－－－
; 主循環：
;－－－－－－－－－－－－－－－－－－－－－－－
      JMP MainLoop           

Init:
;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
;     程序初始化，包括串口、定時器T1、中斷的初始化
;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
      MOV SCON,#11110000B    ; 串口控制寄存器初始化
      ORL PCON,#10000000B    ; 把SMOD位置1
      SETB EA                 ; 中斷允許總控制位使能
      SETB ES                 ; 串口中斷使能
      SETB PS                 ; 把串口中斷設為高優先級
      CALL Timer0_Init        ; 進行定時器T0的初始化
      CALL Timer1_Init         ; 進行定時器T1的初始化
      RET
Timer0_Init:
;－－－－－－－－－－－－－－－－－－－－－－－－－
;    T0作為計數器
;－－－－－－－－－－－－－－－－－－－－－－－－－
      ORL TMOD,#00000101B   ; 計數器T0工作在方式1
      ORL TCON,#00010000B   ; 計數器T0使能
      RET
Timer1_Init:
;－－－－－－－－－－－－－－－－－－－－－－－－－
;     定時器T1作為串口的波特率發生器
;     (2^SMOD)*fosc/32*12*(256-th1)=57600
;－－－－－－－－－－－－－－－－－－－－－－－－－
      ORL TMOD,#00100000B   ; 定時器T1工作在方式2
      ORL TCON,#01000000B    ; 定時器T1使能
      MOV TH1,#0FFH          ; 設定定時器T1的初始值
      RET

Serial_TX:
;－－－－－－－－－－－－－－－－－－－－－－－
;   串口發送，采用查詢的方式
;－－－－－－－－－－－－－－－－－－－－－－－
       MOV A,R1            ; 將要發送的數據寫入A
       MOV SBUF,a            ; 將一個字節寫入串口緩存中
Serial_TX_WAIT1:
       JNB TI,Serial_TX_WAIT1 ; 等待該字節數據發送完成
       NOP
       CLR TI                ; 軟件清除串口發送中斷標志位

       MOV A,R2              ; 將要發送的數據寫入A
       MOV SBUF,a            ; 將一個字節寫入串口緩存中
Serial_TX_WAIT2:
       JNB TI,Serial_TX_WAIT2 ; 等待該字節數據發送完成
       NOP
       CLR TI                ; 軟件清除串口發送中斷標志位      
       RET

Serial_RX_ISR:
;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
;     串口接收中斷服務程序，需要在程序開始時在2FH處寫入緩存區首地址
;－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
       PUSH PSW                   ; 程序狀態字壓棧
       PUSH 1                      ; R1壓棧
       PUSH 2                     ; R2壓棧
       
       MOV C,TI
       CLR TI
JC OUT_ISR
       
       MOV A,SBUF 
       CJNE A,#01,Out_ISR         ; 判斷是否為從機1的命令幀
       CLR SM2                    ; 把SM2清零
       CLR ES                     ; 禁止串口中斷
       CLR RI                      ; 軟件清除串口接收中斷標志
       NOP
Serial_RX_WAIT:                    ; 等待下一個字節數據的接收     
       JNB RI,Serial_RX_WAIT
       MOV A,SBUF                ; 將接收到的數據寫入A
       CJNE A,#0FEH,Out_ISR
       MOV A,TH0
       MOV R1,A                   ; 計數器高位放入R1
       MOV A,TL0
       MOV R2,A                   ; 計數器低位放入R2
       CALL Serial_TX              ; 應答主機
       SETB SM2                   ; SM2置1
Out_ISR:  
       CLR RI                     ; 軟件清除串口接收中斷標志位
       POP 2                      ; R2 出棧
       POP 1                       ; R1 出棧
       POP PSW                    ; 程序狀態字出棧
       RETI       
                
       END