?class Panorama {
	// 兩個影片實例之間的距離
	private static var SPACE = 0;
	// 影片剪輯的寬度減去舞臺寬度的數值
	private static var DISTANCE:Number;
	// 影片剪輯的寬度
	private static var IMG_W:Number;
	//
	public function Panorama(path:MovieClip, obj:String) {
		if (path != undefined && obj != undefined) {
			addMovieClip(path,obj);
		} else {
			trace("沒有指定路徑，或者沒有指定影片剪輯的連接名稱。");
		}
	}
	// 
	public function addMovieClip(path:MovieClip, obj:String):Void {
		for (var i = 0; i<2; i++) {
			path.attachMovie(obj,obj+i,path.getNextHighestDepth());
			//path[obj+i]._y = 0;
		}
		//
		IMG_W = path[obj+"0"]._width;
		DISTANCE = IMG_W-Stage.width;
		// 排列新增的兩個對象
		path[obj+"1"]._x = path[obj+"0"]._x-IMG_W-SPACE;
		// 設定回應鼠標事件
		addMouseEvent(path, path[obj+"0"], path[obj+"1"]);
	}
	//
	private function addMouseEvent(path:MovieClip, img_1:MovieClip, img_2:MovieClip):Void {
		var mouseListener:Object = new Object();
		var startX:Number;
		// 按下滑鼠鈕的事件處理函數
		mouseListener.onMouseDown = function() {
			startX = _root._xmouse;
			path.onEnterFrame = function() {
				var dx:Number = (this._xmouse-startX)/30;
				if (img_1._x>=0) {
					img_2._x = img_1._x-IMG_W-SPACE;
				}
				if (img_2._x>=0) {
					img_1._x = img_2._x-IMG_W-SPACE;
				}
				if (img_1._x<=-DISTANCE) {
					img_2._x = img_1._x+IMG_W+SPACE;
				}
				if (img_2._x<=-DISTANCE) {
					img_1._x = img_2._x+IMG_W+SPACE;
				}
				img_1._x += dx;
				img_2._x += dx;
			};
		};
		// 放開滑鼠鈕的事件處理函數
		mouseListener.onMouseUp = function() {
			delete path.onEnterFrame;
		};
		//
		Mouse.addListener(mouseListener);
	}
}