FINI
/CLE

/UNITS,SI                                                          !國際單位制    
/FILNAME,CSP                                                       !制定文件名為CSP
/TITLE,2D THERMAL SIMULATION OF CSP                                !制定標題

!定義結構參數
!定義塑封體的尺寸
*SET,MC_HEIGHT,1.5E-3          !塑封體高度 
*SET,MC_SLENGTH,16E-3          !塑封體上端長度
*SET,MC_XLENGTH,18E-3          !塑封體下端長度
!定義芯片尺寸(硅)
*SET,CHIP_LENGTH,14E-3         !芯片長度
*SET,CHIP_HEIGHT,0.4E-3         !芯片寬度   
!定義粘結劑尺寸          
*SET,DA_HEIGHT,0.15E-3          !粘結劑高度
!定義銅印制線尺寸 
*SET,CP_HEIGHT,0.05E-3         !銅印制線高度
*SET,CP_LENGTH,1E-3            !銅印制線長度       
!定義基板的尺寸
*SET,PS_LENGTH,20E-3         !基板長度
*SET,PS_HEIGHT,0.15E-3         !基板高度
!定義基板下焊料球的尺寸和數量
*SET,SB_RADIUS,0.5E-3         !焊球半徑
*SET,SB_DIST,2.2E-3                 !焊球間距
*SET,SB_NB,8                  !單排焊球數量
*SET,SB_HEIGHT,0.8E-3         !焊球高度
*SET,SB_JL,2*SQRT(SB_RADIUS**2-SB_HEIGHT**2/4)
!定義PCB的尺寸
*SET,PCB_LENGTH,30E-3        !PCB長度
*SET,PCB_HEIGHT,1.5E-3        !PCB高度

/PREP7                                 !進入前處理
!定義單元類型
ET,1,PLANE82                    	!定義單元類型1為平面單元82
KEYOPT,1,3,2                    	!設定為平面應變問題
ET,2,VISCO108                  		!定義單元類型2為平面單元108
!定義材料特性
!定義PCB的材料屬性
MP,EX,1,22E9                          	!PCB的彈性模量
MP,PRXY,1,0.28                        	!PCB的泊松比
MP,ALPX,1,18E-6                       	!PCB的熱膨脹系數
!焊點材料特性
MP,ALPX,2,21E-6                                                                                        
MPTEMP,1,-55,-35,-15,5,20,50          	!焊點材料的彈性模量、泊松比
MPTEMP,7,75,100,125
MPDATA,EX,2,1,47.97E9,46.89E9,45.79E9,44.38E9,43.25E9,41.33E9
MPDATA,EX,2,7,39.45E9,36.85E9,34.59E9
MPDATA,PRXY,2,1,0.352,0.354,0.357,0.36,0.363,0.365
MPDATA,PRXY,2,7,0.37,0.377,0.38
TB,ANAN,2,,,0                            !焊點ANAND模型材料參數
TBDATA,1,56.33E6,10830,1.49E7,11,0.303,2640E6
TBDATA,7,80.415E6,0.0231,1.34
!定義基板材料屬性
MP,EX,3,22E9                            !基板的彈性模量
MP,PRXY,3,0.28                         	!基板的泊松比
MP,ALPX,3,18E-6                       	!基板的熱膨脹系數
!定義銅印制線材料屬性
MP,EX,4,120.658E9                     	!銅的彈性模量
MP,PRXY,4,0.345                       	!銅的泊松比
MP,ALPX,4,17E-6                         !銅的熱膨脹系數
!定義粘結劑材料屬性
MP,EX,5,5.2E9                           !粘結劑的彈性模量
MP,PRXY,5,0.3                           !粘結劑的泊松比
MP,ALPX,5,40E-6                         !粘結劑的熱膨脹系數
!定義芯片材料屬性
MP,EX,6,131E9                           !芯片材料的彈性模量
MP,PRXY,6,0.3                           !芯片材料的泊松比
MP,ALPX,6,2.8E-6                        !芯片材料的熱膨脹系數
!定義塑封體材料屬性
MP,EX,7,26E9                            !塑封體的彈性模量
MP,PRXY,7,0.3                           !塑封體的泊松比
MP,ALPX,7,7E-6                          !塑封體的熱膨脹系數

