?? ewebeditor.asp
字號:
<!--#include file = "Include/Startup.asp"-->
<%
' 初始輸入參數
Dim sContentID, sStyleID, sFullScreen
Dim sStyleName, sStyleDir, sStyleCSS, sStyleUploadDir, nStateFlag, sDetectFromWord, sInitMode, sBaseUrl
Dim sVersion, sReleaseDate, sLicense
Call InitPara()
' 取所有按鈕
Dim aButtonCode(), aButtonHTML()
Call InitButtonArray()
' 取樣式下的工具欄及按鈕
Dim sToolBar
Call InitToolBar()
' 斷開數據庫連接
Call DBConnEnd()
%>
<html>
<head>
<title>在線文本編輯器</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link href="css/<%=sStyleCSS%>/Editor.css" type="text/css" rel="stylesheet">
<Script Language=Javascript>
var sPath = document.location.pathname;
sPath = sPath.substr(0, sPath.length-14);
var sLinkFieldName = "<%=sContentID%>" ;
var sLinkSourceFileName = "<%=Request.QueryString("sourcefilename")%>" ;
var sLinkSaveFileName = "<%=Request.QueryString("savefilename")%>" ;
// 全局設置對象
var config = new Object() ;
config.Version = "<%=sVersion%>" ;
config.ReleaseDate = "<%=sReleaseDate%>" ;
config.License = "<%=sLicense%>" ;
config.StyleName = "<%=sStyleName%>";
config.StyleEditorHeader = "<head><link href=\""+sPath+"css/<%=sStyleCSS%>/EditorArea.css\" type=\"text/css\" rel=\"stylesheet\"></head><body MONOSPACE>" ;
config.StyleMenuHeader = "<head><link href=\""+sPath+"css/<%=sStyleCSS%>/MenuArea.css\" type=\"text/css\" rel=\"stylesheet\"></head><body scroll=\"no\" onConTextMenu=\"event.returnValue=false;\">";
config.StyleDir = "<%=sStyleDir%>";
config.StyleUploadDir = "<%=sStyleUploadDir%>";
config.InitMode = "<%=sInitMode%>";
config.AutoDetectPasteFromWord = <%=sDetectFromWord%>;
config.BaseUrl = <%=sBaseUrl%>;
</Script>
<Script Language=Javascript src="include/editor.js"></Script>
<Script Language=Javascript src="include/table.js"></Script>
<Script Language=Javascript src="include/menu.js"></Script>
<script language="javascript" event="onerror(msg, url, line)" for="window">
//return true ; // 隱藏錯誤
alert("aaa");
</script>
</head>
<body SCROLLING=no onConTextMenu="event.returnValue=false;">
<table border=0 cellpadding=0 cellspacing=0 width='100%' height='100%'>
<tr><td>
<%=sToolBar%>
</td></tr>
<tr><td height='100%'>
<table border=0 cellpadding=0 cellspacing=0 width='100%' height='100%'>
<tr><td height='100%'>
<input type="hidden" ID="ContentEdit" value="">
<input type="hidden" ID="ModeEdit" value="">
<input type="hidden" ID="ContentLoad" value="">
<input type="hidden" ID="ContentFlag" value="0">
<iframe class="Composition" ID="eWebEditor" MARGINHEIGHT="1" MARGINWIDTH="1" width="100%" height="100%" scrolling="yes">
</iframe>
</td></tr>
</table>
</td></tr>
<% If nStateFlag = 1 Then %>
<tr><td height=25>
<TABLE border="0" cellPadding="0" cellSpacing="0" width="100%" class=StatusBar height=25>
<TR valign=middle>
<td>
<table border=0 cellpadding=0 cellspacing=0 height=20>
<tr>
<td width=10></td>
<td class=StatusBarBtnOff id=eWebEditor_CODE onclick="setMode('CODE')"><img border=0 src="buttonimage/<%=sStyleDir%>/modecode.gif" width=50 height=15 align=absmiddle></td>
<td width=5></td>
<td class=StatusBarBtnOff id=eWebEditor_EDIT onclick="setMode('EDIT')"><img border=0 src="buttonimage/<%=sStyleDir%>/modeedit.gif" width=50 height=15 align=absmiddle></td>
<td width=5></td>
<td class=StatusBarBtnOff id=eWebEditor_TEXT onclick="setMode('TEXT')"><img border=0 src="buttonimage/<%=sStyleDir%>/modetext.gif" width=50 height=15 align=absmiddle></td>
<td width=5></td>
<td class=StatusBarBtnOff id=eWebEditor_VIEW onclick="setMode('VIEW')"><img border=0 src="buttonimage/<%=sStyleDir%>/modepreview.gif" width=50 height=15 align=absmiddle></td>
</tr>
</table>
</td>
<td align=center id=eWebEditor_License style="font-size:9pt"></td>
<td align=right>
<table border=0 cellpadding=0 cellspacing=0 height=20>
<tr>
<td style="cursor:pointer;" onclick="sizeChange(300)"><img border=0 SRC="buttonimage/<%=sStyleDir%>/sizeplus.gif" width=20 height=20 alt="增高編輯區"></td>
<td width=5></td>
<td style="cursor:pointer;" onclick="sizeChange(-300)"><img border=0 SRC="buttonimage/<%=sStyleDir%>/sizeminus.gif" width=20 height=20 alt="減小編輯區"></td>
<td width=40></td>
</tr>
</table>
</td>
</TR>
</Table>
</td></tr>
<% End If %>
</table>
<div id="eWebEditor_Temp_HTML" style="VISIBILITY: hidden; OVERFLOW: hidden; POSITION: absolute; WIDTH: 1px; HEIGHT: 1px"></div>
</body>
</html>
<%
' 顯示調用錯誤提示
Sub ShowErr(str)
Call DBConnEnd()
Response.Write "調用錯誤：" & str
Response.End
End Sub
' 初始化輸入參數
Sub InitPara()
' 取全屏標志
sFullScreen = Trim(Request.QueryString("fullscreen"))
' 取對應的內容ID
sContentID = Trim(Request.QueryString("id"))
If sContentID = "" Then ShowErr "請傳入調用參數ID，即隱藏的內容表單項ID！"
' 取樣式初始值
sStyleName = Trim(Request.QueryString("style"))
If sStyleName = "" Then sStyleName = "standard"
sSql = "select * from ewebeditor_style where s_name='" & sStyleName & "'"
oRs.Open sSql, oConn, 0, 1
If Not oRs.Eof Then
sStyleID = oRs("S_ID")
sStyleName = oRs("S_Name")
sStyleDir = oRs("S_Dir")
sStyleCSS = oRs("S_CSS")
sStyleUploadDir = oRs("S_UploadDir")
nStateFlag = oRs("S_StateFlag")
sDetectFromWord = oRs("S_DetectFromWord")
sInitMode = oRs("S_InitMode")
sBaseUrl = oRs("S_BaseUrl")
sStyleUploadDir = Replace(sStyleUploadDir, "\", "/")
If Right(sStyleUploadDir, 1) <> "/" Then
sStyleUploadDir = sStyleUploadDir & "/"
End If
Else
ShowErr "無效的樣式Style參數傳入，如果要使用默認值，請留空！"
End If
oRs.Close
' 取版本號及發布日期
sSql = "select sys_version,sys_releasedate,sys_license from ewebeditor_system"
oRs.Open sSql, oConn, 0, 1
sVersion = oRs(0)
sReleaseDate = oRs(1)
sLicense = oRs(2)
oRs.Close
End Sub
' 初始化按鈕數組
Sub InitButtonArray()
Dim i
sSql = "select * from ewebeditor_button order by b_order asc"
oRs.Open sSql, oConn, 0, 1
i = 0
Do While Not oRs.Eof
i = i + 1
Redim Preserve aButtonCode(i)
Redim Preserve aButtonHTML(i)
aButtonCode(i) = oRs("B_Code")
Select Case oRs("B_Type")
Case 0
aButtonHTML(i) = "<DIV CLASS=""" & oRs("B_Class") & """ TITLE=""" & oRs("B_Title") & """ onclick=""" & oRs("B_Event") & """><IMG CLASS=""Ico"" SRC=""buttonimage/" & sStyleDir & "/" & oRs("B_Image") & """></DIV>"
Case 1
aButtonHTML(i) = "<SELECT CLASS=""" & oRs("B_Class") & """ onchange=""" & oRs("B_Event") & """>" & oRs("B_HTML") & "</SELECT>"
Case 2
aButtonHTML(i) = "<DIV CLASS=""" & oRs("B_Class") & """>" & oRs("B_HTML") & "</DIV>"
End Select
oRs.MoveNext
Loop
oRs.Close
End Sub
' 由按鈕代碼得到按鈕的最終輸出
Function Code2HTML(s_Code)
Dim i
Code2HTML = ""
For i = 1 To UBound(aButtonCode)
If UCase(aButtonCode(i)) = UCase(s_Code) Then
Code2HTML = aButtonHTML(i)
Exit Function
End If
Next
End Function
' 初始化工具欄
Sub InitToolBar()
Dim aButton, n
sSql = "select t_button from ewebeditor_toolbar where s_id=" & sStyleID & " order by t_order asc"
oRs.Open sSql, oConn, 0, 1
If Not oRs.Eof Then
sToolBar = "<table border=0 cellpadding=0 cellspacing=0 width='100%' class='Toolbar' id='eWebEditor_Toolbar'>"
Do While Not oRs.Eof
sToolBar = sToolBar & "<tr><td><div class=yToolbar>"
aButton = Split(oRs("T_Button"), "|")
For n = 0 To UBound(aButton)
If sFullScreen = "1" And UCase(aButton(n)) = "MAXIMIZE" Then
aButton(n) = "Minimize"
End If
sToolBar = sToolBar & Code2HTML(aButton(n))
Next
sToolBar = sToolBar & "</div></td></tr>"
oRs.MoveNext
Loop
sToolBar = sToolBar & "</table>"
Else
ShowErr "對應樣式沒有設置工具欄！"
End If
oRs.Close
End Sub
%>?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -