VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsOpuser"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Attribute VB_Ext_KEY = "SavedWithClassBuilder6" ,"Yes"
Attribute VB_Ext_KEY = "Top_Level" ,"Yes"
Option Explicit

'保持屬性值的局部變量
Private mvaruserName As String '局部復制
Private mvaruserPwd As String '局部復制
Private mvaruserRank As Integer '局部復制
'保持屬性值的局部變量
Private mvarshopId As Long '局部復制
'保持屬性值的局部變量
Private mvarshopName As String '局部復制
Public Property Let shopName(ByVal vData As String)
'向屬性指派值時使用，位于賦值語句的左邊。
'Syntax: X.shopName = 5
    mvarshopName = vData
End Property


Public Property Get shopName() As String
'檢索屬性值時使用，位于賦值語句的右邊。
'Syntax: Debug.Print X.shopName
    shopName = mvarshopName
End Property



Public Property Let shopId(ByVal vData As Long)
'向屬性指派值時使用，位于賦值語句的左邊。
'Syntax: X.shopId = 5
    mvarshopId = vData
End Property


Public Property Get shopId() As Long
'檢索屬性值時使用，位于賦值語句的右邊。
'Syntax: Debug.Print X.shopId
    shopId = mvarshopId
End Property



Public Property Let userRank(ByVal vData As Integer)
'向屬性指派值時使用，位于賦值語句的左邊。
'Syntax: X.userRank = 5
    mvaruserRank = vData
End Property


Public Property Get userRank() As Integer
'檢索屬性值時使用，位于賦值語句的右邊。
'Syntax: Debug.Print X.userRank
    userRank = mvaruserRank
End Property



Public Property Let userPwd(ByVal vData As String)
'向屬性指派值時使用，位于賦值語句的左邊。
'Syntax: X.userPwd = 5
    mvaruserPwd = vData
End Property


Public Property Get userPwd() As String
'檢索屬性值時使用，位于賦值語句的右邊。
'Syntax: Debug.Print X.userPwd
    userPwd = mvaruserPwd
End Property



Public Property Let userName(ByVal vData As String)
'向屬性指派值時使用，位于賦值語句的左邊。
'Syntax: X.userName = 5
    mvaruserName = vData
End Property


Public Property Get userName() As String
'檢索屬性值時使用，位于賦值語句的右邊。
'Syntax: Debug.Print X.userName
    userName = mvaruserName
End Property

'***********************************************************************
'* 函數名：IsExist
'* 功  能：當前操作人員是否已存在于數據庫中
'* 參  數：
'* 返回值：Boolean                  True 存在 False 不存在或數據查詢錯誤
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Private Function IsExist() As Boolean
    '變量定義
    Dim sql As String           'SQL
    Dim rs As ADODB.Recordset   '記錄集
    
    '生成查詢SQL
    sql = "SELECT * FROM view_UserShop WHERE userName = '" & userName & "'"
    
    '執(zhí)行查詢
    IsExist = False
    On Error GoTo FUNEND
    Set rs = g_conn.Execute(sql)
    If Not rs.EOF Then
        IsExist = True
    End If
    rs.Close
    Set rs = Nothing
FUNEND:
End Function

'***********************************************************************
'* 函數名：IsOnlyAdmin
'* 功  能：是否是最后一位總經理帳號碼
'* 參  數：
'* 返回值：Boolean                  True 是 False 不是
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Private Function IsOnlyAdmin() As Boolean
    '變量定義
    Dim sql As String           'SQL
    Dim rs As ADODB.Recordset   '記錄集
    
    '生成查詢SQL
    sql = "SELECT COUNT(*) FROM view_UserShop WHERE userRank = 1"
    
    '執(zhí)行查詢
    IsOnlyAdmin = False
    On Error GoTo FUNEND
    Set rs = g_conn.Execute(sql)
    If Not rs.EOF Then
        If rs(0) = 1 Then
            IsOnlyAdmin = True
        End If
    End If
    rs.Close
    Set rs = Nothing
FUNEND:
End Function

