if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_DateADD]') and xtype in (N'FN', N'IF', N'TF'))
	drop function [dbo].[f_DateADD]
GO

/*--特殊日期加減函數(shù)

	對(duì)于日期指定部分的加減，使用DATEADD函數(shù)就可以輕松實(shí)現(xiàn)。
	在實(shí)際的處理中，還有一種比較另類的日期加減處理
	就是在指定的日期中，加上（或者減去）多個(gè)日期部分
	比如將2005年3月11日，加上1年3個(gè)月11天2小時(shí)。
	對(duì)于這種日期的加減處理，DATEADD函數(shù)的力量就顯得有點(diǎn)不夠。

	本函數(shù)實(shí)現(xiàn)這樣格式的日期字符串加減處理：
	y-m-d h:m:s.m | -y-m-d h:m:s.m
	說明：
	要加減的日期字符輸入方式與日期字符串相同。日期與時(shí)間部分用空格分隔
	最前面一個(gè)字符如果是減號(hào)（-）的話，表示做減法處理，否則做加法處理。
	如果日期字符只包含數(shù)字，則視為日期字符中，僅包含天的信息。
--*/

/*--調(diào)用示例

	SELECT dbo.f_DateADD(GETDATE(),'11:10')
--*/

CREATE FUNCTION dbo.f_DateADD(
@Date     datetime,
@DateStr   varchar(23)
)RETURNS datetime
AS
BEGIN
	DECLARE @bz int,@s varchar(12),@i int

	IF @DateStr IS NULL OR @Date IS NULL 
		OR(CHARINDEX('.',@DateStr)>0
			AND @DateStr NOT LIKE '%[:]%[:]%.%')
		RETURN(NULL)
	IF @DateStr='' RETURN(@Date)

	SELECT @bz=CASE 
			WHEN LEFT(@DateStr,1)='-' THEN -1
			ELSE 1 END,
		@DateStr=CASE 
			WHEN LEFT(@Date,1)='-' 
			THEN STUFF(RTRIM(LTRIM(@DateStr)),1,1,'')
			ELSE RTRIM(LTRIM(@DateStr)) END

	IF CHARINDEX(' ',@DateStr)>1
		OR CHARINDEX('-',@DateStr)>1
		OR(CHARINDEX('.',@DateStr)=0
			AND CHARINDEX(':',@DateStr)=0)
	BEGIN
		SELECT @i=CHARINDEX(' ',@DateStr+' ')
			,@s=REVERSE(LEFT(@DateStr,@i-1))+'-'
			,@DateStr=STUFF(@DateStr,1,@i,'')
			,@i=0
		WHILE @s>'' and @i<3
			SELECT @Date=CASE @i
					WHEN 0 THEN DATEADD(Day,@bz*REVERSE(LEFT(@s,CHARINDEX('-',@s)-1)),@Date)
					WHEN 1 THEN DATEADD(Month,@bz*REVERSE(LEFT(@s,CHARINDEX('-',@s)-1)),@Date)
					WHEN 2 THEN DATEADD(Year,@bz*REVERSE(LEFT(@s,CHARINDEX('-',@s)-1)),@Date)
				END,
				@s=STUFF(@s,1,CHARINDEX('-',@s),''),
				@i=@i+1				
	END
	IF @DateStr>''
	BEGIN
		IF CHARINDEX('.',@DateStr)>0
			SELECT @Date=DATEADD(Millisecond
					,@bz*STUFF(@DateStr,1,CHARINDEX('.',@DateStr),''),
					@Date),
				@DateStr=LEFT(@DateStr,CHARINDEX('.',@DateStr)-1)+':',
				@i=0
		ELSE
			SELECT @DateStr=@DateStr+':',@i=0
		WHILE @DateStr>'' and @i<3
			SELECT @Date=CASE @i
					WHEN 0 THEN DATEADD(Hour,@bz*LEFT(@DateStr,CHARINDEX(':',@DateStr)-1),@Date)
					WHEN 1 THEN DATEADD(Minute,@bz*LEFT(@DateStr,CHARINDEX(':',@DateStr)-1),@Date)
					WHEN 2 THEN DATEADD(Second,@bz*LEFT(@DateStr,CHARINDEX(':',@DateStr)-1),@Date)
				END,
				@DateStr=STUFF(@DateStr,1,CHARINDEX(':',@DateStr),''),
				@i=@i+1
	END

	RETURN(@Date)
END
GO