;-----------------------------------------------------------------------------
; This file contains the startup code used by the ICCARM C compiler.
;
; The modules in this file are included in the libraries, and may be replaced
; by any user-defined modules that define the PUBLIC symbol _program_start or
; a user defined start symbol.
; To override the cstartup defined in the library, simply add your modified
; version to the workbench project.
;
; All code in the modules (except ?RESET) will be placed in the ICODE segment.
;
; $Revision: 1.2 $
;
;-----------------------------------------------------------------------------
	
;
; Naming covention of labels in this file:
;
;  ?xxx	  - External labels only accessed from assembler.
;  __xxx  - External labels accessed from or defined in C.
;  xxx	  - Labels local to one module (note: this file contains
;           several modules).
;  main	  - The starting point of the user program.
;

;---------------------------------------------------------------
; Macros and definitions for the whole file
;---------------------------------------------------------------


; --- Standard definitions of mode bits and interrupt (I & F) flags in PSRs

;#pragma location="ICODE"

Mode_USR           DEFINE   0x10
Mode_FIQ           DEFINE   0x11
Mode_IRQ           DEFINE   0x12
Mode_SVC           DEFINE   0x13
Mode_ABT           DEFINE   0x17
Mode_UNDEF         DEFINE   0x1B
Mode_SYS           DEFINE   0x1F ; available on ARM Arch 4 and later

I_Bit              DEFINE   0x80 ; when I bit is set, IRQ is disabled
F_Bit              DEFINE   0x40 ; when F bit is set, FIQ is disabled


; --- System memory locations

RAM_Base           DEFINE   0x20000000
RAM_Limit          DEFINE   0x20010000
SRAM_Base          DEFINE   0x60000000
Stack_Base         DEFINE   RAM_Limit


USR_Stack_Length   DEFINE   4096
IRQ_Stack_Length   DEFINE   1024
SVC_Stack_Length   DEFINE   256
FIQ_Stack_Length   DEFINE   256
ABT_Stack_Length   DEFINE   256
UNDEF_Stack_Length DEFINE   256


USR_Stack          DEFINE   Stack_Base                 ; USR stack
IRQ_Stack          DEFINE   USR_Stack-USR_Stack_Length ; followed by IRQ stack
SVC_Stack          DEFINE   IRQ_Stack-IRQ_Stack_Length ; followed by SVC stack
FIQ_Stack          DEFINE   SVC_Stack-SVC_Stack_Length ; followed by FIQ stack
ABT_Stack          DEFINE   FIQ_Stack-FIQ_Stack_Length ; followed by ABT stack
UNDEF_Stack        DEFINE   ABT_Stack-ABT_Stack_Length ; followed by UNDEF stack

EIC_Base_addr      DEFINE   0xFFFFF800; EIC base address
ICR_off_addr       DEFINE   0x00      ; Interrupt Control register offset
CIPR_off_addr      DEFINE   0x08      ; Current Interrupt Priority Register offset
IVR_off_addr       DEFINE   0x18      ; Interrupt Vector Register offset
FIR_off_addr       DEFINE   0x1C      ; Fast Interrupt Register offset
IER_off_addr       DEFINE   0x20      ; Interrupt Enable Register offset
IPR_off_addr       DEFINE   0x40      ; Interrupt Pending Bit Register offset
SIR0_off_addr      DEFINE   0x60      ; Source Interrupt Register 0

EMI_Base_addr      DEFINE   0x6C000000; EMI base address
BCON0_off_addr     DEFINE   0x00      ; Bank 0 configuration register offset
BCON1_off_addr     DEFINE   0x04      ; Bank 1 configuration register offset
BCON2_off_addr     DEFINE   0x08      ; Bank 2 configuration register offset
BCON3_off_addr     DEFINE   0x0C      ; Bank 3 configuration register offset

EMI_ENABLE         DEFINE   0x8000
EMI_SIZE_16        DEFINE   0x0001

GPIO2_Base_addr    DEFINE   0xE0005000; GPIO2 base address
PC0_off_addr       DEFINE   0x00      ; Port Configuration Register 0 offset
PC1_off_addr       DEFINE   0x04      ; Port Configuration Register 1 offset
PC2_off_addr       DEFINE   0x08      ; Port Configuration Register 2 offset
PD_off_addr        DEFINE   0x0C      ; Port Data Register offset