'***********************************************************************
'* 函數名：AppendNew
'* 功  能：追加當前操作人員信息到數據庫
'* 參  數：
'* 返回值：DbOpResult                   數據庫操作結果
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Function AppendNew() As DbOpResult
    '變量定義
    Dim sql As String       'SQL
    Dim affectLines As Long '影響行數
    
    '檢查用戶名是否已存在
    If IsExist() Then
        AppendNew = DbOpRecExist
        Exit Function
    End If
    
    '生成SQL
    sql = "INSERT INTO opuser(userName, userPwd, userRank, shopId) VALUES('" & _
        userName & "','" & userPwd & "'," & CStr(userRank) & "," & CStr(shopId) & ")"
        
    '執(zhí)行插入
    AppendNew = DbOpNG
    On Error Resume Next
    g_conn.Execute sql, affectLines
    If affectLines = 1 Then
        AppendNew = DbOpOk
    End If
End Function

'***********************************************************************
'* 函數名：Update
'* 功  能：更新當前操作人員信息到數據庫
'* 參  數：
'* 返回值：DbOpResult                   數據庫操作結果
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Function Update() As DbOpResult
    '變量定義
    Dim sql As String       'SQL
    Dim affectLines As Long '影響行數
    
    '修正級別與店ID對應關系
    If userRank < 4 Then
        shopId = 1
    End If
    
    '檢查當前操作人員登錄名是否存在
    If Not IsExist() Then
        Update = DbOpRecNoExist
        Exit Function
    End If
    
    '生成SQL
    sql = "UPDATE opuser SET userPwd = '" & userPwd & "'"
    sql = sql & ", userRank = " & CStr(userRank)
    sql = sql & ", shopId = " & CStr(shopId)
    sql = sql & " WHERE userName ='" & userName & "'"
        
    '執(zhí)行更新
    Update = DbOpNG
    On Error Resume Next
    g_conn.Execute sql, affectLines
    If affectLines = 1 Then
        Update = DbOpOk
    End If
End Function

'***********************************************************************
'* 函數名：Delete
'* 功  能：從數據庫中刪除當前操作人員信息
'* 參  數：
'* 返回值：DbOpResult                   數據庫操作結果
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Function Delete() As DbOpResult
    '最后一個總經理帳號拒絕刪除
    If userRank = 1 And IsOnlyAdmin() Then
        Delete = DbOpOnlyRec
        Exit Function
    End If

    '變量定義
    Dim sql As String       'SQL
    Dim affectLines As Long '影響行數
    
    '生成SQL
    sql = "DELETE FROM opuser WHERE userName = '" & userName & "'"
        
    '執(zhí)行刪除
    Delete = DbOpNG
    On Error Resume Next
    g_conn.Execute sql, affectLines
    If affectLines = 1 Then
        Delete = DbOpOk
    End If
End Function

'***********************************************************************
'* 函數名：LoadByUserName
'* 功  能：從數據庫中載入指定操作人員信息
'* 參  數：String                       登陸用戶名
'* 返回值：DbOpResult                   數據庫操作結果
'* 版  本：2006.01.01 顏志軍 初版
'***********************************************************************
Public Function LoadByUserName(ByVal loginUser As String) As DbOpResult
    '變量定義
    Dim sql As String           'SQL
    Dim rs As ADODB.Recordset   '記錄集
    
    '生成查詢SQL
    sql = "SELECT * FROM view_UserShop WHERE userName = '" & Trim(loginUser) & "'"
    
    '執(zhí)行查詢
    LoadByUserName = DbOpNG
    On Error Resume Next
    Set rs = g_conn.Execute(sql)
    If Not rs.EOF Then
        Me.userName = rs("userName")
        Me.userPwd = rs("userPwd")
        Me.userRank = rs("userRank")
        Me.shopId = rs("shopId")
        Me.shopName = rs("shopName")
        LoadByUserName = DbOpRecExist
    Else
        LoadByUserName = DbOpRecNoExist
    End If
    rs.Close
    Set rs = Nothing
End Function