Attribute VB_Name = "mdlOpUser"
Option Explicit

Private Const RANK1 = "總經理"
Private Const RANK2 = "公司管理層"
Private Const RANK3 = "公司庫管"
Private Const RANK4 = "連鎖店操作員"

'***********************************************************************
'* 過程名：IniListViewInOpUser
'* 功  能：以操作人員列表初始化ListView
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Sub IniListViewInOpUser(ByRef lvListViewCtl As ListView)
    If g_listViewState = USERLIST Then
        UpdateListViewInOpUser lvListViewCtl
    Else
        '變量定義
        Dim userSet As clsUserSet
        Dim opUser As clsOpuser
        Dim curListItem As ListItem
        Dim rankName As String
        
        '取得操作員集合
        Set userSet = New clsUserSet
        userSet.LoadSet g_currentUser
        
        '清除現有顯示
        lvListViewCtl.ColumnHeaders.Clear
        lvListViewCtl.ListItems.Clear
        
        '設定表頭
        lvListViewCtl.ColumnHeaders.Add , "登錄名", "登錄名"
        lvListViewCtl.ColumnHeaders.Add , "權限級別", "權限級別"
        lvListViewCtl.ColumnHeaders.Add , "所屬連鎖店", "所屬連鎖店"
        
        '明細顯示
        For Each opUser In userSet
            Set curListItem = lvListViewCtl.ListItems.Add(, , opUser.userName)
            Select Case opUser.userRank
            Case 1
                rankName = RANK1
            Case 2
                rankName = RANK2
            Case 3
                rankName = RANK3
            Case 4
                rankName = RANK4
            End Select
            curListItem.SubItems(1) = rankName
            curListItem.SubItems(2) = opUser.shopName
        Next
    End If
    g_listViewState = USERLIST
    
End Sub

'***********************************************************************
'* 過程名：UpdateListViewInOpUser
'* 功  能：更新操作人員列表
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Sub UpdateListViewInOpUser(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim userSet As clsUserSet
    Dim opUser As clsOpuser
    Dim curListItem As ListItem
    Dim rankName As String
    Dim iLoop As Integer
    
    '取得操作員集合
    Set userSet = New clsUserSet
    userSet.LoadSet g_currentUser
    
    '明細更新
    For Each opUser In userSet
        For iLoop = 1 To lvListViewCtl.ListItems.Count
            If opUser.userName = lvListViewCtl.ListItems.Item(iLoop).Text Then
                GoTo CHECKAGAIN
            End If
        Next
        
        Set curListItem = lvListViewCtl.ListItems.Add(, , opUser.userName)
        Select Case opUser.userRank
        Case 1
            rankName = RANK1
        Case 2
            rankName = RANK2
        Case 3
            rankName = RANK3
        Case 4
            rankName = RANK4
        End Select
        curListItem.SubItems(1) = rankName
        curListItem.SubItems(2) = opUser.shopName
CHECKAGAIN:
    Next
End Sub

'***********************************************************************
'* 過程名：RemoveOpUser
'* 功  能：刪除操作人員
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Sub RemoveOpUser(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim opUserName As String    '操作員名
    Dim opUser As clsOpuser     '操作員
    Dim opUserObj As clsOpUserInfo '操作員對象
    
    If Not lvListViewCtl.SelectedItem Is Nothing Then
        opUserName = lvListViewCtl.SelectedItem.Text
        If MsgBox("刪除操作員[" & opUserName & "]嗎？", vbQuestion Or _
                vbYesNo, "詢問") = vbYes Then
            Set opUser = New clsOpuser
            If opUser.LoadByUserName(opUserName) = DbOpRecExist Then
                Set opUserObj = New clsOpUserInfo
                If opUserObj.RemoveUser(opUser, g_currentUser) Then
                    lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.Index
                    Exit Sub
                End If
            End If
            MsgBox "刪除操作員失敗！", vbExclamation Or vbOKOnly, "警告"
        End If
    Else
        MsgBox "請先選擇要刪除的操作員！", vbExclamation Or vbOKOnly, "警告"
    End If
End Sub

'***********************************************************************
'* 過程名：EditOpUser
'* 功  能：編輯操作人員
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Sub EditOpUser(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim currentSelUserName As String    '當前選擇用戶登錄名
    Dim currentSelUser As clsOpuser     '當前選擇用戶
    Dim opUserInfo As clsOpUserInfo     '用戶信息操作對象
    
    '取得當前選擇
    If lvListViewCtl.SelectedItem Is Nothing Then
         MsgBox "請選擇要編輯的操作員！", vbExclamation Or vbOKOnly, "警告"
    Else
        currentSelUserName = Trim(lvListViewCtl.SelectedItem.Text)
        Set currentSelUser = New clsOpuser
        If currentSelUser.LoadByUserName(currentSelUserName) = DbOpRecExist Then
            Set opUserInfo = New clsOpUserInfo
            opUserInfo.EditUser currentSelUser, g_currentUser
            lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.Index
            UpdateListViewInOpUser lvListViewCtl
        Else
            MsgBox "讀取操作員信息失敗！", vbExclamation Or vbOKOnly, "警告"
        End If
    End If
End Sub

'***********************************************************************
'* 過程名：AppendNewUser
'* 功  能：追加操作人員
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.02 顏志軍 初版
'***********************************************************************
Public Sub AppendNewUser(ByRef lvListViewCtl As ListView)
    Dim opUser As clsOpUserInfo
    Set opUser = New clsOpUserInfo
    opUser.AppendNewUser g_currentUser
    UpdateListViewInOpUser lvListViewCtl
End Sub