;********************MCOBCDTU********************
;本程序實現多字節壓縮BCD碼數轉化為非壓縮BCD碼。
;入口參數：原非壓縮BCD碼地址在SADR中,字節數在CNT中（小于128字節）。
;出口參數：結果存放在以原數據地址為首地址的RAM中,地址在SADR中,字節數在CNT中。
;占用資源：W,FSR,STATUS,020H,021H,023H,028H,029H,02AH,一重堆棧。

           IFNDEF       MCOBCDTU1
            #DEFINE     MCOBCDTU1
                        
MCOBCDTU    MOVF        SADR,W
            MOVWF       TEMP2       
            MOVF        CNT,W
            MOVWF       TEMP3
            ADDWF       CNT,W
            MOVWF       CNT         ;結果字節數
            ADDWF       SADR,F
            DECF        SADR,F      ;結果最高位地址
            DECF        TEMP3,W
            ADDWF       TEMP2,F     ;原數據最高位字節地址
LOOP34      MOVF        TEMP2,W
            MOVWF       FSR
            SWAPF       INDF,W
            MOVWF       TEMP1       ;暫存
            MOVF        SADR,W
            MOVWF       FSR
            MOVF        TEMP1,W
            ANDLW       0FH
            MOVWF       INDF
            DECF        FSR,F
            SWAPF       TEMP1,W
            ANDLW       0FH
            MOVWF       INDF
            DECF        TEMP2,F
            DECF        SADR,F
            DECF        SADR,F
            DECFSZ      TEMP3,F
            GOTO        LOOP34
            INCF        SADR,F
            RETURN
           ENDIF