ORG 0000H
;單片機內存分配申明!
TEMPER_L EQU 29H;用于保存讀出溫度的低8位
TEMPER_H EQU 28H;用于保存讀出溫度的高8位
FLAG1 EQU 38H;是否檢測到DS18B20標志位
a_bit equ 20h ;數碼管個位數存放內存位置
b_bit equ 21h ;數碼管十位數存放內存位置


        KEY_BUF_G DATA 39H ;鍵盤輸入后，的個位值
        KEY_BUF_S DATA 49H ;鍵盤輸入后，的十位值
        KEY_BUF_B DATA 41H ;鍵盤輸入后，的百位值

        K_UP EQU P1.5     ;上調按鈕
        K_DOWN EQU P1.6   ;下調按鈕
        K_ENTER EQU P1.7  ;輸入數據確認按鈕
        K_NOWATER EQU P1.4

        P_DS18B20 EQU P3.3  ;讀取DS18B20的輸入端口
        P_SWITCH EQU P1.3   ;繼電器控制端口,1－風扇，0－電爐

        FLAG EQU 20H.0        ;標志位,確定是否存在DS18B20
        ENTER_FLAG EQU 20H.1  ;鍵盤輸入的標志位,為0說明鍵盤正在輸入，為1說明鍵盤輸入退出
MAIN:
LCALL GET_TEMPER;調用讀溫度子程序
;進行溫度顯示,這里我們考慮用網站提供的兩位數碼管來顯示溫度
;顯示范圍00到99度,顯示精度為1度
;因為12位轉化時每一位的精度為0.0625度,我們不要求顯示小數所以可以拋棄29H的低4位
;將28H中的低4位移入29H中的高4位,這樣獲得一個新字節,這個字節就是實際測量獲得的溫度
;這個轉化溫度的方法可是我想出來的哦~~非常簡潔無需乘于0.0625系數
MOV A,29H
MOV C,40H;將28H中的最低位移入C
RRC A
MOV C,41H
RRC A
MOV C,42H
RRC A
MOV C,43H
RRC A
MOV 29H,A
LCALL DISPLAY;調用數碼管顯示子程序
LCALL SCAN_KEY
LCALL SWITCH
AJMP MAIN

;程序名稱:ERR
;功能:程序出錯處理，顯示四個8，即8888
;入口參數:無
;出口參數:DIS_BUF_X,DIS_BUF_G, DIS_BUF_S, DIS_BUF_B
ERR:	MOV a_bit,#08H ;如果沒有找到DS18B20，那么就顯示錯誤，錯誤顯示為888
        MOV b_bit,#08H
        LCALL DISPLAY
        SETB P3.0
        RET


; 這是DS18B20復位初始化子程序
INIT_1820:
SETB P3.3
NOP
CLR P3.3
;主機發出延時537微秒的復位低脈沖
MOV R1,#3
TSR1:MOV R0,#107
DJNZ R0,$
DJNZ R1,TSR1
SETB P3.3;然后拉高數據線
NOP
NOP
NOP
MOV R0,#25H
TSR2:
JNB P3.3,TSR3;等待DS18B20回應
DJNZ R0,TSR2
LJMP TSR4 ; 延時
TSR3:
SETB FLAG1 ; 置標志位,表示DS1820存在
LJMP TSR5
TSR4:
CLR FLAG1 ; 清標志位,表示DS1820不存在
LJMP TSR7
TSR5:
MOV R0,#117
TSR6:
DJNZ R0,TSR6 ; 時序要求延時一段時間
TSR7:
SETB P3.3
RET

