!在移動載荷作用下，橋梁將發生振動，產生的變形和應力都比靜載荷作用大。移動載荷的這種動力效應是不可忽視的，若在載荷處于最不利的靜力作用位置同時滿足共振條件，那么將會發生較大的動態響應，從而導致橋梁破壞。本例將移動載荷作為勻速移動的常量力來模擬懸索橋在移動載荷下的動態響應。為了提高分析效率，我們在前節初始位置確定分析中已經創建了宏“MODEL.MAC”，在本節只需要直接調用該宏，并將纜索單元的初應變值改為0.0043，即可得到移動載荷作用分析的有限元模型。
!參數定義
FINI								!退出
/CLE
/FILNAME,CABLE_BRIDGE,1
/TITLE,YIDONG HEZAI OF CABLE_BRIDGE
!建立模型
!"MODEL"宏文件應放在工作目錄下。
BW=10.8			!橋面寬度
TH=-1.88			!加勁桁架高度
X1=50				!左側橋塔X向坐標
X2=174				!右側橋塔X向坐標
Y1=18				!橋塔塔頂Y向坐標
Y2=-18.8			!橋塔塔基Y向坐標
D1=0.079			!主纜截面直徑
D2=0.039			!吊索截面直徑
B1=0.16			!縱向分配梁，縱向斜腹桿，橫向內側豎桿，橫向內、外側斜腹桿截面寬度
B2=0.3				!縱向上、下弦桿截面寬度
B3=0.2				!縱向豎桿，橫向外側豎桿截面寬度
B4=0.18			!橫向上、下弦桿截面寬度
B5=0.12			!抗風桁架截面寬度
B6=2.0				!塔柱截面寬度
B7=4.0				!柱間連接件截面寬度
B8=0.14			!橋面板截面厚度
H1=0.28			!縱向分配梁截面厚度
H2=0.2				!縱向上、下弦桿，橫向下弦桿截面厚度
H3=0.14			!縱向斜腹桿，橫向外側豎桿、內側豎桿、外側斜腹桿、內側斜腹桿截面厚度
H4=0.18			!縱向豎桿截面厚度
H5=0.24			!橫向上弦桿截面厚度
H6=0.12			!抗風桁架截面厚度
H7=4.0				!塔柱截面厚度
H8=2.0				!柱間連接件截面厚度
!材料參數設定
INSTR=0.0043			!纜索初應變
!定義單元類型
/PREP7
ET,1,LINK10				!主纜、吊索單元
KEYOPT,1,3,0				!只受拉不受壓
ET,2,BEAM4				!加勁桁架、縱向分配梁、抗風桁架、橋塔單元
ET,3,SHELL63				!橋面板單元
!定義材料屬性
MP,EX,1,21E10				!鋼絲繩材料常數（懸索、吊索）
MP,NUXY,1,0.167
MP,DENS,1,7850	
MP,EX,2,3.0E10				!C30砼材料常數（加勁桁架、縱梁）
MP,NUXY,2,0.3
MP,DENS,2,2500
MP,EX,3,2.8E10				!C20砼材料常數（橋塔、橋面板）
MP,NUXY,3,0.3
MP,DENS,3,2500
!定義實常數
R,1,D1**2*3.1415926/4,INSTR	!主纜
R,2,D2**2*3.1415926/4			!吊索
R,3,B1*H1,,,B1,H1				!縱向分配梁
!縱向加勁桁架
R,4,B2*H2,B2*H2**3/12,B2**3*H2/12,B2,H2	!上、下弦桿
R,5,B1*H3,B1*H3**3/12,B1**3*H3/12,B1,H3	!縱向斜腹桿、內側豎桿、外側斜腹桿、內側斜腹桿
R,6,B3*H4,B3*H4**3/12,B3**3*H4/12,B3,H4	!縱向豎桿
!橫向加勁桁架實常數
R,7,B4*H5,B4*H5**3/12,B4**3*H5/12,B4,H5	!上弦桿
R,8,B4*H2,B4*H2**3/12,B4**3*H2/12,B4,H2	!下弦桿
R,9,B3*H3,B3*H3**3/12,B3**3*H3/12,B3,H3	!外側豎桿
R,10,B5*H6,B5*H6**3/12,B5**3*H6/12,B5,H6	!抗風桁架實常數	
R,11,B6*H7,B6*H7**3/12,B6**3*H7/12,B6,H7	!橋塔塔柱實常數
R,12,B7*H8,B7*H8**3/12,B7**3*H8/12,B7,H8	!橋塔柱間連接件實常數
R,13,B8						!橋面板人行道板及車行道板實常數
!建模
!建立模型時，采用自下而上的方法建立除橋塔外的模型部分，然后通過對線劃分單元建立橋塔模型。
!建立單側主纜單元模型
*DO,I,1,12,1
N,I,4*(I-1),(4*(I-1)+12)**2/256+2		!創建節點
*ENDDO
N,13,50,18
*DO,I,1,29,1
N,I+13,4*I+52,(4*I-60)**2/256+2		!創建節點
*ENDDO
N,43,174,18
*DO,I,1,12,1
N,I+43,4*I+176,(4*I-60)**2/256+2		!創建節點
*ENDDO
TYPE,1								!指定單元類型
MAT,1								!指定材料類型
REAL,1								!指定實常數
*DO,I,1,54,1
E,I,I+1								!連接節點生成單元
*ENDDO
!建立單側吊索單元模型
*DO,I,1,11,1
N,I+55,4*I							!創建節點
*ENDDO
*DO,I,1,29,1
N,I+66,4*I+52						!創建節點
*ENDDO
*DO,I,1,11,1
N,I+95,4*I+176						!創建節點
*ENDDO							!壓縮節點編號
TYPE,1								!指定單元類型
MAT,1								!指定材料類型
REAL,2								!指定實常數
*DO,I,2,12,1
E,I,I+54								!連接節點生成單元
*ENDDO
*DO,I,14,42,1
E,I,I+53								!連接節點生成單元
*ENDDO
*DO,I,44,54,1
E,I,I+52								!連接節點生成單元
*ENDDO
!建立單側塔柱模型
K,1,X1,Y1							!創建關鍵點
K,2,X1,Y2							!創建關鍵點
K,3,X2,Y1							!創建關鍵點
K,4,X2,Y2							!創建關鍵點
K,5,X1,TH							!創建關鍵點
K,6,X2,TH							!創建關鍵點
K,7,X1,0							!創建關鍵點
K,8,X2,0							!創建關鍵點
L,1,7								!連接關鍵點生成線
L,3,8								!連接關鍵點生成線
L,7,2								!連接關鍵點生成線
L,8,4								!連接關鍵點生成線
!將已建好的單側模型，對稱復制到另一側
LSEL,ALL,ALL						!選擇所有線
LGEN,2,ALL,,,,,BW					!將所有線復制到Z=BW平面
ESEL,ALL,ALL						!選擇所有單元
EGEN,2,200,ALL,,,,,,,,,,BW			!將所有單元復制到Z=BW平面
KGEN,2,5,6,,,,BW,10					!將關鍵點5，6復制到Z=BW平面
L,5,15								!建立支撐橫梁
L,6,16								!建立支撐橫梁
L,1,9								!建立塔頂縱向梁
L,3,11								!建立塔頂縱向梁
NUMCMP,ALL						!壓縮對象編號
!***********加勁桁架模型**********
!建立橫向上弦桿單元模型
N,213,8,TH,BW						!創建節點
N,214,8,TH							!創建節點
N,215,8,,1.89						!創建節點
NGEN,7,1,215,,,,,1.17				!將所選節點沿X方向復制
N,222,8,TH,1.89						!創建節點
NGEN,4,1,222,,,,,2.34				!將所選節點沿X方向復制
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,7								!指定實常數
E,57,215							!連接節點生成單元
E,163,221							!連接節點生成單元
*DO,I,215,220,1
E,I,I+1								!連接節點生成單元
*ENDDO
!建立橫向下弦桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,8								!指定實常數
E,214,222							!連接節點生成單元
E,213,225							!連接節點生成單元
*DO,I,222,224,1
E,I,I+1								!連接節點生成單元
*ENDDO
!建立橫向外側斜腹桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,5								!指定實常數
E,163,225							!連接節點生成單元
E,225,220
E,220,224
E,224,218
E,218,223
E,223,216
E,216,222
E,222,57
!建立橫向外側豎桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,9								!指定實常數
*DO,I,1,4,1
E,213+2*I,221+I					!連接節點生成單元
*ENDDO
!建立縱向豎桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,6								!指定實常數
E,163,213							!連接節點生成單元
E,57,214
ESEL,S,ELEM,,211,237,1			!選擇單元
EGEN,2,200,ALL,,,,,,,,-4				!將已單元沿X方向復制
ALLS								!全選
NUMMRG,ALL						!合并所有重合對象
NUMCMP,ALL						!壓縮對象編號
!建立縱向上、下弦桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,4								!指定實常數
NGEN,2,77,162,,,2					!復制節點
NGEN,2,1,239,,,,TH					!復制節點
E,162,239							!連接節點生成單元
E,239,163
E,226,240
E,240,213
!建立縱向斜腹桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,5								!指定實常數
E,226,239							!連接節點生成單元
E,239,213							!連接節點生成單元
ESEL,S,ELEM,,265,270,1			!選擇單元
EGEN,2,100,ALL,,,,,,,,,,-BW			!將已單元沿X方向復制
!建立橫向內側豎桿，內側斜腹桿單元模型
TYPE,2								!指定單元類型
MAT,2								!指定材料類型
REAL,5								!指定實常數
*DO,I,1,7,1
E,227+I,214+I						!連接節點生成單元
*ENDDO
NUMCMP,ALL						!壓縮編號
E,56,163							!連接節點生成單元
E,162,57
NUMCMP,ALL			!壓縮對象編號
!**************************************
!建立橋面單元模型
TYPE,3								!指定單元類型
MAT,3								!指定材料類型
REAL,13							!指定實常數
E,162,163,221,234
E,234,221,220,233
*DO,I,1,5,1
E,234-I,221-I,220-I,233-I
*ENDDO
E,228,215,57,56
!將桁架和橋面單元模型沿橋縱向復制
ESEL,S,ELEM,,211,293,1
EGEN,54,1000,ALL,,,,,,,,4
ALLS
NUMMRG,ALL						!合并所有對象
NUMCMP,ALL						!壓縮對象編號
NSEL,ALL							!選擇所有節點
NSEL,U,LOC,Y,Y1					!選擇以＝Y1平面上的節點
CM,QIAO,NODE						!將所選節點歸為QIAO一組
!劃分橋塔塔柱單元模型
LSEL,S,LINE,,1,8,1					!選擇線
LESIZE,ALL,1.88					!指定已選線上的單元份數
MSHKEY,1							!采用映射網格劃分方式
MSHAPE,0,3D						!采用四邊形、3D單元
TYPE,2								!指定單元類型
MAT,3								!指定材料類型
REAL,11							!指定實常數
LMESH,ALL							!對已選線進行網格劃分
ALLS
!劃分塔柱間連接件單元模型
LSEL,S,LINE,,9,12,1					!選擇線
LESIZE,ALL,,,10						!指定已選線上的單元份數
REAL,12							!指定實常數
LMESH,ALL							!對已選線進行網格劃分
ALLS								!全選
CMSEL,U,QIAO						!篩除屬于QIAO組的節點
NUMMRG,NODE						!合并重合節點
NUMCMP,ALL						!壓縮編號
!將橋塔塔柱單元與橋面單元重合的節點的自由度耦合
ALLS								!全選
CP,1,UY,431,1213					!耦合兩節點Y方向自由度
CP,2,UZ,431,1213					!耦合兩節點Z方向自由度
CP,3,ROTX,431,1213				!耦合兩節點X方向的轉動自由度
CP,4,UY,433,1173
CP,5,UZ,433,1173
CP,6,ROTX,433,1173
CP,7,UY,962,1223
CP,8,UZ,962,1223
CP,9,ROTX,962,1223
CP,10,UY,964,1183
CP,11,UZ,964,1183
CP,12,ROTX,964,1183
CP,13,UY,430,1192
CP,14,UZ,430,1192
CP,15,ROTX,430,1192
CP,16,UY,432,1152
CP,17,UZ,432,1152
CP,18,ROTX,432,1152
CP,19,UY,961,1202
CP,20,UZ,961,1202
CP,21,ROTX,961,1202
CP,22,UY,963,1162
CP,23,UZ,963,1162
CP,24,ROTX,963,1162
!施加邊界條件
!約束主纜
NSEL,S,LOC,X,0						!選擇節點
D,ALL,ALL							!約束主纜端部的所有自由度
NSEL,S,LOC,X,224					!選擇節點
D,ALL,ALL							!約束主纜端部的所有自由度
!約束橋塔塔基
NSEL,S,LOC,Y,Y2					!選擇節點
D,ALL,ALL							!約束橋塔塔基節點的所有自由度
!約束加勁桁架兩端
NSEL,S,LOC,X,220					!選擇節點
NSEL,U,LOC,Y,3
D,ALL,ALL							!約束加勁桁架端部的所有自由度
NSEL,S,LOC,X,4						!選擇節點
NSEL,U,LOC,Y,3
D,ALL,ALL							!約束加勁桁架端部的所有自由度
*END								!運行宏生成模型
!加載及求解
!本例中的移動載荷視為勻速常量力載荷行分析。其中載荷MG＝2000N，簡化成四個車輪上的相等集中載荷，車輪間距為8M，正好為兩個橋面單元的長度，則簡諧力F=500COS(10T)，載荷移動速度V＝120公里/小時。
!參數定義
!定義參數
DELTL=4							!橋面單元長度
V=120								!載荷移動速度
DELTT=DELTL/V*3.6				!荷載經過一個單元所用時間
F=1000								!常量力大小
W=10								!簡諧力的圓頻率
LF=8								!前后車輪間距
NUM=54							!橋面單元數
MM=NUM+1+LF/DELTL			!循環最大數目
!設置分析選項
FINI
/SOLU
ANTYPE,4							!指定分析類型為瞬態動力學分析
TRNOPT,FULL						!瞬態動力學分析采用FULL法
NLGEOM,ON
NROPT,FULL  
!計算重力的影響
TIMINT,OFF
TIME,1E-8
KBC,1
NSUBST,5
SSTIF,ON
ACEL,,9.8
ALLS
SOLVE                                 	!求解
!施加常量力移動載荷并求解
TIMINT,ON                             !打開時間積分開關
KBC,0
*DO,I,1,MM,1
OUTRES,ALL,ALL					!輸出每一步的結果
TIME,I*DELTT
NSUBST,5
*IF,I,LT,LF/DELTL,THEN
	FDELE,ALL,ALL					!刪除所有集中力載荷
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)		!施加簡諧力載荷
	ALLS
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	SOLV
*ELSEIF,I,LT,(NUM+1)
	FDELE,ALL,ALL
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	NSEL,S,LOC,X,I*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	SOLV
*ELSE
	FDELE,ALL,ALL
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	NSEL,S,LOC,X,(I-2)*DELTL
	NSEL,R,LOC,Y
	NSEL,R,LOC,Z,BW-1.89
	F,ALL,FY,-F*COS(W*I*DELTT)					!施加簡諧力載荷
	ALLS
	SOLV
*ENDIF
*ENDDO 

FINI
/POST1						!進入通用后處理
SET,30,2					!查看30步第2子步即載荷移動到跨中附近的結果
PLNSOL, U,Y				!顯示y方向位移云圖
PLNSOL, S,EQV				!顯示等效應力云圖
/POST26					!進入時間歷程后處理
NUMVAR,20				!指定允許的變量數
NSOL,2,677,U,Y, UY_CENT  !取出中間節點的Y向位移數據
DERIV,3,2,1,,VY_CENT		!對中間節點的Y向位移微分運算，得到Y向速度
PLVAR,2					!顯示中間節點的Y向位移隨時間變化曲線
PLVAR,3