CPM_Base_addr      DEFINE   0xA0000040; CPM Base Address
BOOTCR_off_addr    DEFINE   0x10      ; CPM - Boot Configuration Register
FLASH_mask         DEFINE   0x0000    ; to remap FLASH at 0x0
RAM_mask           DEFINE   0x0002    ; to remap RAM at 0x0

;|----------------------------------------------------------------------------------|
;| - APB Bridge  (System Peripheral)                                               |
;|----------------------------------------------------------------------------------|
APB1_base_addr     DEFINE   0xC0000000          ; APB Bridge1 Base Address
APB2_base_addr     DEFINE   0xE0000000          ; APB Bridge2 Base Address
CKDIS_off_addr     DEFINE   0x10                ; APB Bridge1 - Clock Disable  Register
SWRES_off_addr     DEFINE   0x14                ; APB Bridge1 - Software Reset Register
CKDIS1_config_all  DEFINE   0x27FB              ; To enable/disable clock of all APB1's peripherals
SWRES1_config_all  DEFINE   0x27FB              ; To reset all APB1's peripherals
CKDIS2_config_all  DEFINE   0x7FDD              ; To enable/disable clock of all APB2's peripherals
SWRES2_config_all  DEFINE   0x7FDD              ; To reset all APB2's peripherals


;---------------------------------------------------------------
; ?program_start
;---------------------------------------------------------------
		PROGRAM	?program_start

		RSEG	IRQ_STACK:DATA(2)
		RSEG	SVC_STACK:DATA:NOROOT(2)
		RSEG	CSTACK:DATA(2)
		RSEG	ICODE:CODE:NOROOT(2)
		PUBLIC	__program_start
		EXTERN	?main
                CODE32


;*******************************************************************************
;*******                         -- MACROS --                            *******
;*******************************************************************************