; 讀出轉換后的溫度值
GET_TEMPER:
SETB P3.3
LCALL INIT_1820;先復位DS18B20
JB FLAG1,TSS2
RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
TSS2:
CLR P3.0;DS18B20已經被檢測到!!!!!!!!!!!!!!!!!!
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H ; 發出溫度轉換命令
LCALL WRITE_1820
;這里通過調用顯示子程序實現延時一段時間,等待AD轉換結束,12位的話750微秒
LCALL DISPLAY
LCALL INIT_1820;準備讀溫度前先復位
MOV A,#0CCH ; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH ; 發出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200; 將讀出的溫度數據保存到35H/36H
RET
;寫DS18B20的子程序(有具體的時序要求)
WRITE_1820:
MOV R2,#8;一共8位數據
CLR C
WR1:
CLR P3.3
MOV R3,#6
DJNZ R3,$
RRC A
MOV P3.3,C
MOV R3,#23
DJNZ R3,$
SETB P3.3
NOP
DJNZ R2,WR1
SETB P3.3
RET
; 讀DS18B20的程序,從DS18B20中讀出兩個字節的溫度數據
READ_18200:
MOV R4,#2 ; 將溫度高位和低位從DS18B20中讀出
MOV R1,#29H ; 低位存入29H(TEMPER_L),高位存入28H(TEMPER_H)
RE00:
MOV R2,#8;數據一共有8位
RE01:
CLR C
SETB P3.3
NOP
NOP
CLR P3.3
NOP
NOP
NOP
SETB P3.3
MOV R3,#9
RE10:
DJNZ R3,RE10
MOV C,P3.3
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
DEC R1
DJNZ R4,RE00
RET

;程序名稱:SCAN_KEY
;功能:掃描鍵盤
;入口參數:DIS_BUF_G,DIS_BUF_S,DIS_BUF_B
;出口參數:KEY_BUF_G,KEY_BUF_S,kEY_BUF_B
SCAN_KEY:
      JNB K_NOWATER,NOWATER
      JB K_ENTER,QUIT			;如果有Enter鍵入，則開始鍵盤輸入
      LCALL K_DELAY
      JB K_ENTER,QUIT
      CLR ENTER_FLAG				;每次進來都賦值輸入標志，設置為0
      MOV KEY_BUF_G,a_bit ;將當前的溫度賦值給KEY_BUF,也就是說是以當前溫度為基準，進行加減的
      MOV KEY_BUF_S,b_bit
K_LOOP:
      JB ENTER_FLAG,QUIT;如果輸入完成，ENTER_FLAG則為1，退出鍵盤程序
      JB K_ENTER,KUP
      CALL PRO_ENTER
KUP:  JB K_UP,KDOWN
      CALL PRO_UP
KDOWN:JB K_DOWN,LOOPA
      CALL PRO_DOWN
LOOPA:LCALL DISPLAY
      SJMP K_LOOP
QUIT: RET


;程序名稱：無水報警子程序
NOWATER:
       CALL K_DELAY
       JB  K_NOWATER,SCAN_KEY
       CLR P3.0
       call err
       CLR P1.3
       RET


;程序名稱:PRO_ENTER
;功能:確認鍵盤輸入和退出鍵盤輸入
;入口參數:ENTER_FLAG
;出口參數:ENTER_FLAG
PRO_ENTER:
      CALL K_DELAY
      JB K_ENTER,K_LOOP ;按鍵抖動處理
      SETB ENTER_FLAG
      CALL K_DELAY
      RET

;程序名稱:PRO_UP
;功能:數值上調處理
;入口參數:KEY_BUF_G,KEY_BUF_S,KEY_BUF_B
;出口參數:DIS_BUF_G,DIS_BUF_S,DIS_BUF_B
PRO_UP:
      CALL K_DELAY
      JB K_UP,K_LOOP    ;按鍵抖動處理
      INC KEY_BUF_G     ;個位增一
      MOV A,KEY_BUF_G
      CJNE A,#0AH,UPNEXT;個位增加到10，回0
      MOV KEY_BUF_G,#00H
      INC KEY_BUF_S     ;十位加一
      MOV A,KEY_BUF_S
      CJNE A,#0AH,UPNEXT;十位超過99，溢出了
      MOV R0,#200
