Attribute VB_Name = "mdlTreeViewInMainLeft"
Option Explicit

Private Const KINDKEYPRE = "KINDKEY"                '類別KYE前綴
Private Const MERCHANDISEKEYPRE = "MERCHANDISEKEY"  '商品KEY前綴

'***********************************************************************
'* 過程名：IniTreeView
'* 功  能：初始化TreeView
'* 參  數(shù)：TreeView                  TreeView控件
'* 版  本：2006.01.05 顏志軍 初版
'***********************************************************************
Public Sub IniTreeView(ByRef tvTreeViewCtl As TreeView)
    '變量定義
    Dim kindSet As clsMerchandisekindSet    '商口類別集
    Dim kind As clsMerchandisekind          '商品類別
    Dim currentNode As Node                 '當(dāng)前節(jié)點(diǎn)
    
    '生成對象
    Set kindSet = New clsMerchandisekindSet
    
    '清空TreeView中節(jié)點(diǎn)
    tvTreeViewCtl.Nodes.Clear
    
    '加入控件
    For Each kind In kindSet
        Set currentNode = tvTreeViewCtl.Nodes.Add(, tvwLast, _
                KINDKEYPRE & CStr(kind.kindId), kind.kindName, 1)
        '加入該類下的商品
        IniMerchandiseInTreeView tvTreeViewCtl, currentNode.index, kind.kindId
    Next
End Sub

'***********************************************************************
'* 過程名：IniMerchandiseInTreeView
'* 功  能：初始化類別下商品名
'* 參  數(shù)：TreeView                     TreeView控件
'*       ：Integer                      類別節(jié)點(diǎn)index
'*       ：Integer                      類別ID
'* 版  本：2006.01.05 顏志軍 初版
'***********************************************************************
Private Sub IniMerchandiseInTreeView(ByRef tvTreeViewCtl As TreeView, _
        ByVal index As Integer, _
        ByVal kindId As Integer)
    '變量定義
    Dim merchandiseSet As clsMerchandiseinfoSet '商品集
    Dim merchandise As clsMerchandiseinfo       '商品
    
    '取得指定類別下商品集
    Set merchandiseSet = New clsMerchandiseinfoSet
    merchandiseSet.LoadSetByKindId kindId
    
    '加入控件
    For Each merchandise In merchandiseSet
        tvTreeViewCtl.Nodes.Add index, tvwChild, MERCHANDISEKEYPRE & _
            CStr(merchandise.merchandiseId), merchandise.merchandiseName, 2
    Next
End Sub

'***********************************************************************
'* 過程名：GetCurrentSel
'* 功  能：取得當(dāng)前選擇
'* 參  數(shù)：Integer                      節(jié)點(diǎn)類型 1類別 2商品
'*       ：String                       名稱
'*       ：TreeView                     TreeView控件
'* 版  本：2006.01.06 顏志軍 初版
'***********************************************************************
Private Sub GetCurrentSel(ByRef selKind As Integer, _
                        ByRef selName As String, _
                        ByRef tvTreeViewCtl As TreeView)
    
    If Not tvTreeViewCtl.SelectedItem Is Nothing Then
        '取得節(jié)點(diǎn)KEY及TEXT屬性
        Dim key As String
        Dim itemName As String
        key = tvTreeViewCtl.SelectedItem.key
        itemName = tvTreeViewCtl.SelectedItem.Text
        
        '分析節(jié)點(diǎn)
        If InStr(key, KINDKEYPRE) > 0 Then  '類別
            selKind = 1
        Else    '商品
            selKind = 2
        End If
        selName = itemName
    Else
        selKind = 0 '無選擇節(jié)點(diǎn)
    End If
    
End Sub

'***********************************************************************
'* 函數(shù)名：FindItemInListView
'* 功  能：在LISTVIEW中查找條目
'* 參  數(shù)：ListView                     列表控件
'*       ：TreeView                     TreeView控件
'* 版  本：2006.01.06 顏志軍 初版
'***********************************************************************
Private Function FindItemInListView(ByRef lvListViewCtl As ListView, _
                                    ByVal col As Integer, _
                                    ByVal flag As String) As Integer
    '單獨(dú)一行
    Dim item As ListItem
                                        
    For Each item In lvListViewCtl.ListItems
        If col = 0 Then
            If item.Text = flag Then
                FindItemInListView = item.index
                Exit Function
            End If
        ElseIf col > 0 And col <= item.ListSubItems.Count Then
            If item.SubItems(col) = flag Then
                FindItemInListView = item.index
                Exit Function
            End If
        End If
    Next
    
    FindItemInListView = -1
End Function

'***********************************************************************
'* 過程名：UpdateSelectInList
'* 功  能：更新LISTVIEW選擇條
'* 參  數(shù)：ListView                     列表控件
'*       ：TreeView                     TreeView控件
'* 版  本：2006.01.06 顏志軍 初版
'***********************************************************************
Public Sub UpdateSelectInList(ByRef lvListViewCtl As ListView, _
                                ByRef tvTreeViewCtl As TreeView)
                                
    '變量定義
    Dim curSelKind As Integer   '當(dāng)前選擇節(jié)點(diǎn)類型
    Dim curSelName As String    '當(dāng)前選擇節(jié)點(diǎn)內(nèi)容
    Dim index As Integer        '更新的選擇位置
    
    '取得選擇信息
    GetCurrentSel curSelKind, curSelName, tvTreeViewCtl
    
    '更新ListView選擇條位置
    Select Case g_listViewState
    Case USERLIST
    Case MEMBERSHOPLIST
    Case MERCHANDISEKINDLIST
        If curSelKind = 1 Then
            index = FindItemInListView(lvListViewCtl, 1, curSelName)
        End If
    Case MERCHANDISELIST
        If curSelKind = 1 Then
            index = FindItemInListView(lvListViewCtl, 2, curSelName)
        ElseIf curSelKind = 2 Then
            index = FindItemInListView(lvListViewCtl, 1, curSelName)
        End If
    Case APPLYLIST
        If curSelKind = 2 Then
            index = FindItemInListView(lvListViewCtl, 2, curSelName)
        End If
    Case DAYREPORTLIST
        If curSelKind = 2 Then
            index = FindItemInListView(lvListViewCtl, 2, curSelName)
        End If
    Case REPORTDAY
        If curSelKind = 1 Then
            index = FindItemInListView(lvListViewCtl, 3, curSelName)
        ElseIf curSelKind = 2 Then
            index = FindItemInListView(lvListViewCtl, 2, curSelName)
        End If
    Case REPORTMON
        If curSelKind = 1 Then
            index = FindItemInListView(lvListViewCtl, 3, curSelName)
        ElseIf curSelKind = 2 Then
            index = FindItemInListView(lvListViewCtl, 2, curSelName)
        End If
    End Select
    
    If index > 0 Then
        lvListViewCtl.ListItems(index).Selected = True
    End If
End Sub