<%
Class Cls_vbsPage
	Private oConn		'連接對象
	Private iPagesize	'每頁記錄數(shù)
	Private sPageName	'地址欄頁數(shù)參數(shù)名
	Private sDbType
	'數(shù)據(jù)庫類型,AC為access,MSSQL為SQL SERVER2000存儲過程版,MYSQL為mysql,PGSQL為PostGreSql
	Private iRecType	'記錄總數(shù)(>0為另外取值再賦予或者固定值,0執(zhí)行count設(shè)置存cookies,-1執(zhí)行count不設(shè)置cookies)
	Private sJsUrl		'Cls_jsPage.js的路徑
	Private sField		'字段名
	Private sTable		'表名
	Private sCondition	'條件,不需要where
	Private sOrderBy	'排序,不需要order by,需要asc或者desc
	Private sPkey		'主鍵,必寫
	Private iRecCount

	'================================================================
	' Class_Initialize 類的初始化
	'================================================================
	Private Sub Class_Initialize
		iPageSize=10
		sPageName="Page"
		sDbType="AC"
		iRecType=0
		sJsUrl=""
		sField=" * "
	End Sub

	'================================================================
	' Conn 得到數(shù)據(jù)庫連接對象
	'================================================================
	Public Property Set Conn(ByRef Value)
		Set oConn=Value
	End Property

	'================================================================
	' PageSize 設(shè)置每一頁記錄條數(shù),默認10記錄
	'================================================================
	Public Property Let PageSize(ByVal intPageSize)
		iPageSize=CheckNum(intPageSize,0,0,iPageSize,0) 
	End Property

	'================================================================
	' PageName 地址欄頁數(shù)參數(shù)名
	'================================================================
	Public Property Let PageName(ByVal strPageName)
		sPageName=IIf(Len(strPageName)<1,sPageName,strPageName)
	End Property

	'================================================================
	' DbType 得到數(shù)據(jù)庫類型
	'================================================================ 
	Public Property Let DbType(ByVal strDbType)
		sDbType=UCase(IIf(Len(strDbType)<1,sDbType,strDbType))
	End Property

	'================================================================
	' RecType 取記錄總數(shù)(>0為賦值或者固定值,0執(zhí)行count設(shè)置存cookies,-1執(zhí)行count不設(shè)置cookies適用于搜索)
	'================================================================
	Public Property Let RecType(ByVal intRecType)
		iRecType=CheckNum(intRecType,0,0,iRecType,0) 
	End Property

	'================================================================
	' JsUrl 取得Cls_jsPage.js的路徑
	'================================================================
	Public Property Let JsUrl(ByVal strJsUrl)
		sJsUrl=strJsUrl
	End Property

	'================================================================
	' Pkey 取得主鍵
	'================================================================
	Public Property Let Pkey(ByVal strPkey)
		sPkey=strPkey
	End Property

	'================================================================
	' Field 取得字段名
	'================================================================
	Public Property Let Field(ByVal strField)
		sField=IIf(Len(strField)<1,sField,strField)
	End Property

	'================================================================
	' Table 取得表名
	'================================================================
	Public Property Let Table(ByVal strTable)
		sTable=strTable
	End Property

	'================================================================
	' Condition 取得條件
	'================================================================
	Public Property Let Condition(ByVal strCondition)
		s=strCondition
		sCondition=IIf(Len(s)>2," WHERE "&s,"")
	End Property

	'================================================================
	' OrderBy 取得排序
	'================================================================
	Public Property Let OrderBy(ByVal strOrderBy)
		s=strOrderBy
		sOrderBy=IIf(Len(s)>4," ORDER BY "&s,"")
	End Property

	'================================================================
	' RecCount 修正記錄總數(shù)
	'================================================================
	Public Property Get RecCount()
		If iRecType>0 Then
			i=iRecType
		Elseif iRecType=0 Then
			i=CheckNum(Request.Cookies("ShowoPage")(sPageName),1,0,0,0)
			s=Trim(Request.Cookies("ShowoPage")("sCond"))
			IF i=0 OR sCondition<>s Then
				i=oConn.Execute("SELECT COUNT("&sPkey&") FROM "&sTable&" "&sCondition,0,1)(0)
				Response.Cookies("ShowoPage")(sPageName)=i
				Response.Cookies("ShowoPage")("sCond")=sCondition
			End If
		Else
			i=oConn.Execute("SELECT COUNT("&sPkey&") FROM "&sTable&" "&sCondition,0,1)(0)
		End If
		iRecCount=i
		RecCount=i
	End Property

	'================================================================
	' ResultSet 返回分頁后的記錄集
	'================================================================
	Public Property Get ResultSet()
		s=Null
		'記錄總數(shù)
		i=iRecCount
		'當前頁
		If i>0 Then
			iPageCount=Abs(Int(-Abs(i/iPageSize)))'頁數(shù)
			iPageCurr=CheckNum(Request.QueryString(sPageName),1,1,1,iPageCount)'當前頁
			Select Case sDbType
				Case "MSSQL" 'sqlserver2000數(shù)據(jù)庫存儲過程版
					Set Rs=server.CreateObject("Adodb.RecordSet")
					Set Cm=Server.CreateObject("Adodb.Command")
					Cm.CommandType=4
					Cm.ActiveConnection=oConn
					Cm.CommandText="sp_Util_Page"
					Cm.parameters(1)=i
					Cm.parameters(2)=iPageCurr
					Cm.parameters(3)=iPageSize
					Cm.parameters(4)=sPkey
					Cm.parameters(5)=sField
					Cm.parameters(6)=sTable
					Cm.parameters(7)=Replace(sCondition," WHERE ","")
					Cm.parameters(8)=Replace(sOrderBy," ORDER BY ","")
					Rs.CursorLocation=3
					Rs.LockType=1
					Rs.Open Cm
				Case "MYSQL" 'MYSQL數(shù)據(jù)庫
					ResultSet_Sql="SELECT "&sField&" FROM "&sTable&" "&sCondition&" "&sOrderBy&" LIMIT "&(iPageCurr-1)*iPageSize&","&iPageSize
					Set Rs=oConn.Execute(ResultSet_Sql)
				Case Else '其他情況按最原始的方法處理(AC同理)
					Set Rs = Server.CreateObject ("Adodb.RecordSet")
					ResultSet_Sql="SELECT "&sField&" FROM "&sTable&" "&sCondition&" "&sOrderBy
					Rs.Open ResultSet_Sql,oConn,1,1,&H0001
					Rs.AbsolutePosition=(iPageCurr-1)*iPageSize+1
			End Select
			s=Rs.GetRows(iPageSize)
			Rs.close
			Set Rs=Nothing
		End If
		ResultSet=s
	End Property

	'================================================================
	' Class_Terminate 類注銷
	'================================================================
	Private Sub Class_Terminate()
		If IsObject(oConn) Then oConn.Close:Set oConn=Nothing
	End Sub

	'================================================================
	' 輸入:檢查字符,是否有最小值,是否有最大值,最小值(默認數(shù)字),最大值
	'================================================================
	Private Function CheckNum(ByVal strStr,ByVal blnMin,ByVal blnMax,ByVal intMin,ByVal intMax)
		Dim i,s,iMi,iMa
		s=Left(Trim(""&strStr),32):iMi=intMin:iMa=intMax
		If IsNumeric(s) Then
			i=CDbl(s)
			i=IIf(blnMin=1 And i<iMi,iMi,i)
			i=IIf(blnMax=1 And i>iMa,iMa,i)
		Else
			i=iMi
		End If
		CheckNum=i
	End Function

	'================================================================
	' 輸入:簡化條件判斷
	'================================================================
	Private Function IIf(ByVal blnBool,ByVal strStr1,ByVal strStr2)
		Dim s
		If blnBool Then
			s=strStr1
		Else
			s=strStr2
		End If
		IIf=s
	End Function

	'================================================================
	' 上下頁部分
	'================================================================
	Public Sub ShowPage()%>
		<Script Language="JavaScript" type="text/JavaScript" src="<%=sJsUrl%>Cls_jsPage.js"></Script>
		<Script Language="JavaScript" type="text/JavaScript">
		var s= new Cls_jsPage(<%=iRecCount%>,<%=iPageSize%>,3,"s"); 
		s.setPageSE("<%=sPageName%>=","");
		s.setPageInput("<%=sPageName%>");
		s.setUrl("");
		s.setPageFrist("首頁","<<");
		s.setPagePrev("上頁","<");
		s.setPageNext("下頁",">");
		s.setPageLast("尾頁",">>");
		s.setPageText("[{$PageNum}]","第{$PageNum}頁");
		s.setPageTextF(" {$PageTextF} "," {$PageTextF} ");
		s.setPageSelect("{$PageNum}","第{$PageNum}頁");
		s.setPageCss("","","");
		s.setHtml("共{$RecCount}記錄 頁次{$Page}/{$PageCount} 每頁{$PageSize}條 {$PageFrist} {$PagePrev} {$PageText} {$PageNext} {$PageLast} {$PageInput} {$PageSelect}");
		s.Write();
		</Script>
	<%End Sub

End Class%>