<%
Function LogUserIn(ByVal vUserName, vUserArray, vMoodArray, vUserCount)

	Dim vUser

	vUserName = Trim(vUserName)
	If vUserName = "" Or Request.Cookies("BannedFromChat") = "True" Then
		LogUserIn = False
	Else
		If vUserCount = 0 Then
			vUserCount = 1
			Redim vUserArray(1)
			Redim vMoodArray(1)
			vUserArray(0) = vUserName
			vMoodArray(0) = 1
		Else
			For vUser = 0 To vUserCount - 1
				If UCase(vUserArray(vUser)) = UCase(vUserName) Then
					LogUserIn = False
					Exit Function
				End If
			Next
			vUserCount = vUserCount + 1
			Redim Preserve vUserArray(vUserCount - 1)
			Redim Preserve vMoodArray(vUserCount - 1)
			vUserArray(vUserCount - 1) = vUserName
			vMoodArray(vUserCount - 1) = 1
		End If
		LogUserIn = True
	End If
	
End Function

Function LogUserOut(ByVal vUserName, vUserArray, vMoodArray, vUserCount)

	Dim vUser, vThisUser

	vThisUser = -1
	For vUser = 0 To vUserCount - 1
		If vUserArray(vUser) = vUserName Then
			vThisUser = vUser
			Exit For	
		End If
	Next
	If vThisUser = -1 Then
		LogUserOut = False	
	Else
		For vUser = vThisUser To vUserCount - 2
			vUserArray(vUser) = vUserArray(vUser + 1)
			vMoodArray(vUser) = vMoodArray(vUser + 1)
		Next
		vUserCount = vUserCount - 1
		Redim Preserve vUserArray(vUserCount - 1)
		Redim Preserve vMoodArray(vUserCount - 1)
		LogUserOut = True
	End If

End Function

Sub AddLineToChat(ByVal vRoomNo, ByVal vNewLine)

	Dim vCurrentLine, vChatLines, vMaxLines

	vCurrentLine = Application("ChatLineCount" & vRoomNo)
	vChatLines = Application("ChatLines" & vRoomNo)
	vMaxLines = Application("ChatMaxLines" & vRoomNo)
	vCurrentLine = vCurrentLine + 1
	If vCurrentLine > vMaxLines Then
		vMaxLines = vMaxLines + 500
		If vCurrentLine = 1 Then
			Redim vChatLines(vMaxLines)
		Else
			Redim Preserve vChatLines(vMaxLines)
		End If
		Application("ChatMaxLines" & vRoomNo) = vMaxLines
	End If
	vChatLines(vCurrentLine - 1) = vNewLine
	Application("ChatLines" & vRoomNo) = vChatLines
	Application("ChatLineCount" & vRoomNo) = vCurrentLine
	
End Sub

Function CheckOp(ByVal vName, ByVal vPassword)

	Dim vOpName, vOpPassword
	Dim vOpCount
	Dim vINIFile
	
	vINIFile = Application("INIFile")
	
	Do
		vOpCount = vOpCount + 1
		vOpName = "" & IniFileValue(vINIFile, "Ops", "Op" & vOpCount & "Name")
		vOpPassword = "" & IniFileValue(vINIFile, "Ops", "Op" & vOpCount & "Password")
		If vOpName = "" Then Exit Do
		If UCase(vOpName) = UCase(vName) Then
			If UCase(vOpPassword) = UCase(vPassword) Then
				CheckOp = "OK"
			Else
				CheckOp = "BadPassword"
			End If
			Exit Function
		End If
	Loop
	
	CheckOp = "NotOP"
	
End Function
%>