;****************************************************************
;*  ★★★    自帶字庫12864圖形中文液晶模塊演示程序    ★★★   *
;* (電子驛站單片機實驗板、開發板配套例程，程序轉載請著明出處。) *
;*  E-mail: support@ourmpu.com   QQ留言：451338254 476485321    *
;*  編程：ourmpu  http://www.ourmpu.com/ 更多例程請登陸網站     *
;****************************************************************
;* 此演示程序僅適用與本站提供的配套的自帶字庫12864液晶模塊演示  *
;* 2M位中文字型ROM(CGROM)，總共提供8192個中文字型（16×16點陣）  *
;* 16K位半寬字型ROM(HCGROM)，總共提供126個西文字型（16×8點陣）  *
;* 64×16位字符產生RAM（CGRAM）                                  *
;* 15×16位總共240點的ICON  RAM（ICONRAM）                       *
;****************************************************************

RS EQU P2.0 ;H=DATA,L=COM
RW EQU P2.1 ;H=READ,L=WRITE
E EQU P2.2 ;
COM EQU 30H ;控制字暫存單元
DAT EQU 31H ;顯示數據暫存單元
CODER EQU 32H ;字符代碼暫存單元
ADDR EQU 33H ;地址暫存單元

ORG 0000H
AJMP MAIN

ORG 0030H
MAIN:
MOV SP,#60H
MOV P2,#0F8H
LCALL DEL_20MS
LCALL DEL_20MS
LCALL DEL_20MS
LCALL DEL_20MS
LCALL DEL_20MS
LCALL INI ;進入初始化子程序
MOV ADDR,#80H
MOV DPTR,#WEL_1
LCALL W_LINE
MOV ADDR,#90H
MOV DPTR,#WEL_2
LCALL W_LINE
MOV ADDR,#88H
MOV DPTR,#WEL_3
LCALL W_LINE
MOV ADDR,#98H
MOV DPTR,#WEL_4
LCALL W_LINE
LCALL DEL_1500MS
MOV ADDR,#80H
MOV DPTR,#WEL_5
LCALL W_LINE
MOV ADDR,#90H
MOV DPTR,#WEL_6
LCALL W_LINE
MOV ADDR,#88H
MOV DPTR,#WEL_7
LCALL W_LINE
MOV ADDR,#98H
MOV DPTR,#WEL_8
LCALL W_LINE
LCALL DEL_1500MS
MOV ADDR,#80H ;
MOV DPTR,#HZ_1 ;
LCALL W_LINE
MOV ADDR,#90H ;
MOV DPTR,#HZ_2 ;
LCALL W_LINE
MOV ADDR,#88H ;
MOV DPTR,#HZ_3 ;
LCALL W_LINE
MOV ADDR,#98H ;
MOV DPTR,#HZ_4 ;
LCALL W_LINE
LCALL DEL_1500MS ;延時后重復顯示
LJMP MAIN

INI:
MOV COM,#30H ;功能設定,基本指令
LCALL WCOM
MOV COM,#30H ;基本指令,8-bit 模式,基本指令
LCALL WCOM
MOV COM,#0CH ;顯示開,游標關,反白關
LCALL WCOM
MOV COM,#01H ;清除顯示
LCALL WCOM
MOV COM,#06H ;進入設定點,游標7 右移,畫面不移動
LCALL WCOM
RET

W_LINE: ;寫入一行8 漢字子程序
MOV COM,ADDR ;
LCALL WCOM ;
MOV R2,#16 ;16 個循環,連續寫入8 個漢字或是16 個西文字符
W_L1:
MOV A,#00H
MOVC A,@A+DPTR
MOV CODER,A
LCALL WCODE
INC DPTR
DJNZ R2,W_L1
RET

WCOM: ;寫指令子程序
CLR RS
SETB RW
WC1:
MOV P0,#0FFH
SETB E
MOV A,P0
CLR E
JB ACC.7,WC1 ;查忙
CLR RW
MOV P0,COM
SETB E
CLR E
RET

WCODE: ;寫代碼子程序
CLR RS
SETB RW
WCO1:
MOV P0,#0FFH
SETB E
MOV A,P0
CLR E
JB ACC.7,WCO1
SETB RS
CLR RW
MOV P0,CODER
SETB E
CLR E
RET

DEL_20MS:
MOV R0,#30
D2:
MOV R1,#255
D1:
NOP
NOP
NOP
DJNZ R1,D1
DJNZ R0,D2
RET

DEL_100MS:
LCALL DEL_20MS
LCALL DEL_20MS
LCALL DEL_20MS
LCALL DEL_20MS
LCALL DEL_20MS
RET

DEL_500MS:
LCALL DEL_100MS
LCALL DEL_100MS
LCALL DEL_100MS
LCALL DEL_100MS
LCALL DEL_100MS
RET

DEL_1500MS:
LCALL DEL_500MS
LCALL DEL_500MS
LCALL DEL_500MS
RET

WEL_1:
DB "電子驛站歡迎您！"
WEL_2:
DB " www.ourmpu.com "
WEL_3:
DB "TEL:13376781108 "
WEL_4:
DB "FAX:0762-2826385"
WEL_5:
DB "圖形以及字符顯示"
WEL_6:
DB "顯示四行八個中文"
WEL_7:
DB "內帶標準中文字庫"
WEL_8:
DB "含8192個中文字型"
HZ_1:
DB "少小離家老大回，"
HZ_2:
DB "鄉音無改鬢毛衰。"
HZ_3:
DB "兒童相見不相識，"
HZ_4:
DB "笑問客從何處來。"
END