Attribute VB_Name = "mdlMerchandiseKind"
Option Explicit

'***********************************************************************
'* 過程名：AppendMerchandiseKind
'* 功  能：追加新類別
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub AppendMerchandiseKind(ByRef lvListViewCtl As ListView)
    Dim opMerchandiseKind As clsOpMerchandisekind
    Set opMerchandiseKind = New clsOpMerchandisekind
    opMerchandiseKind.AppendNewMerchandisekind g_currentUser
    UpdateListViewInMerchandiseKind lvListViewCtl
End Sub

'***********************************************************************
'* 過程名：EditMerchandiseKind
'* 功  能：編輯商品類別信息
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub EditMerchandiseKind(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim currentSelMerchandiseKindString As String        '當前選擇商品類別ID
    Dim currentSelMerchandiseKind As clsMerchandisekind  '當前選擇商品類別
    Dim opMerchandiseKind As clsOpMerchandisekind        '商品類別操作對象
    
    '取得當前選擇
    If lvListViewCtl.SelectedItem Is Nothing Then
         MsgBox "請選擇要編輯的商品類別！", vbExclamation Or vbOKOnly, "警告"
    Else
        currentSelMerchandiseKindString = Trim(lvListViewCtl.SelectedItem.Text)
        Set currentSelMerchandiseKind = New clsMerchandisekind
        If currentSelMerchandiseKind.LoadByKindId(CInt(currentSelMerchandiseKindString)) = DbOpRecExist Then
            Set opMerchandiseKind = New clsOpMerchandisekind
            opMerchandiseKind.EditMerchandiseKind currentSelMerchandiseKind, g_currentUser
            lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.index
            UpdateListViewInMerchandiseKind lvListViewCtl
        Else
            MsgBox "讀取商品類別信息失敗！", vbExclamation Or vbOKOnly, "警告"
        End If
    End If
End Sub

'***********************************************************************
'* 過程名：RemoveMerchandiseKind
'* 功  能：刪除商品種類
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub RemoveMerchandiseKind(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim currentSelMerchandiseKindString As String        '當前選擇商品類別ID
    Dim currentSelMerchandiseKind As clsMerchandisekind  '當前選擇商品類別
    Dim opMerchandiseKind As clsOpMerchandisekind        '商品類別操作對象
    Dim merchandiseSet As clsMerchandiseinfoSet          '商品集
    
    If Not lvListViewCtl.SelectedItem Is Nothing Then
        currentSelMerchandiseKindString = lvListViewCtl.SelectedItem.Text
        '檢查該類下是否還有商品
        Set merchandiseSet = New clsMerchandiseinfoSet
        merchandiseSet.LoadSetByKindId currentSelMerchandiseKindString
        If merchandiseSet.Count > 0 Then
            MsgBox "該商品類別下還有商品，不能刪除該類別！", vbExclamation Or vbOKOnly, "警告"
            Exit Sub
        End If
        
        '執行刪除
        If MsgBox("刪除ID為[" & currentSelMerchandiseKindString & "]的商品種類嗎？", _
                vbQuestion Or vbYesNo, "詢問") = vbYes Then
            Set currentSelMerchandiseKind = New clsMerchandisekind
            If currentSelMerchandiseKind.LoadByKindId(CInt(currentSelMerchandiseKindString)) = DbOpRecExist Then
                Set opMerchandiseKind = New clsOpMerchandisekind
                If opMerchandiseKind.RemoveMerchandiseKind(currentSelMerchandiseKind, g_currentUser) Then
                    lvListViewCtl.ListItems.Remove lvListViewCtl.SelectedItem.index
                    Exit Sub
                End If
            End If
            MsgBox "刪除商品類別失敗！", vbExclamation Or vbOKOnly, "警告"
        End If
    Else
        MsgBox "請先選擇要刪除的商品類別！", vbExclamation Or vbOKOnly, "警告"
    End If
End Sub

'***********************************************************************
'* 過程名：IniListViewInMerchandiseKind
'* 功  能：以商品種類列表初始化ListView
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub IniListViewInMerchandiseKind(ByRef lvListViewCtl As ListView)
    If g_listViewState = MERCHANDISEKINDLIST Then
        UpdateListViewInMerchandiseKind lvListViewCtl
    Else
        '變量定義
        Dim kindSet As clsMerchandisekindSet
        Dim merchandiseKind As clsMerchandisekind
        Dim curListItem As ListItem
        
        '取得商品類型集合
        Set kindSet = New clsMerchandisekindSet
        
        '清除現有顯示
        lvListViewCtl.ColumnHeaders.Clear
        lvListViewCtl.ListItems.Clear
        
        '設定表頭
        lvListViewCtl.ColumnHeaders.Add , "商品類別ID", "商品類別ID"
        lvListViewCtl.ColumnHeaders.Add , "商品類別名", "商品類別名"
        lvListViewCtl.ColumnHeaders.Add , "備注", "備注"
        
        '明細顯示
        For Each merchandiseKind In kindSet
            Set curListItem = lvListViewCtl.ListItems.Add(, , CStr(merchandiseKind.kindId))
            curListItem.SubItems(1) = merchandiseKind.kindName
            curListItem.SubItems(2) = merchandiseKind.remark
        Next
    End If
    g_listViewState = MERCHANDISEKINDLIST
End Sub

'***********************************************************************
'* 過程名：UpdateListViewInMerchandiseKind
'* 功  能：更新商品類別列表
'* 參  數：ListView                 列表控件
'* 版  本：2006.01.03 顏志軍 初版
'***********************************************************************
Public Sub UpdateListViewInMerchandiseKind(ByRef lvListViewCtl As ListView)
    '變量定義
    Dim kindSet As clsMerchandisekindSet
    Dim merchandiseKind As clsMerchandisekind
    Dim curListItem As ListItem
    Dim iLoop As Integer
    
    '取得商品類型集合
    Set kindSet = New clsMerchandisekindSet
    
    '明細更新
    For Each merchandiseKind In kindSet
        For iLoop = 1 To lvListViewCtl.ListItems.Count
            If merchandiseKind.kindId = lvListViewCtl.ListItems.item(iLoop).Text Then
                GoTo CHECKAGAIN
            End If
        Next
        
        Set curListItem = lvListViewCtl.ListItems.Add(, , merchandiseKind.kindId)
        curListItem.SubItems(1) = merchandiseKind.kindName
        curListItem.SubItems(2) = merchandiseKind.remark
CHECKAGAIN:
    Next
End Sub