/FILNAME,PIER
/TITLE,ANALYSIS OF A BRIDGE'S PIER 
*CREATE,PIER,MAC	!創建宏文件PIER
/UNITS,SI		!使用國際單位制
*AFUN,DEG		!使用角度制
*SET,H,78		!墩高
*SET,D,12.6		!實心底面直徑
*SET,DD,10.44		!空心底面直徑
*SET,DT,11		!墩帽直徑
*SET,HT,2.5		!墩帽高
*SET,TT,3		!實心部分高
*SET,KO,45		!外母線斜率
*SET,KI,50		!內母線斜率
*SET,EE,29E9		!橋墩彈性模量
*SET,NU,0.3		!橋墩泊松比
*SET,DEN,2500		!橋墩密度
*SET,ALPHA,0.05		!設定質量阻尼ALPHA為0.05
*SET,BETA,0.01		!設定剛度阻尼BETA為0.01
*SET,OMEGA,2		!設定激勵角頻率2

!進入前處理
/PREP7
ET,1,MESH200
KEYOPT,1,1,6		!不帶中間節點四邊形單元
ET,2,SOLID45
MP,EX,1,EE
MP,NUXY,1,NU
MP,DENS,1,DEN
!建立幾何模型
!建立關鍵點
K,1
K,2,DD/2+TT/KI
K,3,D/2
K,4,,TT
K,5,DD/2,TT
K,6,D/2-TT/KO,TT
K,7,,H-TT
K,8,DD/2-(H-2*TT)/KI,H-TT
K,9,D/2-(H-TT)/KO,H-TT
K,10,,H
K,11,DD/2-(H-TT)/KI,H
K,12,D/2-H/KO,H
K,13,DT/2,H
K,14,,H+HT
K,15,DD/2-(H-TT+HT)/KI,H+HT
K,16,D/2-(H+HT)/KO,H+HT
K,17,DT/2,H+HT
!建立用于旋轉的面
A,2,3,6,5
A,5,6,9,8
A,8,9,12,11
A,11,12,16,15
A,12,13,17,16
!建立用于延伸的面
WPROT,,-90			!繞X軸旋轉-90度
WPOFFS,,,TT			!移動工作平面到空心底部
CYL4,,,,,DD/2			!建立實心圓面
WPOFFS,,,H-TT			!移動工作平面到墩帽底部
CYL4,,,,,DD/2-(H-TT)/KI		!建立實心圓面
WPCSYS,				!工作平面回到笛卡兒坐標系
ASEL,S,AREA,,6,7,1		!選擇面
ASBW,ALL,,DELETE		!用工作平面切分面
WPROT,,,90			!繞Y軸旋轉90度
ASEL,S,AREA,,8,11,1		!選擇面
ASBW,ALL,,DELETE		!用工作平面切分面
ALLS				!選擇所有的元素
/PNUM,LINE,1			!打開線編號開關
/PNUM,AREA,1			!打開面編號開關
!建立有限元模型
!劃分空心部分橋墩的面網格
MAT,1
TYPE,1
CSYS,
LSEL,S,LINE,,1,1,1
LSEL,A,LINE,,3,12,3
LSEL,A,LINE,,14,16,2
LESIZE,ALL,,,2			!網格劃分數2
LSEL,S,LINE,,2,4,2
LSEL,A,LINE,,8,10,2
LSEL,A,LINE,,11,15,2
LESIZE,ALL,,,2			!網格劃分數2
LSEL,S,LINE,,5,7,2
LESIZE,ALL,,,40
ASEL,S,AREA,,1,5,1
AMESH,ALL
!劃分實心部分的面網格
ALLS
WPCSYS,				!工作平面回到笛卡兒坐標系
WPROT,,-90			!繞X軸旋轉-90度
LSEL,S,LINE,,17,24,1		!選擇要劃分網格的線
LESIZE,ALL,,,6			!網格劃分數6
LSEL,S,LINE,,27,34,1		!選擇要劃分網格的線
LESIZE,ALL,,,6			!網格劃分數6
ASEL,S,AREA,,6,7,1
ASEL,A,AREA,,12,17,1
AMESH,ALL
!由面網格延伸成體網格
!墩帽中部網格
TYPE,2
ASEL,S,AREA,,14,17,1
EXTOPT,ESIZE,2			!設置延伸份數2
EXTOPT,ACLEAR,0			!設置延伸后保留面網格
VEXT,ALL,,,,HT,,1-HT/(DD*KI/2-H+TT),,1-HT/(DD*KI/2-H+TT)	
!設置X,Y,Z方向延伸長度0,-TT,0
!頂部實心網格
ASEL,S,AREA,,14,17,1
EXTOPT,ESIZE,2			!設置延伸份數2
EXTOPT,ACLEAR,1			!設置延伸后去掉面網格
VEXT,ALL,,,,-TT,,1+TT/(DD*KI/2-H+TT),,1+TT/(DD*KI/2-H+TT)	
!設置X,Y,Z方向延伸長度0,-TT,0
!底部實心網格
ASEL,S,AREA,,6,7,1
ASEL,A,AREA,,12,13,1
EXTOPT,ESIZE,2			!設置延伸份數2
EXTOPT,ACLEAR,1			!設置延伸后去掉面網格
VEXT,ALL,,,,-TT,,1+2*TT/(DD*KI),,1+2*TT/(DD*KI)			
!設置X,Y,Z方向延伸長度0,-TT,0
!由面網格旋轉成體網格
ASEL,S,AREA,,1,5,1
EXTOPT,ESIZE,6			!設置延伸份數6
EXTOPT,ACLEAR,1			!設置延伸后去掉面網格
VROTA,ALL,,,,,,1,14		!旋轉面生成體網格,關鍵點1與14定義旋轉軸
NUMMRG,ALL			!合并所有重合元素
NUMCMP,ALL			!壓縮所有元素的編號
!施加約束
NSEL,S,LOC,Y,			!選擇塔底部節點
D,ALL,UX				!約束所選節點X方向自由度
D,ALL,UY				!約束所選節點Y方向自由度
D,ALL,UZ				!約束所選節點Z方向自由度
ALLS				!選中所有的元素
EPLOT				!顯示單元
/VIEW,1,1,1,1			!正等軸視圖
SAVE				!保存模型
*END				!結束宏文件
PIER				!運行宏生成模型
FINI				!退出前處理器
!加載與求解
/SOLU
ANTYPE,2				!設置分析類型為模態分析
MODOPT,SUBSP,10			!設置模態分析方法為subspace法
MXPAND,10,,,1			!設置模態分析擴展10階
LUMPM,ON				!打開近似集中質量
ACEL,0,9.8,0			!設置重力加速度
ALLS				!選中所有的元素
SOLVE				!求解
SAVE				!保存
FINI				!退出SOLU求解器
!***************后處理****************
/POST1
FILE,'PIER','rst'			!讀入結果文件
SET,LIST				!列出各階頻率
SET,1,1				!讀取第1階振型
PLNSOL,S,EQV,0,1.0		!顯示等效應力
ANMODE,10,0.5,,0			!制作第1階動畫
SET,1,3				!讀取第2階振型
PLDI				!顯示第2階變形
ANMODE,10,0.5,,0			!制作第2階動畫
SET,1,5				!讀取第3階振型
PLNSOL,U,Y,0,1.0		!顯示Y向位移
ANMODE,10,0.5,,0			!制作第3階動畫
SET,1,6				!讀取第4階振型
PLNSOL,S,Y,0,1.0    		!顯示Y方向應力
ANMODE,10,0.5,,0			!制作第4階動畫