!參數定義
FINI
/CLE
/FILNAME,MOTAI
/TITLE,MODEL ANALYSIS OF DUCAO
*CREATE,MODEL,MAC				!創建宏文件MODEL
!幾何參數設定
LK=40								!渡槽單跨跨度
W=27								!渡槽寬度
H=7									!槽體高度
HS=5.74							!設計水深
HD=15								!槽墩高度
D1=4								!槽墩上部圓弧直徑
D2=6								!槽墩下部圓弧直徑
HW1=1.5							!槽底橫梁截面下底寬度
HH3=1.475							!槽底橫梁截面慣性軸高度
DW1=3								!頂梁截面上底寬度
DH1=0.5							!頂梁截面高度1
DH2=0.7							!頂梁截面總高度
!槽底縱梁截面尺寸
ZW=0.85							!槽底縱梁截面寬度
ZH=0.5								!槽底縱梁截面高度
!頂部拉桿截面尺寸
LW=0.5								!頂部拉桿寬度
LH=0.35							!頂部拉桿高度
T1=0.7								!墻板厚度
T2=0.35							!槽底厚度
T3=0.6								!槽墩厚度
!材料參數設定
E1=3.25E10							!槽體彈性模量
E2=2.8E10							!槽墩彈性模量
E3=3.86E9							!盆式支座彈性模量
DS1=2500							!槽體密度
DS2=2500							!槽墩密度
DS3=2500							!盆式支座密度
V1=0.167							!槽體泊松比
V2=0.167							!槽墩泊松比
SS=3E7								!盆式支座的屈服應力
!定義單元類型
/PREP7
ET,1,BEAM189
ET,2,SHELL63
ET,3,COMBIN40
ET,4,COMBIN40
ET,5,COMBIN14
KEYOPT,3,3,0   					!X方向
KEYOPT,4,3,2   					!Y方向
KEYOPT,5,1,0						!設置為線性單元
KEYOPT,5,2,3   					!Z方向
SECTYPE,1,BEAM,MESH
SECOFFSET,USER,HH3,HW1/2		!移動槽底橫梁截面的慣性軸位置	
SECREAD,'SEC1','SECT',' ',MESH	!讀取槽底橫梁截面庫文件
SECTYPE,2,BEAM,MESH
SECOFFSET,USER,DH2-DH1/2,DW1/2	!移動頂梁截面的慣性軸位置	
SECREAD,'SEC2','SECT',' ',MESH	!讀取頂梁截面庫文件
SECTYPE,3,BEAM,RECT			!定義槽底縱梁橫截面
SECOFFSET,USER,ZH/2,ZW			
SECDATA,ZW,ZH
SECTYPE,4,BEAM,RECT			!定義頂部拉桿橫截面
SECDATA,LW,LH
!定義材料屬性
MP,EX,1,E1							!槽體彈性模量
MP,EX,2,E2							!槽墩彈性模量
MP,DENS,1,DS1						!槽體密度
MP,DENS,2,DS2						!槽墩密度
MP,PRXY,1,V1						!槽體泊松比
MP,PRXY,2,V2						!槽墩泊松比
MP,DAMP,3,0
!定義實常數
R,1,T1								!墻板厚度
R,2,T2								!槽底厚度
R,3,T3								!槽墩空心殼厚度
R,4,E3,0,0,0,SS						!x、y向彈簧支座
R,5,E3								!z向彈簧支座
!實體建模
!槽體線面分布
LOCAL,11,0,,,,,-90					!創建坐標系
CSYS,11							!轉換到新坐標系下
WPCSYS,,11						!將工作平面移到與新坐標系一致
K,1									!建立關鍵點
K,100,LK							!建立關鍵點
KFILL,1,100,15,,1					!填充關鍵點
NUMCMP,ALL						!壓縮編號
KSEL,S,KP,,1,17						!選擇關鍵點
KGEN,2,ALL,,,,W,,20				!復制關鍵點
NUMCMP,ALL						!壓縮編號
KSEL,S,KP,,1,17,16					!選擇關鍵點
KGEN,3,ALL,,,,W/3,,200				!復制關鍵點
NUMCMP,ALL						!壓縮編號
ALLS								!全部選擇
L,1,17								!創建線
L,18,34								!創建線
L,35,36								!創建線
L,37,38								!創建線
*DO,I,1,17
L,I,I+17								!創建線
*ENDDO
LGEN,2,ALL,,,,,H,200				!復制線
NUMCMP,ALL						!壓縮編號
L,1,39								!創建線
L,17,55								!創建線
L,18,56								!創建線
*DO,I,34,38
L,I,I+38								!創建線
*ENDDO
AL,1,5,2,21							!由線生成面
AL,1,43,22,44						!由線生成面
AL,3,47,24,48						!由線生成面
AL,4,49,25,50						!由線生成面
AL,2,45,23,46						!由線生成面
 	 