ERROR1:LCALL ERR        ;出錯，顯示8888
      DJNZ R0,ERROR1
      DEC KEY_BUF_S     ;退回99
      MOV KEY_BUF_G,#09H
UPNEXT:
      MOV a_bit,KEY_BUF_G
      MOV b_bit,KEY_BUF_S

      CALL K_DELAY
      RET

;程序名稱:PRO_DOWN
;功能:數值下調處理
;入口參數:KEY_BUF_G,KEY_BUF_S,KEY_BUF_B
;出口參數:DIS_BUF_G,DIS_BUF_S,DIS_BUF_B
PRO_DOWN:
      CALL K_DELAY
      JB K_DOWN,K_LOOP    ;按鍵抖動處理
      DEC KEY_BUF_G       ;個位減一
      MOV A,KEY_BUF_G
      CJNE A,#0FFH,DOWNNEXT;個位減到0，回到9
      MOV KEY_BUF_G,#09H
      DEC KEY_BUF_S        ;十位減一
      MOV A,KEY_BUF_S
      CJNE A,#0FFH,DOWNNEXT;十位低于0，溢出了
      MOV R0,#200
ERROR2:LCALL ERR           ;出錯，顯示8888
      DJNZ R0,ERROR2
      INC KEY_BUF_S        ;退回00
      MOV KEY_BUF_G,#00H
DOWNNEXT:
      MOV a_bit,KEY_BUF_G ;增加完成后，賦值退出，然后DISPLAY顯示出來
      MOV b_bit,KEY_BUF_S
      CALL K_DELAY
      RET




K_DELAY:			;鍵盤抖動延時子程序
	MOV R6,#250
DL20MS_1:
	MOV R7,#200
	DJNZ R7,$
	DJNZ R6, DL20MS_1
	RET

;繼電器控制
SWITCH:
        MOV A,KEY_BUF_G		;三個Buffer都是0的話，說明還沒有輸入數值，直接退出
        JNZ SNEXT
        MOV A,KEY_BUF_S
        JNZ SNEXT
        MOV A,KEY_BUF_B
        JZ  SQUIT
SNEXT:
	MOV A,KEY_BUF_S
	SUBB A,b_bit
	JC COOL
	JNZ HOT					;十位如果相等，那么繼續比較個位
	MOV A,KEY_BUF_G
	SUBB A,a_bit
	JC COOL
HOT:  CLR P_SWITCH				;P_SWITCH 為0說明當前溫度小于設定溫度，要升溫，所以接電爐
	  SJMP SQUIT
COOL: SETB P_SWITCH         ;P_SWITCH 為1說明當前溫度大于設定溫度，要降溫，所以接風扇
SQUIT:RET

;顯示子程序
display: mov a,29H;將29H中的十六進制數轉換成10進制
mov b,#10 ;10進制/10=10進制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個位在b
mov dptr,#numtab ;指定查表啟始地址
mov r0,#4
dpl1: mov r1,#250 ;顯示1000次
dplop: mov a,a_bit ;取個位數
MOVC A,@A+DPTR ;查個位數的7段代碼
clr p2.1 ;開個位顯示
mov p0,a ;送出個位的7段代碼

acall d1ms ;顯示1ms
setb p2.1
mov a,b_bit ;取十位數
MOVC A,@A+DPTR ;查十位數的7段代碼
clr p2.0 ;開十位顯示
mov p0,a ;送出十位的7段代碼

acall d1ms ;顯示1ms
setb p2.0
djnz r1,dplop ;100次沒完循環
djnz r0,dpl1 ;4個100次沒完循環
ret
;1MS延時(按12MHZ算)
D1MS: MOV R7,#80
DJNZ R7,$
RET
;實驗板上的7段數碼管0～9數字的共陰顯示代碼
numtab: DB 03FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH
end