<%@Language = "VBScript"%>
<%
Option Explicit
Response.Buffer = True
Response.Expires = -1000

%>
<!-- #INCLUDE FILE="inifiles.asp" -->
<!-- #INCLUDE FILE = "chatlib.asp" -->
<%

Dim vUserToKick, vBanUser
Dim vMyName, vMyPassword
Dim vRoomNo
Dim vUserArray, vUserCount

vUserToKick = Request.QueryString("UserToBan")
vBanUser = (Request.QueryString("Ban") = "True")

vMyName = Session("ChatName")
vMyPassword = Session("Password")

If CheckOp(vMyName, vMyPassword) = "OK" Then
	vRoomNo = Session("RoomNo")
	Application.Lock
	vUserArray = Application("ChatUsers" & vRoomNo)
	vUserCount = Application("UserCount" & vRoomNo)
	If KickUser(vUserToKick, vBanUser, vUserArray, vUserCount) = True Then
		Response.Write "Result=OK"
	Else
		Response.Write "Result=Failed"
	End If
	Application("ChatUsers" & vRoomNo) = vUserArray
	Application("UserCount" & vRoomNo) = vUserCount
	Application.Unlock
Else
	Response.Write "Result=BadPassword"
End If

Function KickUser(ByVal vUserName, vBan, vUserArray, vUserCount)

	Dim vUser

	For vUser = 0 To vUserCount - 1
		If UCase(vUserArray(vUser)) = UCase(vUserName) Then
			If vBan Then
				vUserArray(vUser) = vUserArray(vUser) & "[banned]"
			Else
				vUserArray(vUser) = vUserArray(vUser) & "[kicked]"
			End If
			KickUser = True
			Exit Function
		End If
	Next
	KickUser = False
	
End Function

Response.Flush
Response.End
%>