!建模
!建塑封體結構
K,1,0,0                                    !建關鍵點1
K,2,0,MC_HEIGHT                            !建關鍵點2
K,3,MC_SLENGTH/2,MC_HEIGHT                 !建關鍵點3
K,4,MC_XLENGTH/2,0                         !建關鍵點4
A,1,2,3,4                           	!通過關鍵點建面
!建立粘結劑模型
RECTNG,0,CHIP_LENGTH/2,0,DA_HEIGHT
!建立芯片模型
RECTNG,0,CHIP_LENGTH/2,DA_HEIGHT,DA_HEIGHT+CHIP_HEIGHT
!建基板
RECTNG,0,PS_LENGTH/2,0,-PS_HEIGHT
!建立焊球
WPOFF,SB_DIST/2,-PS_HEIGHT-SB_HEIGHT/2    
CSWPLA,11,0
PCIRC,SB_RADIUS, ,0,360
ASEL,S,LOC,Y,0,SB_HEIGHT/2+PS_HEIGHT
AOVLAP,ALL                                                       	!疊分基板和焊球模型
ASEL,S,LOC,Y,SB_HEIGHT/2,SB_HEIGHT/2+PS_HEIGHT                       	!選擇基板
AADD,ALL                                                            	!生成一個單一面                                                     
RECTNG,-SB_JL/2,SB_JL/2,SB_HEIGHT/2,SB_HEIGHT/2+PS_HEIGHT
ASEL,S,LOC,Y,SB_HEIGHT/2,SB_HEIGHT/2+PS_HEIGHT
ASEL,R,LOC,X,-SB_JL/2,SB_JL/2
ASEL,A,LOC,Y,-SB_RADIUS,SB_HEIGHT/2
AGEN,SB_NB/2,ALL,,,SB_DIST,0,0,0
!建銅印制線
WPOFF,-CP_LENGTH/2,SB_HEIGHT/2+PS_HEIGHT
RECTNG,0,CP_LENGTH,0,CP_HEIGHT
CSYS                                                               !激活初始笛卡爾坐標系
WPCSYS                                                             !工作坐標系和當前坐標系重合
ASEL,S,LOC,Y,0,CP_HEIGHT
ASEL,R,LOC,X,SB_DIST/2-CP_LENGTH/2,SB_DIST/2+CP_LENGTH/2
AGEN,SB_NB/2,ALL,,,SB_DIST,0,0,0
!建PCB板
WPOFF,0,-PS_HEIGHT-SB_HEIGHT                         
CSWPLA,12,0
RECTNG,0,PCB_LENGTH/2,0,-PCB_HEIGHT
ALLSEL,ALL  
AOVLAP,ALL                                           	!疊分模型
ASEL,S,LOC,Y,-PCB_HEIGHT,0
AADD,ALL
NUMCMP,ALL                                          	!壓縮編號
ALLSEL,ALL 

!網格劃分設置
!對PCB板進行工作平面切割
CSYS,12
ASEL,S,LOC,Y,-PCB_HEIGHT,0
*DO,I,0,1,1
*DO,J,0,3,1
WPROTA,0,0,90			!工作平面繞Y軸旋轉90度
WPOFF,,,SB_DIST/2-SB_JL/2+J*SB_DIST+I*SB_JL
ASBW,ALL
WPCSYS
*ENDDO
*ENDDO

CSYS
WPCSYS
WPOFF,,DA_HEIGHT
WPROTA,0,90,0			!工作平面繞X軸旋轉90度
ASEL,S,AREA,,20
ASBW,ALL

WPCSYS
WPOFF,CHIP_LENGTH/2,0,0
WPROTA,0,0,90
ASEL,S,AREA,,24
ASBW,ALL

!賦材料屬性
ASEL,S,AREA,,3,6
CSYS,11
WPCSYS
ASEL,A,LOC,Y,-SB_HEIGHT/2,SB_HEIGHT/2
AATT,2,,2                              		!焊點
CSYS
ASEL,R,AREA,,3,6
ASEL,INVE
ASEL,R,LOC,Y,-PS_HEIGHT,0
AATT,3,,1                             		!基板
ASEL,S,LOC,Y,0,CP_HEIGHT
AATT,4,,1                               	!銅印制線
ASEL,S,AREA,,20
ASEL,A,AREA,,31,32,1
AATT,7,,1                                     	!塑封體
ASEL,S,LOC,Y,PS_HEIGHT,PS_HEIGHT+CHIP_HEIGHT  	!芯片
AATT,6,,1
CSYS,12
ASEL,S,LOC,Y,-PCB_HEIGHT,0
AATT,1,,1                          		!PCB板
ASEL,S,AREA,,21 
AATT,5,,1                         		!粘結劑
ALLSEL,ALL  