;*******************************************************************************
;* Macro Name     : EIC_INIT
;* Description    : This macro Initialize the EIC as following :
;                 - IRQ disabled
;                 - FIQ disabled
;                 - IVR contain the load PC opcode (0xF59FF00)
;                 - Current priority level equal to 0
;                 - All channels are disabled
;                 - All channels priority equal to 0
;                 - All SIR registers contain offset to the related IRQ
;                   table entry
;* Input          : None.
;* Output         : None.
;*******************************************************************************
; no longer use this EIC_INIT macro in application, instead use modified c lib
;function EIC_Init() 
EIC_INIT   MACRO

        LDR     r3, =EIC_Base_addr
        LDR     r4, =0xE59F0000
        STR     r4, [r3, #IVR_off_addr]; Write the LDR pc,[pc,#offset]
                                       ; instruction code in IVR[31:16]
        LDR     r2, =32                ; 32 Channel to initialize
        LDR     r0, =T0TIMI_Addr       ; Read the address of the IRQs
                                       ; address table
        LDR     r1, =0x0000FFFF
        AND     r0,r0,r1
        LDR     r5, =SIR0_off_addr     ; Read SIR0 address
        SUB     r4,r0,#8               ; subtract 8 for prefetch
        LDR     r1, =0xF7E8            ; add the offset to the 0x00000000
                                       ; address(IVR address + 7E8 = 0x00000000)
                                       ; 0xF7E8 used to complete the
                                       ; LDR pc,[pc,#offset] opcode
        ADD     r1,r4,r1               ; compute the jump offset
EIC_INI MOV     r4, r1, LSL #16        ; Left shift the result
        STR     r4, [r3, r5]           ; Store the result in SIRx register
        ADD     r1, r1, #4             ; Next IRQ address
        ADD     r5, r5, #4             ; Next SIR
        SUBS    r2, r2, #1             ; Decrement the number of SIR registers
                                       ; to initialize
        BNE     EIC_INI                ; If more then continue
        ENDM
;*******************************************************************************
;* Macro Name     : PERIPHERAL_INIT
;* Description    : This macro reset all device peripherals.
;* Input          : None.
;* Output         : None.
;*******************************************************************************
PERIPHERAL_INIT MACRO

        LDR     r1, =APB1_base_addr      ; r0= APB1 base address
        LDR     r2, =APB2_base_addr      ; r0= APB2 base address
        LDR     r0, =CKDIS1_config_all
        STRH    r0, [r1, #CKDIS_off_addr]; Clock Disabling for all APB1 peripherals
        LDR     r0, =CKDIS2_config_all
        STRH    r0, [r2, #CKDIS_off_addr]; Clock Disabling for all APB2 peripherals
        LDR     r0, =SWRES1_config_all
        STRH    r0, [r1, #SWRES_off_addr]; Keep under reset all APB1 peropherals
        LDR     r0, =SWRES2_config_all
        STRH    r0, [r2, #SWRES_off_addr]; Keep under reset all APB2 peropherals
        MOV     r7, #10                  ; Wait that the selected macrocells exit from reset
loop1   SUBS    r7, r7, #1
        BNE     loop1
        MOV     r0, #0
        STRH    r0, [r1, #SWRES_off_addr]; Enable all all APB1 peropherals
        STRH    r0, [r2, #SWRES_off_addr]; Enable all all APB2 peropherals
        STRH    r0, [r1, #CKDIS_off_addr]; Clock Enabling for all APB1 peripherals
        STRH    r0, [r2, #CKDIS_off_addr]; Clock Enabling for all APB2 peripherals
        MOV     r7, #10                  ; Wait that the selected macrocells exit from reset
loop2   SUBS    r7, r7, #1
        BNE     loop2
        ENDM

; define remapping
; If you need to remap memory before entring the main program
; uncomment next ligne
;        #define   remapping

; Then define which memory to remap to address 0x00000000
;  Uncomment next line if you want to remap RAM
;        #define  remap_ram

;  Uncomment next line if you want to remap FLASH
;         #define remap_flash


        IMPORT  T0TIMI_Addr
__program_start
         LDR     pc, =NextInst
NextInst
		NOP		; Wait for OSC stabilization
		NOP
		NOP
		NOP
		NOP
		NOP
		NOP
		NOP
		NOP

        MSR     CPSR_c, #Mode_ABT|F_Bit|I_Bit
        LDR     SP, =ABT_Stack

        MSR     CPSR_c, #Mode_UNDEF|F_Bit|I_Bit
        LDR     SP,= UNDEF_Stack

        MSR     CPSR_c, #Mode_SVC|F_Bit|I_Bit
        LDR     SP, =RAM_Limit
; Uncomment next ligne if you need to reset all device pripherals
;       PERIPHERAL_INIT           ; Reset all device peripherals

;Uncomment next ligne if you need to initialize the EIC
;       EIC_INIT                  ; Initialize EIC

;******************************************************************************
;REMAPPING
;Description  : Remapping  memory whether RAM,FLASH
;               at Address 0x0 after the application has started executing.
;               Remapping is generally done to allow RAM  to replace FLASH
;               at 0x0.
;               the remapping of RAM allow copying of vector table into RAM
;******************************************************************************

#ifdef remapping
    #ifdef remap_flash
        MOV     r0, #FLASH_mask
    #endif
    #ifdef remap_ram
        MOV     r0, #RAM_mask
    #endif

        LDR     r1, =CPM_Base_addr
        LDRH    r2, [r1, #BOOTCR_off_addr]; Read BOOTCR Register
        BIC     r2, r2, #0x03             ; Reset the two LSB bits of BOOTCR
        ORR     r2, r2, r0                ; change the two LSB bits of BOOTCR
        STRH    r2, [r1, #BOOTCR_off_addr]; Write BOOTCR Register
#endif

       	MSR     CPSR_c, #Mode_FIQ|I_Bit; Change to FIQ mode
        LDR     SP, =FIQ_Stack            ; Initialize FIQ stack pointer

       	MSR     CPSR_c, #Mode_IRQ|I_Bit; Change to IRQ mode
        LDR     SP, =IRQ_Stack            ; Initialize IRQ stack pointer

        MSR     CPSR_c, #Mode_USR         ; Change to User mode, Enable IRQ and FIQ
        LDR     SP, =USR_Stack            ; Initialize USR stack pointer

        ;EIC_INIT ; (1) move it from "before remap" to "after remap"
        ; (2)over-function above macro to following new self-written c code
    
        
; --- Now branches to a C lib function

        b ?main   ; Note : use B not BL, because an application will
                         ; never return this way

        LTORG

        END