;********************************************************************
;*                                                                  *
;* ME500單片機開發系統演示程序 - 0-9999999.9 秒計數                 *
;*                                                                  *
;* 8位數碼管顯示                                                    *
;*                                                                  *
;* 版本： V1.0 (2006/11/20)                                         *
;* 作者： gguoqing (Email: gguoqing@willar.com)                     *
;* 網站： www.willar.com(偉納電子)   www.mcusj.com(偉納單片機世界)  *
;* 郵箱： support@willar.com                                        *
;*                                                                  *
;*【版權】Copyright(C)偉納電子 www.willar.com  All Rights Reserved  *
;*【聲明】此程序僅用于學習與參考，引用請注明版權和作者信息！        *
;*                                                                  *
;********************************************************************

         Count      EQU  40H
         TimeCount  EQU  3FH

;**********************************************************

         ORG 0000H
         JMP  MAIN
         ORG  000BH
         JMP  TIMER0
         ORG 0030H

;**********************************************************
MAIN:
         MOV  SP,#60H
         MOV TMOD,#01
         SETB  EA
         SETB  ET0
         SETB  TR0
         MOV  TH0,#4CH         ;50ms定時
         MOV  TL0,#00H
         MOV  R0,#Count
         MOV  A,#00H
CLR_1:
         MOV  @R0,A             ;清零
         INC  R0
         CJNE  R0,#49H,CLR_1      
DISP:
         MOV R0,#Count         ;獲得顯示單元首地址
         MOV R1,#07FH          ;從第一個數碼管開始
         MOV R2,#08H           ;共顯示8位數碼管
DISP1:
         MOV A,@R0             ;獲得當前位地址
         MOV DPTR,#TABLE       ;獲得表頭
         MOVC A,@A+DPTR        ;查表獲得顯示數據
         MOV P0,A              ;顯示數據
         MOV P2,R1             ;開始顯示當前位
         MOV A,R1              ;準備顯示下一位
         CJNE  A,#0BFH,DISP2
         CLR  P0.7             ;加小數點
DISP2:         
         RR A
         MOV R1,A              ;下一位
         INC R0                ;取下一個單元地址
         LCALL DELAY2MS        ;延時 2 MS
         DJNZ R2,DISP1         ;重復顯示下一個
         MOV  P2,#0FFH
         JMP  DISP
         RET                   ;顯示完成，返回
;---------------------------------------------------------
;延時子程序
;---------------------------------------------------------
DELAY2MS:
         MOV  R6,#10
DEL1:
         MOV  R7,#100
         DJNZ  R7,$
         DJNZ  R6,DEL1
         RET
;**********************************************************
TIMER0:
         PUSH  ACC
         MOV  TH0,#4CH             ;50ms定時
         MOV  TL0,#00H
         INC  TimeCount
         MOV  A,TimeCount
         CJNE  A,#2,T_END
         MOV  TimeCount,#00H
         INC Count                 ;小數位
         MOV A,Count
         CJNE A,#10,T_END
         MOV  Count,#00H
         INC Count+1               ;個位
         MOV A,Count+1
         CJNE A,#10,T_END
         MOV  Count+1,#00H
         INC Count+2               ;十位
         MOV A,Count+2
         CJNE A,#10,T_END
         MOV  Count+2,#00H
         INC Count+3               ;百位
         MOV A,Count+3
         CJNE A,#10,T_END
         MOV  Count+3,#00H
         INC Count+4               ;千位
         MOV A,Count+4
         CJNE A,#10,T_END
         MOV  Count+4,#00H
         INC Count+5               ;萬位
         MOV A,Count+5
         CJNE A,#10,T_END
         MOV  Count+5,#00H
         INC Count+6               ;十萬位
         MOV A,Count+6
         CJNE A,#10,T_END
         MOV  Count+6,#00H
         INC Count+7               ;百萬位
         MOV A,Count+7
         CJNE A,#10,T_END
         MOV  Count+7,#00H                       
T_END:
         POP  ACC
         RETI

;**********************************************************
TABLE:
        DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H
        DB 80H ,90H,0FFH
        DB 88H,83H,0C6H,0A1H,86H,8EH
;**********************************************************
         END