!建立槽墩模型
CONE,D2/2,D1/2,-HD,,-180,-90		!創建1/4圓臺體積
VDELE,1,,,0							!刪除體積
ADELE,9,10							!刪除多余的面
CONE,D2/2,D1/2,-HD,,-90,0			!創建另外1/4圓臺體積
VDELE,1,,,0							!刪除體積
ADELE,12,13						!刪除多余的面
NUMCMP,ALL						!壓縮編號
WPOFFS,,W							!將工作平面沿y軸移動w距離
CONE,D2/2,D1/2,-HD,,0,90			!創建1/4圓臺體積
VDELE,1,,,0							!刪除體積
ADELE,15,16						!刪除多余的面
CONE,D2/2,D1/2,-HD,,90,180		!創建另外1/4圓臺體積
VDELE,1,,,0							!刪除體積
ADELE,18,19						!刪除多余的面
NUMCMP,ALL						!壓縮編號
A,80,78,97,99						!創建面
A,87,92,90,85						!創建面
A,78,97,90,85						!創建面
A,80,99,92,87 						!創建面
ASEL,S,AREA,,6,21					!選擇面6到21
LSLA,S								!選擇屬于已選面的所有線
LSEL,S,LINE,,51,52					!選擇線
LSEL,A,LINE,,55,56					!選擇線
LSEL,A,LINE,,69,70					!選擇線
LSEL,A,LINE,,73,74					!選擇線
LSEL,A,LINE,,64,65					!選擇線
LSEL,A,LINE,,82,83					!選擇線
LSEL,A,LINE,,60,61					!選擇線
LSEL,A,LINE,,78,79					!選擇線
LESIZE,ALL,,,4						!指定線的網格份數

LSEL,S,LINE,,91,94					!選擇線
LESIZE,ALL,,,8						!指定線的網格份數
LSEL,S,LINE,,87,90					!選擇線
LESIZE,ALL,,,9						!指定線的網格份數

LSEL,S,LINE,,57,58					!選擇線
LSEL,A,LINE,,75,76					!選擇線
LSEL,A,LINE,,66,67					!選擇線
LSEL,A,LINE,,84,85					!選擇線
LESIZE,ALL,,,5						!指定線的網格份數

ASEL,S,AREA,,6,21					!選擇面
AATT,2,3,2							!設置所選面的單元屬性
AMESH,ALL							!對面劃分網格
AGEN,2,ALL,,,LK,,,100				!將已建好的單墩模型復制到另一側
ALLS								!全選
NUMMRG,NODE						!合并重節點
NUMCMP,ALL						!壓縮編號

ALLS								!選擇已建好的槽墩模型
CM,CAODUN,NODE					!將槽墩的所有節點歸為caodun一組
NSEL,S,LOC,Z						!選擇節點
NSEL,R,LOC,X						!選擇節點
NSEL,R,LOC,Y,0,W					!選擇節點
CM,CAODUN1,NODE				!將已選節點歸為caodun1一組
NSEL,S,LOC,Z						!選擇節點
NSEL,R,LOC,X,LK					!選擇節點
NSEL,R,LOC,Y,0,W					!選擇節點
CM,CAODUN2,NODE 				!將已選節點歸為caodun2一組
!劃分單元
!指定相關線的單元分數
LSEL,S,LINE,,26,42					!選擇線
LSEL,A,LINE,,6,20					!選擇線
LESIZE,ALL,,,3						!指定線的網格份數

LSEL,S,LINE,,22,25					!選擇線
LSEL,A,LINE,,1,4					!選擇線
LESIZE,ALL,,,16						!指定線的網格份數

LSEL,S,LINE,,43,50					!選擇線
LESIZE,ALL,,,3						!指定線的網格份數
!劃分單元
!劃分槽底橫梁網格
LSEL,S,LINE,,1,4					!選擇線
LATT,1,,1,,,,1						!設置線單元屬性
LMESH,ALL							!劃分線單元
!劃分頂梁網格
LSEL,S,LINE,,22,25					!選擇線
LATT,1,,1,,,,2						!設置線單元屬性
LMESH,ALL							!劃分線單元
!劃分槽底縱梁網格
LSEL,S,LINE,,6,20					!選擇線
LATT,1,,1,,,,3						!設置線單元屬性
LMESH,ALL							!劃分線單元
!劃分頂部拉桿網格
LSEL,S,LINE,,26,42					!選擇線
LATT,1,,1,,,,4						!設置線單元屬性
LMESH,ALL							!劃分線單元
!劃分槽底網格
LSEL,S,LINE,,5,21,16				!選擇線
LESIZE,ALL,,,9						!指定線單元份數
ASEL,S,AREA,,1						!選擇面
AATT,1,2,2							!設置面單元屬性
AMESH,ALL							!劃分面單元
!劃分墻板網格
ASEL,S,AREA,,2,5					!選擇面
AATT,1,1,2							!設置面單元屬性
AMESH,ALL 						!劃分面單元
!模擬盆式支座
NSEL,S,LOC,Z						!選擇節點
NSEL,R,LOC,X						!選擇節點
CMSEL,U,CAODUN1					!去掉屬于caodun1集的節點
CM,CAOTI1,NODE					!將已選節點歸為caoti1組
NSEL,S,LOC,Z						!選擇節點
NSEL,R,LOC,X,LK					!選擇節點
CMSEL,U,CAODUN2					!去掉屬于caodun2集的節點
CM,CAOTI2,NODE					!將已選節點歸為caoti2組
ALLS								!全選
CMSEL,U,CAODUN,NODE			!去掉屬于caodun集的節點
NUMMRG,NODE						!合并重節點
NUMCMP,ALL						!壓縮編號
CSYS,0								!轉到原始笛卡兒坐標系
*DIM,N_MID,,16						!定義長度為16的數組
*DO,I,1,8
!*****選擇與槽墩重合的屬于槽體的節點********
ALLS
*IF,I,LE,4,THEN			
	NSEL,S,LOC,Z,-(I-1)*W/3
	NSEL,R,LOC,Y,
	NSEL,R,LOC,X,
	CMSEL,R,CAODUN1
	N_MID(I)=NODE(,,-(I-1)*W/3)		!將所選的節點編號賦給數組N_MID
	ALLS
	NSEL,S,LOC,Z,-(I-1)*W/3
	NSEL,R,LOC,Y,
	NSEL,R,LOC,X,
	CMSEL,R,CAOTI1
	N_MID(I+8)=NODE(,,-(I-1)*W/3)		!將所選的節點編號賦給數組N_MID
*ELSE
	NSEL,S,LOC,Z,-(I-5)*W/3
	NSEL,R,LOC,Y,
	NSEL,R,LOC,X,LK
	CMSEL,R,CAODUN2
	N_MID(I)=NODE(LK,,-(I-5)*W/3)		!將所選的節點編號賦給數組N_MID
	ALLS
	NSEL,S,LOC,Z,-(I-5)*W/3
	NSEL,R,LOC,Y,
	NSEL,R,LOC,X,LK
	CMSEL,R,CAOTI2
	N_MID(I+8)=NODE(LK,,-(I-5)*W/3)	!將所選的節點編號賦給數組N_MID
*ENDIF
!******************************************
TYPE,3
REAL,4
E,N_MID(I),N_MID(I+8)					!模擬x向支座
TYPE,4
REAL,4
E,N_MID(I),N_MID(I+8)					!模擬y向支座
TYPE,5
REAL,5
E,N_MID(I),N_MID(I+8)					!模擬z向支座
*ENDDO 
ALLS									!全選
CMSEL,U,CAODUN1						!去掉屬于caodun1集的節點
CMSEL,U,CAODUN2						!去掉屬于caodun2集的節點
CMSEL,U,CAOTI1						!去掉屬于caoti1集的節點
CMSEL,U,CAOTI2						!去掉屬于caoti2集的節點
NUMMRG,NODE							!合并重節點
NUMMRG,KP							!合并重合的關鍵點
NUMCMP,ALL							!壓縮編號
!邊界條件
!將槽體兩側節點x方向的自由度約束，以模擬鄰槽的影響。
CSYS,11							!轉換到11號坐標系下
ALLS								!全選
ESEL,S,TYPE,,2						!選擇單元類型號為2的單元
NSLE,S,ALL							!選擇屬于已選單元的所有節點
NSEL,R,LOC,X						!選擇節點
NSEL,R,LOC,Y,0,W					!選擇節點
NSEL,R,LOC,Z,0,H					!選擇節點
D,ALL,UX							!約束所選節點x方向自由度
ALLS								!全選
ESEL,S,TYPE,,2						!選擇單元類型號為2的單元
NSLE,S,ALL							!選擇節點
NSEL,R,LOC,X,LK					!選擇節點
NSEL,R,LOC,Y,0,W					!選擇節點
NSEL,R,LOC,Z,0,H					!選擇節點
D,ALL,UX							!約束所選節點x方向自由度
!約束底部節點的所有自由度
ALLS								!全選
NSEL,S,LOC,Z,-HD					!選擇節點
D,ALL,ALL 							!約束所選節點所有自由度
*END								!結束宏文件
PIER								!運行宏生成模型
FINI								!退出前處理器
!加載與求解
!預應力靜力分析
FINI
/SOLU								!進入求解器
ANTYPE,STATIC					!指定為靜力學求解類型
ACEL,,9.8							!施加重力加速度
AUTOTS,ON						!打開自動時間步長
PSTRES,ON							!打開預應力開關
NSUB,5								!設定子步數為5
ALLS								!選擇所有元素
SOLVE								!求解
!模態分析
FINI
/SOLU
ANTYPE,2							! 指定為模態求解類型
MODOPT,LANB,10					!提取前10階模態
MXPAND,10,,,0						!指定擴展模態為10階
PSTRES,ON							!打開預應力開關
MODOPT,LANB,10,0,100,,OFF
ALLS
SOLVE
!結果后處理
!靜力求解結果
FINI
/POST1
PLDISP,1							!查看變形圖
PLNSOL,S,EQV						!查看等效應力云圖
 	 
!模態分析結果
FINI
/POST1
SET,LIST							!查看各階頻率，如表5-3所示
*DO,I,1,10
SET,,, ,,, ,I 						!查看各階振型						
PLDISP,0
*ENDDO