;===========================================================================
; File Name:	Sys_init.asm
;
; Module Name: S Y S _ I N I T				      
;
; Originator:	Digital Control Systems Group
;			Texas Instruments
;
; Description:  Initializes F24x/xx devices
;
;
;=====================================================================================
; History:
;-------------------------------------------------------------------------------------
; 9-15-2000	Release	Rev 1.0	
;===========================================================================
		.include	x24x_app.h
		.def	SYS_INIT
		.ref	GPR0

stack_size	.set	20h
stack_start	.usect	"stack",stack_size	

SYS_INIT:
		POINT_PG0
		SETC	INTM			;Disable interrupts
		SPLK	#0h, IMR		;Mask all Ints
		SPLK	#0FFh, IFR		;Clear all Int Flags

;Init PDP interrupt flag after reset		
		LDP	#PIRQR0>>7h
		LACC	PIRQR0		; Clear pending PDP flag
		AND	#0FFFEh
		SACL	PIRQR0
		LACC	PIRQR2		; Clear pending PDP flag
		AND	#0FFFEh
		SACL	PIRQR2
		POINT_EV
		LACC	EVAIFRA		; Clear PDPINTA flag
		OR	#0001h
		SACL	EVAIFRA 
		LDP	#EVBIFRA>>7h
		LACC	EVBIFRA		; Clear PDPINTB flag
		OR	#0001h
		SACL	EVBIFRA 
		
		POINT_PG0
		CLRC	SXM			;Clear Sign Extension Mode
		CLRC	OVM			;Reset Overflow Mode
		CLRC	CNF			;Config Block B0 to Data mem.
		SPM	0
		LAR	AR1, #stack_start		;Init s/w stack pointer
		MAR	*,AR1

		POINT_B0
		SPLK	#00C0h, GPR0	;Set 1 wait states for I/O space
		OUT	GPR0, WSGR

		POINT_PF1 
   
		.if (x4_PLL)  
    		SPLK	#008Dh, SCSR1	; x4 PLL, ADC en, EVA,EVAB en, clr Ill Addr flg         
		.endif 
 
    		.if (x2_PLL)  
    		SPLK	#0285h, SCSR1	; x2 PLL, ADC en, EV1 en, clr Ill Addr flg
		.endif 
        
	;Comment out if WD is to be active
		KICK_DOG
		SPLK	#006Fh, WD_CNTL 	;Disable WD if VCCP=5V
		KICK_DOG
		RET