?? 3d-qfp-定稿.txt
字號:
FINI
/CLE
/UNITS,SI !國際單位制
/FILNAME,QFP !制定文件名為QFP
/TITLE,3D THERMAL SIMULATION OF QFP !制定標題
!定義結構參數
!定義PCB的尺寸
*SET,PCB_L,40E-3 !PCB長度
*SET,PCB_W,40E-3 !PCB寬度
*SET,PCB_H,2E-3 !PCB高度
!定義芯片尺寸
*SET,C_L,15E-3 !芯片長度
*SET,C_W,15E-3 !芯片寬度
*SET,C_H,2.5E-3 !芯片高度
!定義引線上下部分尺寸
*SET,LES_L,1.5E-3 !引線兩端長度
*SET,LEM_H,1.2E-3 !引線中間長度
*SET,LE_W,0.3E-3 !引線寬度
*SET,LE_T,0.4E-3 !引線厚度
*SET,LE_NB,12 !芯片一側引腳數
*SET,LE_DIST,1E-3 !引線間距
!定義焊料尺寸
*SET,SO_L,1.5E-3 !焊點長度
*SET,SO_H,0.15E-3 !焊點高度
*SET,SO_T,0.4E-3 !焊點厚度
!定義熱介質材料的尺寸
*SET,TIM_H,0.15E-3 !熱介質厚度
!定義熱擴展面的尺寸
*SET,HS_L,25E-3 !熱擴展面長度
*SET,HS_W,25E-3 !熱擴展面寬度
*SET,HS_H,1.5E-3 !熱擴展面厚度
!定義粘結劑的尺寸
*SET,SA_H,0.15E-3 !粘結劑厚度
!定義熱沉基座的尺寸
*SET,SINK_L,28E-3 !熱沉基座長度
*SET,SINK_W,28E-3 !熱沉基座寬度
*SET,SINK_H,1.5E-3 !熱沉基座厚度
*SET,FIN_NB,10 !散熱片數量
*SET,FIN_H,4E-3 !散熱片高度
*SET,FIN_T,1E-3 !散熱片厚度
*SET,FIN_DIST,2.8E-3 !散熱片間距
!************************
!*******前處理***********
!************************
/PREP7 !進入前處理
ET,1,SOLID70 !定義單元類型
MP,KXX,1,82 !定義芯片的導熱系數
MP,KXX,2,390 !定義引線材料(Cu)的導熱系數
MP,KXX,3,50 !定義焊料(63Sn37Pb)的導熱系數
MP,KXX,4,8.37 !定義PCB的導熱系數（各項異性）
MP,KYY,4,8.37
MP,KZZ,4,0.32
MP,KXX,5,1.1 !定義粘結劑的導熱系數
MP,KXX,6,1 !定義熱介質材料的導熱系數
MP,KXX,7,240 !定義熱沉(Al)的導熱系數
MP,KXX,8,390 !定義熱擴展面(Cu)的導熱系數
!實體建模
BLOCK,0,PCB_L/2,0,PCB_W/2,0,PCB_H !建立PCB板
WPOFF,0,0,PCB_H+SO_H+LEM_H+2*LE_W-C_H/2 !偏移坐標系
CSWPLA,11,0 !定義編號為11的局部坐標系
BLOCK,0,C_L/2,0,C_W/2,0,C_H !建立芯片
BLOCK,0,C_L*3/8,0,C_W*3/8,0,C_H
VSEL,S,LOC,Z,0,C_H !選擇芯片部分
VOVLAP,ALL !疊分選擇的部分
WPOFF,C_L/2,(LE_DIST-LE_T)/2,C_H/2 !偏移坐標系
BLOCK,0,LES_L,0,LE_T,0,-LE_W !建立引線上端
WPOFF,LES_L,0,-LE_W !偏移坐標系
BLOCK,0,-LE_W,0,LE_T,0,-LEM_H !建立引線中端
WPOFF,-LE_W,0,-LEM_H !偏移坐標系
BLOCK,0,LES_L,0,LE_T,0,-LE_W !建立引線下端
BLOCK,0,LES_L,0,LE_T,-LE_W,-LE_W-SO_H !建立釬焊部分
CSYS !激活初始笛卡爾坐標系
WPCSYS !工作坐標系和當前坐標系重合
VSEL,S,LOC,X,C_L/2,C_L/2+2*LES_L !選擇引線和焊料實體
VSEL,R,LOC,Z,PCB_H,PCB_H*5
VGEN,LE_NB/2,ALL,,,,LE_DIST,,,0 !對所選實體沿Y向復制
VSEL,S,LOC,X,C_L/2,C_L/2+2*LES_L !選擇復制得到的引線和焊料實體
VSEL,R,LOC,Z,PCB_H,PCB_H*5
WPROTA,-45,0,0 !工作平面繞Z軸旋轉－45度
CSWPLA,12,0 !定義編號為12的局部坐標系
VSYMM,X,ALL,,,,0,0 !對引線和焊料進行鏡像復制
CSYS,11 !激活編號為11的局部坐標系
WPCSYS !工作坐標系和當前坐標系重合
BLOCK,0,C_L/2,0,C_W/2,C_H,C_H+TIM_H !建立熱介質材料部分
WPOFF,0,0,C_H+TIM_H !偏移坐標系
CSWPLA,13,0 !建立編號為13的局部坐標系
*SET,HS_H1,TIM_H+C_H/2+2*LE_W+SO_H+LEM_H-SA_H !定義熱擴展面相關的一個參量
BLOCK,0,HS_L/2,0,HS_W/2,0,HS_H !建立熱擴展面
BLOCK,HS_L/2,HS_L/2-HS_H,0,HS_W/2,0,-HS_H1 !建立熱擴展面
BLOCK,HS_L/2,HS_L/2-HS_H,0,HS_W/2,-HS_H1,-HS_H1-SA_H !建立熱擴展面和PCB間的粘結劑部分
BLOCK,0,HS_L/2-HS_H,HS_W/2,HS_W/2-HS_H,0,-HS_H1 !建立熱擴展面
BLOCK,0,HS_L/2-HS_H,HS_W/2,HS_W/2-HS_H,-HS_H1,-HS_H1-SA_H!建立熱擴展面和PCB間的粘結劑
BLOCK,0,HS_L/2,0,HS_W/2,HS_H,HS_H+SA_H !建立熱擴展面和熱沉間的熱介質材料
BLOCK,0,SINK_L/2,0,SINK_W/2,HS_H+SA_H,HS_H+SA_H+SINK_H !建立熱沉部分
WPOFF,0,0,HS_H+SA_H+SINK_H !偏移坐標系
CSWPLA,14,0 !建立編號為14的局部坐標系
*SET,FIN_DT, (FIN_DIST-FIN_T)/2
BLOCK,FIN_DT,FIN_DT+FIN_T,0,SINK_W/2,0,FIN_H !建立熱沉的散熱片
VSEL,S,LOC,Z,0,FIN_H !選擇建立的散熱片
VGEN,FIN_NB/2,ALL,,,FIN_DIST,,,,0 !沿X向復制散熱片
!將PCB分為三部分，便于對結構規則部分進行SWEEP進行網格劃分
CSYS !激活初始笛卡爾坐標系
WPCSYS !工作坐標系和當前坐標系重合
BLOCK,0,HS_L/2,0,HS_W/2,0,PCB_H !建立熱擴展面大小的一個實體
BLOCK,0,C_L/2,0,C_W/2,0,PCB_H !建立芯片大小的一個實體
VSEL,S,LOC,Z,0,PCB_H !選擇整個PCB板部分
VOVLAP,ALL !疊分選擇的部分
ALLSEL,ALL !選擇所有組元
VGLUE,ALL !粘接所有實體
NUMCMP,ALL !壓縮所有組元編號
!賦材料屬性
CSYS
VSEL,S,LOC,Z,0,PCB_H !選擇PCB板
VATT,4,,1,0 !定義PCB材料屬性
VSEL,S,LOC,Z,PCB_H,PCB_H+SO_H !選擇一側的焊料部分
VSEL,R,LOC,X,C_L/2,HS_L/2-HS_H
VATT,3,,1,0 !定義焊料材料屬性
VSEL,S,LOC,Z,PCB_H,PCB_H+SO_H !選擇另一側的焊料部分
VSEL,R,LOC,Y,C_L/2,HS_L/2-HS_H
VATT,3,,1,0 !定義焊料材料屬性
VSEL,S,LOC,Z,PCB_H,PCB_H+SA_H !選擇PCB和熱擴展面間一側的粘結劑
VSEL,R,LOC,X,HS_L/2-HS_H,HS_L/2
VATT,5,,1,0 !定義粘結劑材料屬性
VSEL,S,LOC,Z,PCB_H,PCB_H+SA_H !選擇PCB和熱擴展面間另一側的粘結劑
VSEL,R,LOC,Y,HS_L/2-HS_H,HS_L/2
VATT,5,,1,0 !定義粘結劑材料屬性
CSYS,11 !激活編號為11的局部坐標系
VSEL,S,LOC,Z,0,C_H !選擇芯片
VSEL,R,LOC,X,0,C_L/2
VSEL,R,LOC,Y,0,C_W/2
VATT,1,,1,0 !定義芯片材料屬性
VSEL,S,LOC,Z,C_H,C_H+TIM_H !選擇熱介質材料
VSEL,R,LOC,X,0,C_L/2
VSEL,R,LOC,Y,0,C_W/2
VATT,6,,1,0 !定義熱介質材料屬性
VSEL,S,LOC,Z,C_H/2-2*LE_W-LEM_H,C_H/2 !選擇一側引線
VSEL,R,LOC,X,C_L/2,HS_L/2-HS_H
VATT,2,,1,0 !定義引線材料屬性
VSEL,S,LOC,Z,C_H/2-2*LE_W-LEM_H,C_H/2 !選擇另一側引線
VSEL,R,LOC,Y,C_L/2,HS_L/2-HS_H
VATT,2,,1,0 !定義引線材料屬性
CSYS,13 !激活編號為13的局部坐標系
VSEL,S,LOC,Z,0,HS_H !選擇芯片上的熱擴展面
VATT,8,,1,0 !定義熱擴展面材料屬性
VSEL,S,LOC,Z,-HS_H1,0 !選擇芯片一側的熱擴展面
VSEL,R,LOC,X,HS_L/2-HS_H,HS_L/2
VATT,8,,1,0 !定義熱擴展面材料屬性
VSEL,S,LOC,Z,-HS_H1,0 !選擇芯片另一側的熱擴展面
VSEL,R,LOC,Y,HS_L/2-HS_H,HS_L/2
VATT,8,,1,0 !定義熱擴展面材料屬性
VSEL,S,LOC,Z,HS_H,HS_H+SA_H !選擇熱沉與熱擴展面間的熱介質材料部分
VATT,6,,1,0 !定義熱介質材料屬性
VSEL,S,LOC,Z,HS_H+SA_H,5*FIN_H !選擇熱沉部分
VATT,7,,1,0 !定義熱沉材料屬性
!劃分網格
VSEL,S,VOLU,,65,66,1
VSEL,INVE !在整個實體中選擇未選擇的部分
VSWEEP,ALL !對選擇的實體進行映射網格劃分
LSEL,S,LINE,,14,15,1
LESIZE,ALL,,,8
LSEL,S,LINE,,20,22,2
LSEL,A,LINE,,39,41,2
LESIZE,ALL,,,3
LSEL,S,LINE,,704,705,1
LESIZE,ALL,,,5
LSEL,S,LINE,,495,496,1
LESIZE,ALL,,,6
VSEL,S,VOLU,,65,66,1
MSHAPE,1,3D !定義單元類型
VMESH,ALL !進行自由網格劃分
!定義加載條件
!并施加PCB對流和輻射邊界條件
ASEL,S,,,4 !選擇3號面
ASEL,A,,,6 !添加4號面
ASEL,A,,,366 !添加392號面
SFA,ALL,1,CONV,10,25 !定義熱對流
SFA,ALL,,RDSF,0.9,1 !定義熱輻射
!施加熱擴展面對流邊界條件
ASEL,S,AREA,,115,254,139 !選擇115,254號面
ASEL,A,AREA,,347,348,1 !添加347,348號面
ASEL,A,AREA,,367 !添加367號面
SFA,ALL,1,CONV,10,25 !定義熱對流
!施加熱沉對流邊界條件
VSEL,S,MAT,,7 !選擇材料編號為7(熱沉)的實體
ASLV,S !選擇該實體的全部面
ASEL,U,,,117 !不選擇117號面
ASEL,U,,,119,143,6 !不選擇119,125,131,137,143號面
SFA,ALL,1,CONV,10,25 !定義熱對流
!設置輻射計算的參數
STEF,5.67E-8 !定義玻爾茲曼常數（黑體輻射常數）
TOFFST,273 !攝氏溫度和開氏溫度的差值
RADOPT,0.5,0.01,0 !輻射求解設置
SPCTEMP,1,25 !環境溫度
TUNIF,25 !設定初始溫度
!======================
!======加載求解========
!======================
!施加芯片的熱源
VSEL,S,MAT,,1 !選擇材料編號為1(芯片)的實體
BFV,ALL,HGEN,1.778E6 !加載熱源(熱流密度)此時功率為1W
ALLSEL,ALL !選擇所有組元
!求解過程
/SOLU
ANTYPE,STATIC
TIME,1 !設置時間為1
DELTIM,0.5,0.5,0.5 !定義載荷的時間步長
NEQIT,1000 !定義非線性分析中的最大平衡迭代次數
SOLVE !求解
SAVE !保存
!======================
!=======通用后處理=======
!======================
FINISH
/POST1
!查看總體溫度分布圖
PLNSOL,TEMP,,0
!查看芯片溫度分布圖
ESEL,S,MAT,,1
PLNSOL,TEMP,,0
!查看引線的溫度分布圖
ESEL,S,MAT,,2
PLNSOL,TEMP,,0
!查看焊料的溫度分布圖
ESEL,S,MAT,,3
PLNSOL,TEMP,,0
!查看PCB溫度分布圖
ESEL,S,MAT,,4
PLNSOL,TEMP,,0
!查看熱介質材料的溫度分布圖
ESEL,S,MAT,,6
PLNSOL,TEMP,,0
!查看熱沉的溫度分布圖
ESEL,S,MAT,,7
PLNSOL,TEMP,,0
!查看熱擴展面溫度分布圖
ESEL,S,MAT,,8
PLNSOL,TEMP,,0
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -