?? 門式剛架.txt
字號:
!*********************************************************
!* 門式剛架
!******************************注釋***********************
!梁柱采用剛接(和鉸接）兩種，采用變截面BEAM44
!檐口高H=12M 跨距=32M 柱網尺寸64*30M
!*********************************************************
FINI
/CLE
/FILNAME,EX
/TITLE,THE ANALYSIS OF THE MSGJ
!*********************模型幾何參數區*************************
*SET,H,12 !檐口高12M
*SET,H1,10 !下檐 高10M
*SET,B,32 !橫距32M
*SET,L,64 !縱跨距64M
!*********************模型材料參數區*************************
*SET,E_LZ,2.1E11 !彈性模量（PA）
*SET,U_LZ,0.3 !泊松比
*SET,DENS_LZ,7800 !密度，KG/M^-3
*SET,E_LT_SQ,2.1E11 !彈性模量（PA）
*SET,U_LT_SQ,0.3 !泊松比
*SET,DENS_LT_SQ,7800 !密度，KG/M^-3
*SET,E_XC,2.1E11 !彈性模量（PA）
*SET,U_XC,0.3 !泊松比
*SET,DENS_XC,7800 !密度，KG/M^-3
*SET,INI_STRAIN,0.00314 !初始應變
!定義材料阻尼
*set,dampration,0.02
*set,FREQ1,3.0215
*set,mp_betad,dampration/(acos(-1)*FREQ1)
/PREP7
!定義采用單元類型
ET,1,44 !變界面梁BEAM44
ET,2,188 !采用BEAM188
ET,3,10 !桿單元LINK80
ET,200,82 !定義PLANE82單元劃分梁截面
!************************定義材料屬性*****************************
!梁柱材料屬性
MP,EX,1,E_LZ !彈性模量
MP,PRXY,1,U_LZ !泊松比
MP,DENS,1,DENS_LZ !密度
!檁條 墻架梁 山墻柱的材料屬性
MP,EX,2,E_LT_SQ !彈性模量
MP,PRXY,2,U_LT_SQ !泊松比
MP,DENS,1,DENS_LT_SQ !密度
!斜支撐材料屬性
MP,EX,3,E_XC !彈性模量
MP,PRXY,3,U_XC !泊松比
MP,DENS,1,DENS_XC !密度
mp,damp,1,mp_betad
mp,damp,2,mp_betad
mp,damp,3,mp_betad
!**********************實常數******************************************
!********************山墻柱（抗風柱）利用自定義截面箱形梁***********************
!自定義截面
RECTNG,0,0.5.0,0,0.3, !生成矩形
CYL4,0.14,0.125,0.09,-180, !生成左下半個圓
CYL4,0.14,0.175,0.09,180, !生成左上半個圓
CYL4,0.36,0.125,0.09,-180, !生成右下半個圓
CYL4,0.36,0.175,0.09,180, !生成右上半個圓
RECTNG,0.05,0.23,0.125,0.175, !生成左邊連接矩形
RECTNG,0.27,0.45,0.125,0.175, !生成右邊連接矩形
ASEL,U,,,1 !在當前選擇集中不選擇面1
CM,AREA0,AREA !定義面集合AREA0
ALLSEL,ALL !選擇所有元素
ASBA,1,AREA0 !布爾減
ESIZE,0.04 !控制截面劃分尺寸
TYPE,200 !選擇單元類型
AMESH,ALL !劃分網格
SECWRITE,USERBEAM,SECT,,200 !寫入用戶定義截面
ACLEAR,ALL !清除網格
ADELE,ALL,,1 !刪除面及其下屬元素
LDELE,ALL,,,1 !刪除線及其下屬元素
!--------------------------------
SECTYPE,200,BEAM,MESH,SECT1 !由截面號指定截面
SECOFFSET,CENT,,, !截面無偏移
SECREAD,'USERBEAM','SECT',' ',MESH !讀入用戶定義截面
ESIZE,,5 !修改網格控制
!屋面檁條利用單元庫中的截面工子型188
SECTYPE,1,BEAM,I !定義工子梁截面
SECOFFSET,CENT !截面無偏移
SECDATA,0.3,0.3,0.3,0.02,0.02,0.012 !截面數據
!墻架梁利用單元庫中的截面工子型188
SECTYPE,2,BEAM,I !定義工子梁截面
SECOFFSET,CENT !截面無偏移
SECDATA,0.3,0.3,0.3,0.02,0.02,0.012 !截面數據
!定義變截面的實常數
R,1,1.652E-2,8.16667E-4,1.42198E-3,0.35,0.175,0, !第1段變截面I節點
RMODIF,1,7,1.7187E-2,8.16667E-4,1.74344E-3,0.38335,0.175 !第1段變截面J節點
R,2,1.7187E-2,8.16667E-4,1.74344E-3,0.38335,0.175, !第2段變截面I節點
RMODIF,2,7,1.7853E-2,8.16667E-4,2.10287E-3,0.41665,0.175, !第2段變截面J節點
R,3,1.7853E-2,8.16667E-4,2.10287E-3,0.41665,0.175, !第3段變截面I節點
RMODIF,3,7,1.852E-2,8.16667E-4,2.50283E-3,0.45,0.175, !第3段變截面J節點
R,4,1.852E-2,8.16667E-4,2.50283E-3,0.45,0.175, !第4段變截面I節點
RMODIF,4,7,1.9187E-2,8.16667E-4,2.9443E-3,0.48335,0.175, !第4段變截面J節點
R,5,1.9187E-2,8.16667E-4,2.9443E-3,0.48335,0.175, !第5段變截面I節點
RMODIF,5,7,1.9853E-2,8.16667E-4,3.428E-3,0.51665,0.175, !第5段變截面J節點
R,6,1.9853E-2,8.16667E-4,3.428E-3,0.51665,0.175, !第6段變截面I節點
RMODIF,6,7,1.9853E-2,8.16667E-4,3.428E-3,0.51665,0.175, !第6段變截面J節點
R,7,2.252E-2,8.16667E-4,5.82412E-3,0.65,0.175,0, !第7段變截面I節點
RMODIF,7,7,2.027E-2,0.000816667,3.75E-3,0.5375,0.175,0, !第7段變截面J節點
R,8,2.027E-2,8.16667E-4,3.75E-3,0.5375,0.175, !第8段變截面I節點
RMODIF,8,7,1.9145E-2,0.000816667,2.922E-3,0.48125,0.175,0 !第8段變截面J節點
R,9,1.9145E-2,8.16667E-4,2.922E-3,0.48125,0.175, !第9段變截面I節點
RMODIF,9,7,1.802E-2,8.16667E-4,2.1992E-3,0.425,0.175,0 !第9段變截面J節點
R,10,1.3808E-2,6E-4,1.6564E-3,0.425,0.15, !第10段變截面I節點
RMODIF,10,7,1.3808E-2,6E-4,1.6564E-3,0.425,0.15, !第10段變截面J節點
R,11,INI_STRAIN !初始應變
!生成關鍵點
K,1,-B/2,0 !建立1號關鍵點
K,2,-B/2,H1/6,0 !建立2號關鍵點
K,3,-B/2,(H1/6)*2,0 !建立3號關鍵點
K,4,-B/2,(H1/6)*3,0 !建立4號關鍵點
K,5,-B/2,(H1/6)*4,0 !建立5號關鍵點
K,6,-B/2,(H1/6)*5,0 !建立6號關鍵點
K,7,-B/2,(H1/6)*6,0 !建立7號關鍵點
K,8,-3*B/8,H1+(H-H1)/4 !建立8號關鍵點
K,9,-B/4,H1+2*(H-H1)/4,0 !建立9號關鍵點
K,10,-B/8,H1+3*(H-H1)/4,0 !建立10號關鍵點
K,11,-0,H,0 !建立11號關鍵點
*DO,I,1,10,1 !循環控制
L,I,I+1 !連線
*ENDDO !循環結束
*DO,I,1,10,1 !循環控制
LSEL,S,,,I !選擇線
LATT,1,I,1 !賦予屬性
*ENDDO !循環結束
ALLSEL !選擇所有元素
LMESH,ALL !劃分所有線
/ESHAPE,1,ON
/REPLOT
LGEN,6,ALL,,,,,8,100 !復制所有線每次向Z方向偏移8M編號增加100
!生成檁條
*DO,I,3,11,1 !循環控制
*DO,J,1,5,1 !循環控制
*IF,I,EQ,4,OR,I,EQ,6,THEN !條件判斷
I=I+1 !條件
*ENDIF !條件結束
L,I+(J-1)*100,I+J*100 !連線
LATT,2,,2,,,,1 !賦予屬性
*ENDDO !循環結束
*ENDDO !循環結束
LSEL,ALL !選擇所有線
LSEL,S,TYPE,,2 !利用單元號選擇線
ESIZE,,5 !指定劃分數
LMESH,ALL !劃分當前選擇集中所有線
!生成墻架梁 BEAM188
KSEL,S,,,501,505,2 !選擇關鍵點
KGEN,5,ALL,,,4,,,100 !復制關鍵點每次向X方向偏移4M編號增加100
*DO,I,503,505,2 !循環控制
*DO,J,1,4,1 !循環控制
L,(J-1)*100+I,J*100+I !連線
LATT,2,,2,,,,2 !賦予屬性
*ENDDO !循環結束
*ENDDO !循環結束
LSEL,ALL !選擇所有線
LSEL,S,TYPE,,2 !利用單元號選擇線
LSEL,R,SEC,,2 !利用截面號選擇線
LMESH,ALL !劃分當前選擇集中所有線
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -