Attribute VB_Name = "mdlMerchandise"
Option Explicit

'***********************************************************************
'* 過程名：AppendMerchandise
'* 功  能：追加新商品
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub AppendMerchandise(ByRef lvListViewCtl As ListView)
    Dim opMerchandiseinfo As clsOpMerchandiseinfo
    Set opMerchandiseinfo = New clsOpMerchandiseinfo
    opMerchandiseinfo.AppendNewMerchandise g_currentUser
    UpdateListViewInMerchandise lvListViewCtl
End Sub

'***********************************************************************
'* 過程名：EditMerchandise
'* 功  能：編輯商品信息
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub EditMerchandise(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim currentSelMerchandiseString As String            '當前選擇商品ID
    Dim currentSelMerchandiseInfo As clsMerchandiseinfo  '當前選擇商品
    Dim opMerchandise As clsOpMerchandiseinfo            '商品操作對象
    
    '取得當前選擇
    If lvListViewCtl.SelectedItem Is Nothing Then
         MsgBox "請選擇要編輯的商品類別！", vbExclamation Or vbOKOnly, "警告"
    Else
        currentSelMerchandiseString = Trim(lvListViewCtl.SelectedItem.Text)
        Set currentSelMerchandiseInfo = New clsMerchandiseinfo
        If currentSelMerchandiseInfo.LoadById(CInt(currentSelMerchandiseString)) = DbOpRecExist Then
            Set opMerchandise = New clsOpMerchandiseinfo
            opMerchandise.EditMerchandise currentSelMerchandiseInfo, g_currentUser
            lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.Index
            UpdateListViewInMerchandise lvListViewCtl
        Else
            MsgBox "讀取商品信息失敗！", vbExclamation Or vbOKOnly, "警告"
        End If
    End If
End Sub

'***********************************************************************
'* 過程名：RemoveMerchandise
'* 功  能：刪除商品
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub RemoveMerchandise(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim currentSelMerchandiseString As String            '當前選擇商品ID
    Dim currentSelMerchandiseInfo As clsMerchandiseinfo  '當前選擇商品
    Dim opMerchandise As clsOpMerchandiseinfo            '商品操作對象
    
    If Not lvListViewCtl.SelectedItem Is Nothing Then
        currentSelMerchandiseString = lvListViewCtl.SelectedItem.Text
        If MsgBox("刪除ID為[" & currentSelMerchandiseString & "]的商品嗎？", _
                vbQuestion Or vbYesNo, "詢問") = vbYes Then
            Set currentSelMerchandiseInfo = New clsMerchandiseinfo
            If currentSelMerchandiseInfo.LoadById(CInt(currentSelMerchandiseString)) = DbOpRecExist Then
                Set opMerchandise = New clsOpMerchandiseinfo
                If opMerchandise.RemoveMerchandise(currentSelMerchandiseInfo, g_currentUser) Then
                    lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.Index
                    Exit Sub
                End If
            End If
            MsgBox "刪除商品失敗！", vbExclamation Or vbOKOnly, "警告"
        End If
    Else
        MsgBox "請先選擇要刪除的商品！", vbExclamation Or vbOKOnly, "警告"
    End If
End Sub

'***********************************************************************
'* 過程名：IniListViewInMerchandise
'* 功  能：以商品列表初始化ListView
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub IniListViewInMerchandise(ByRef lvListViewCtl As ListView)
    If g_listViewState = MERCHANDISELIST Then
        UpdateListViewInMerchandise lvListViewCtl
    Else
        '變量定義
        Dim merchandiseSet As clsMerchandiseinfoSet
        Dim merchandise As clsMerchandiseinfo
        Dim curListItem As ListItem
        
        '取得商品類型集合
        Set merchandiseSet = New clsMerchandiseinfoSet
        
        '清除現有顯示
        lvListViewCtl.ColumnHeaders.Clear
        lvListViewCtl.ListItems.Clear
        
        '設定表頭
        lvListViewCtl.ColumnHeaders.Add , "商品ID", "商品ID"
        lvListViewCtl.ColumnHeaders.Add , "商品名", "商品名"
        lvListViewCtl.ColumnHeaders.Add , "所屬類別", "所屬類別"
        lvListViewCtl.ColumnHeaders.Add , "備注", "備注"
        
        '明細顯示
        For Each merchandise In merchandiseSet
            Set curListItem = lvListViewCtl.ListItems.Add(, , CStr(merchandise.merchandiseId))
            curListItem.SubItems(1) = merchandise.merchandiseName
            curListItem.SubItems(2) = merchandise.kindName
            curListItem.SubItems(3) = merchandise.remark
        Next
    End If
    g_listViewState = MERCHANDISELIST
End Sub

'***********************************************************************
'* 過程名：UpdateListViewInMerchandise
'* 功  能：更新商品列表
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub UpdateListViewInMerchandise(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim merchandiseSet As clsMerchandiseinfoSet
    Dim merchandise As clsMerchandiseinfo
    Dim curListItem As ListItem
    Dim iLoop As Integer
    
    '取得商品類型集合
    Set merchandiseSet = New clsMerchandiseinfoSet
    
    '明細更新
    For Each merchandise In merchandiseSet
        For iLoop = 1 To lvListViewCtl.ListItems.Count
            If merchandise.merchandiseId = lvListViewCtl.ListItems.Item(iLoop).Text Then
                GoTo CHECKAGAIN
            End If
        Next
        
        Set curListItem = lvListViewCtl.ListItems.Add(, , CStr(merchandise.merchandiseId))
        curListItem.SubItems(1) = merchandise.merchandiseName
        curListItem.SubItems(2) = merchandise.kindName
        curListItem.SubItems(3) = merchandise.remark
CHECKAGAIN:
    Next
End Sub