!網格劃分
CSYS
WPCSYS
ASEL,S,LOC,Y,-PS_HEIGHT,DA_HEIGHT
AESIZE,ALL,0.2E-3                           	!選取已選平面上的全部線
MSHAPE,0,2D 
MSHKEY,0
AMESH,ALL

ALLSEL,ALL
MSHKEY,1
AMAP,15,14,16,58,57     			!焊球
AMAP,16,19,20,60,59 
AMAP,17,25,26,62,61  
AMAP,18,31,32,64,63 

LSEL,S,LINE,,31,89,58      			!PCB板
LSEL,A,LINE,,90,95,5
LESIZE,ALL,,,5
LSEL,S,LINE,,85,87,1
LESIZE,ALL,,,5
LSEL,S,LINE,,83
LESIZE,ALL,,,10
ASEL,S,MAT,,1
AMESH,ALL

ASEL,S,MAT,,6            			!芯片
AMESH,ALL

ASEL,S,AREA,,20          			!塑封體
AMESH,ALL
ALLSEL,ALL
AMAP,32,6,73,3,74

  
!施加約束條件
CSYS,12
WPCSYS
LSEL,S,LOC,X,0,0
DL,ALL,,SYMM
LSEL,S,LOC,Y,-PCB_HEIGHT,-PCB_HEIGHT
DL,ALL,,ALL
ALLSEL,ALL  
!設置求解選項
!======================
!=======加載求解=======
!======================
/SOLU
/SOLU                            	!進入求解器
ANTYPE,4                        	!設定為瞬態分析
TRNOPT,FULL                     	!定義瞬態分析類型
NLGEOM,1                        	!設定為大變形分析
NROPT,FULL                      	!設定全N-R求解
TREF,25                         	!設定參考溫度
TOFFST,273                      	!設定攝氏溫度與開氏溫度之間的差值
OUTRES,ALL,ALL                  	!輸出每個子步的所有值

TUNIF,25                        	!定義節點溫度為25度
TIME,1E-5                       	!定義時間為1E-5
SOLVE                           	!求解
!施加載荷并進行計算
NSUBST,5                           	!設定載荷子步數為5
KBC,0                                  	!定義載荷為斜坡載荷
*DO,N,0,7,1                     	!施加溫度循環載荷，循環圈數為8圈
  TUNIF,125                   		!升溫階段
  TIME,5*60+68*60*N             	!升溫結束時間
  SOLVE                           	!求解

  TIME,30*60+68*60*N     		!保溫結束時間
  SOLVE                           	!求解

  TUNIF,-55                  		!降溫結束時間
  TIME,39*60+68*60*N
  SOLVE                           	!求解

  TIME,64*60+68*60*N       		!保溫結束時間
  SOLVE                           	!求解
  
TUNIF,25                        	!升溫階段
  TIME,68*60+68*60*N       		!升溫結束時間
  SOLVE                           	!求解
*ENDDO
SAVE
!======================
!=======通用后處理=======
!======================
/POST1
PLNSOL,U,SUM,0,1                !查看總體變形分布圖
PLNSOL,S,EQV,0,1                !查看等效應力分布圖
PLNSOL,EPPL,EQV,0,1             !查看等效塑性應變分布圖
FINISH        

/POST26
!時間歷程后處理（單元結果）
X向
ESOL,2,7,37,S,X,X_2
XVAR,1
PLVAR,2                             !繪制危險點的X向應力隨時間變化圖
ESOL,3,7,37,EPPL,X,EPPLX_3
XVAR,1
PLVAR,3                             !繪制危險點的X向塑性變形隨時間變化圖
ESOL,4,7,37,EPEL,X,EPELX_4
XVAR,1
PLVAR,4                             !繪制危險點的X向彈性應變隨時間變化圖
ADD,5,3,4,,T_STRAIN,,,1,1,1
XVAR,1
PLVAR,5                             !繪制危險點的總X向應變隨時間變化圖  
XVAR,5
PLVAR,2                             !繪制危險點的X向應力－X向應變環
/AXLAB,X,X STRAIN
/AXLAB,Y,X STRESS\PA